R>Custom World Boss Script

[MASHU26]

Is it possible to make a world boss event with all players in a specific map gets reward if the boss is defeated and special reward for the player/party that killed the boss?

[PottScilgrim]

Try this:

You'll need to modify the settings in "OnInit" with the mob ID's of the bosses you want to use, the map(s) you'd like to use for the event, and the prize item ID's and amounts.

 

//================================================================//
//	World Boss Script
//	Created by PottScilgrim
//================================================================//
-	script	WorldBossEvent	-1,{ 


//================================================================//
//	Change the "OnClock" times to be when you want the event to begin
//================================================================//
OnClock1100:
OnClock2300:
	if(.WBMAPS$[1] == "") { 
		if(.WBMOBID[1] == 0){
			monster .WBMAPS$[0],0,0,"[World Boss]",.WBMOBID[0],1,"WorldBossEvent::OnWBDead",2;
		} else {
			monster .WBMAPS$[0],0,0,"[World Boss]",.WBMOBID[rand(getarraysize(.WBMOBID))],1,"WorldBossEvent::OnWBDead",2;
		}
	} else {
		if(.WBMOBID[1] == 0){
			monster .WBMAPS$[rand(getarraysize(.WBMAPS$))],0,0,"[World Boss]",.WBMOBID[0],1,"WorldBossEvent::OnWBDead",2;
		} else {
			monster .WBMAPS$[rand(getarraysize(.WBMAPS$))],0,0,"[World Boss]",.WBMOBID[rand(getarraysize(.WBMOBID))],1,"WorldBossEvent::OnWBDead",2;
		}
	}
	announce "[World Boss]: The world boss has spawned!",bc_all;
	end;

//================================================================//
//	This event fires off when the world boss is killed
//================================================================//
OnWBDead:
	announce "[World Boss]: "+ strcharinfo(0)+" landed the final blow against the world boss!",bc_all;
	getitem .sprize,.sprizeamt; // Gives only the winning player this prize
	addrid 1,0;	// Attaches all players on the current map 
	getitem .mprize,.mprizeamt;	// Gives all players a prize
	end;

//================================================================//
//	These are the NPC settings
//================================================================//
OnInit:
	// Add your world boss mob ID's here. If you only need one, just put one.
	setarray .WBMOBID, 1002,1003;

	// Add the maps for your world boss event here. If you only want one, just add one.
	setarray .WBMAPS$,"prontera","geffen";

	// This is the special prize for the player that lands the final hit.
	.sprize = 512;
	.sprizeamt = 1;

	// This is the prize that gets given to all players on the event map when it is killed
	.mprize = 513;
	.mprizeamt = 1;
	end;
}