Jobmaster Rebirth into regular Jobchange

yani9o · May 10, 2020

Hello there

I have a problem with the Jobmaster NPC:

When you rebirth via Jobmaster and then level to joblvl 10 again, you can't change to 1st Job the "normal" way (for example novice high -> acolyte high):

image.png.8fdf2798567b0d71ede449bdb2ddd4f9.png

Anyone knows how to fix this?

Does it have anything to do with not paying for reading the book in juno? seems like a flag is not set or something like that...

Also, is there a way to change the "Book reading" cost in juno for rebirth?

Thanks in advance

yani9o · May 11, 2020

Okay then...

Actual Problem:
The NPCs for First Job (Rebirth) check for ADVJOB - but i can't find where and how it's set (where is that variable saved? SQL?)...
Can i just write this in Jobmaster.txt (where you change to novice high)?

ADVJOB = Class;

There is something similar tho:

lastJob = Class; // Saves the lastJob for rebirth

Is that the same?

Other approach, npc/jobs/valkyrie.txt:
The Book of Ymir (after you paid to read the book) starts a quest in line 329:

set valkyrie_Q,2;
if(checkquest(1000) == -1) {
	setquest 1000;
}

Then, Valkyrie completes this quest in line 156:

completequest 1000;

Need to test if this would be enough to make it work...

About the Book of Ymir cost, line 226 (changed it to 500k zeny):

			mes "[Metheus Sylphe]";
			mes "Also, in order to preserve the original 'Book of Ymir,' we have decided to accept donations from people who wish to read the copy we have provided.";
			next;
			mes "[Metheus Sylphe]";
			mes "The suggested";
			mes "donation amount is";
			mes "500,000 zeny.";
			next;
			if (select("Donate.:Cancel.") == 1) {
				if (Zeny >= 500000) {
					set Zeny, Zeny-500000;
					set valkyrie_Q,1;
					mes "[Metheus Sylphe]";
					mes "Thank you, your donation will be used for a good cause. You may";
					mes "now go in and read the book.";
					close;
				}
				mes "[Metheus Sylphe]";
				mes "Unfortunately, you don't seem to possess enough zeny at the moment. Please check your funds and come back again.";
				close;
			}

I'll report back just in case someone else is looking for the same i did.

yani9o · May 11, 2020

Solution

Change this in /npc/custom/jobmaster.txt (line 307):

if (.@to_cls == Job_Novice_High && .LastJob)
		lastJob = Class; // Saves the lastJob for rebirth

to:

if (.@to_cls == Job_Novice_High && .LastJob) {
  lastJob = Class;		// Saves the lastJob for rebirth
  ADVJOB = Class + 4001;	// Sets rebirth path for regular job change
  set valkyrie_Q,2;		// Complete Book of Ymir Quest
  completequest 1000;		// Complete Rebirth Quest
}

Now, you can decide between jobmaster and normal jobchange all the time (Rebirth 1st -> Rebirth 2nd is working now too).

Just in case if someone is interested in a "custom" jobmaster.txt (Warning, maybe kinda messy now xD):
Changes made:
- Added costs to jobchanges and added dialogue for them (at bottom, 1st = 5k, 2nd = 50k, rebirth/3rd = 500k - you can set these to 0, dialogue won't change tho...)
- Changed Items you get for Novice -> 1st (only non-rebirth now, items according to irowiki.org jobchange )
- Disabled Star Emperor and Soul Reaper (was not included in that 5-min package back then - tbh, no idea anymore where i did that xD)
- Allways get platinum skills if changing from novice high to high 1st (like on live)
- Added learn platinum skills dialogue option at start (cost is set at bottom too - needs if() to check if already learned... don't care atm)
- Moved Jobmaster to Eden Group (Because i have all my custom npcs there) and changed sprite to 10180 (4_M_GONY)

//===== rAthena Script =======================================
//= Job Master
//===== Description: =========================================
//= A fully functional job changer.
//===== Additional Comments: =================================
//= 1.0 Initial script. [Euphy]
//= 1.1 Fixed reset on Baby job change.
//= 1.2 Added Expanded Super Novice support and initial Kagerou/Oboro support.
//= 1.3 Kagerou/Oboro added.
//= 1.4 Rebellion added.
//= 1.5 Added option to disable RebirthClass. [mazvi]
//= 1.6 Added option to get job related equipment on change. [Braniff]
//= 1.7 Readability changes. Also added BabyExpanded and BabySummoner classes. [Jey]
//= 1.8 Added option to disable Baby Novice Only but Baby Class can be Enabled [mazvi]
//= 1.9 Migrate/Integrate to Global Functions Platinum Skills. [mazvi]
//============================================================

-	script	Job Master	-1,{

function Get_Job_Equip;
// Checks if the Player has the required level.
// closes if not, returns if yes
function	Require_Level	{
	if (BaseLevel < getarg(0) || JobLevel < getarg(1)) {
		.@blvl = getarg(0) - BaseLevel;
		.@jlvl = getarg(1) - JobLevel;
		mes "Level requirement:";
		mes ((getarg(0)>1)? 
			"^bb0000"+getarg(0)+"^000000 (^bb0000Base^000000) / ":"")+"^00bb00"+
			getarg(1)+"^000000 (^00bb00Job^000000)";
		mes "You need " +
			((.@blvl > 0) ? "^bb0000"+.@blvl+"^000000 more base levels " + 
				((.@jlvl > 0) ? "and " : "") : "") +
			((.@jlvl > 0) ? "^00bb00"+.@jlvl+"^000000 more job levels " : "") +
			"to continue.";
		close;
	}
	return;
}

// Checks if the given eac is a baby class
function Is_Baby	{
	return ((getarg(0, eaclass())&EAJL_BABY)>0);
}

// Checks if the player can change to third class.
// Note: This does not include the level checks.
function	Can_Change_Third	{
	// To change to third class you either need to be:
	// * Second Class
	// * Transcendent Second Class
	// * Baby Second Class
	if( !.ThirdClass )
		return false; // Third job change disabled
	if( !(eaclass()&EAJL_2) )
		return false; // Not second Class
	if( eaclass()&EAJL_THIRD )
		return false; // Already Third Class
	if( roclass(eaclass()|EAJL_THIRD) < 0 )
		return false; // Job has no third Class
	if( (eaclass()&EAJ_UPPERMASK) == EAJ_SUPER_NOVICE )
		return false; // Exp. Super Novice equals 3rd Cls, but has it's own case
	if( Is_Baby() && (!.BabyClass || !.BabyThird) )
		return false; // No Baby (Third) change allowed
	return true;
}

function	Can_Rebirth	{
	// To rebirth, you need to be:
	// * Second Class
	if( !.RebirthClass )
		return false; // Rebirth disabled
	if( !(eaclass()&EAJL_2) )
		return false; // Not second Class
	if( eaclass()&EAJL_UPPER )
		return false; // Already Rebirthed
	if( roclass(eaclass()|EAJL_UPPER) < 0 )
		return false; // Job has no transcended class
	if( Is_Baby() && !.BabyClass )
		return false; // No Baby changes allowed
	return true;
}

// Checks if the given eac is a first class
function	Is_First_Cls	{
	return (getarg(0) <= EAJ_TAEKWON);
}

function	Check_Riding	{
	// Note: Why we should always check for Riding:
	// Mounts are considered as another class, which
	// would make this NPC bigger just to handle with
	// those special cases.
	if (checkfalcon() || checkcart() || checkriding() || ismounting()) {
		mes "Please remove your " +
			((checkfalcon()) ? "falcon" : "") +
			((checkcart()) ? "cart" : "") +
			((checkriding()) ? "Peco" : "") +
			((ismounting()) ? "mount" : "") +
			" before proceeding.";
		close;
	}
	return;
}
function	Check_SkillPoints	{
	if (.SkillPointCheck && SkillPoint) {
		mes "Please use all your skill points before proceeding.";
		close;
	}
	return;
}

// addJobOptions is essentially the same like
// setarray .@array[getarraysize(.@array)],opt1,opt2,...;
// It's just easier to read, since we're using it very often
function	Job_Options	{
	.@argcount = getargcount();
	.@arr_size = getarraysize(getarg(0));
	for( .@i = 1; .@i < .@argcount; .@i++) {
		setarray getelementofarray(getarg(0), .@arr_size++),getarg(.@i);
	}
}

// Begin of the NPC
	mes .NPCName$;

	// initialisation
	deletearray .@job_opt[0],getarraysize(.@job_opt);
	.@eac = eaclass();
	.@third_possible = Can_Change_Third();
	.@rebirth_possible = Can_Rebirth();
	.@first_eac = .@eac&EAJ_BASEMASK;
	.@second_eac = .@eac&EAJ_UPPERMASK;
	// Note: These are already set in pc.cpp
	// BaseClass = roclass(.@eac&EAJ_BASEMASK) which is the players First Class
	// BaseJob = roclass(.@eac&EAJ_UPPERMASK) which is the players Second Class
	//dispbottom "Debug: eac ("+.@eac+"), third ("+.@third_possible+"), rebirth("+.@rebirth_possible+"), BaseClass ("+BaseClass+"), BaseJob ("+BaseJob+")";
		
	// From here on the jobmaster checks the current class
	// and fills the the array `.@job_opt` with possible
	// job options for the player.
	
	if( .@rebirth_possible ) {
		// Rebirth option (displayed on the top of the menu)
		Require_Level(.Req_Rebirth[0], .Req_Rebirth[1]);
		Job_Options(.@job_opt, Job_Novice_High);
	}
	if( .@third_possible ) {
		// Third Job change (displayed below rebirth)
		Require_Level(.Req_Third[0], .Req_Third[1]);
		Job_Options(.@job_opt, roclass(.@eac|EAJL_THIRD));
	}
	 
	if (.SecondExpanded && 
	   (.@eac&EAJ_UPPERMASK) == EAJ_SUPER_NOVICE && // is Super Novice
	   !(eaclass()&EAJL_THIRD) ) {				 	// not already Expanded SN
		// (Baby) Super Novice to Expanded (Baby) Super Novice
	   	if( !Is_Baby(.@eac) || (.BabyClass && .BabyExpanded) ) {
			// .BabyClass & .BabyExpanded must be enabled if the is a baby
			Require_Level(.Req_Exp_SNOVI[0], .Req_Exp_SNOVI[1]);
			Job_Options(.@job_opt,roclass(.@eac|EAJL_THIRD)); // Expanded SN is "third" cls
		}
	}
	
	if (.SecondExpanded && 
		((.@eac&(~EAJL_BABY)) == EAJ_NINJA || 		// is (Baby) Ninja
		(.@eac&(~EAJL_BABY)) == EAJ_GUNSLINGER)) {	// is (Baby) Gunslinger
		// (Baby) Ninja to (Baby) Kagerou / Oboro
		// (Baby) Gunslinger to (Baby) Rebellion
		if( !Is_Baby(.@eac) || (.BabyClass && .BabyExpanded) ) {
			// .BabyClass & .BabyExpanded must be enabled if the is a baby
			Require_Level(.Req_Exp_NJ_GS[0], .Req_Exp_NJ_GS[1]);
			// Kagerou, Oboro, Rebellion are considered as a 2-1 class
			Job_Options(.@job_opt, roclass(.@eac|EAJL_2_1));
		}
	}
	
	// Player is Job_Novice, Job_Novice_High or Job_Baby
	if (.@first_eac == EAJ_NOVICE && .@second_eac != EAJ_SUPER_NOVICE) {
		// MAPID_NOVICE, MAPID_SUPER_NOVICE, MAPID_NOVICE_HIGH, MAPID_BABY
		Require_Level(.Req_First[0], .Req_First[1]);
		switch(Class) {
			case Job_Novice:
				// First job change
				Job_Options(.@job_opt,Job_Swordman,
					Job_Mage, Job_Archer, Job_Acolyte, Job_Merchant, Job_Thief,
					Job_Super_Novice, Job_Taekwon, Job_Gunslinger, Job_Ninja);
				if( .BabyNovice )
					Job_Options(.@job_opt, Job_Baby);
				break;
			case Job_Novice_High:
				// Job change after rebirth
				if( .LastJob && lastJob )
					Job_Options(.@job_opt,
						roclass((eaclass(lastJob)&EAJ_BASEMASK)|EAJL_UPPER));
				else
					Job_Options(.@job_opt, 
						Job_Swordman_High, Job_Mage_High, Job_Archer_High,
						Job_Acolyte_High, Job_Merchant_High, Job_Thief_High);
				break;
			case Job_Baby:
				if( !.BabyClass )
					break;
				// First job change as a baby
				Job_Options(.@job_opt, Job_Baby_Swordman, Job_Baby_Mage,
					Job_Baby_Archer,Job_Baby_Acolyte, Job_Baby_Merchant,
					Job_Baby_Thief);
				if( .BabyExpanded )
					Job_Options(.@job_opt, Job_Super_Baby, Job_Baby_Taekwon,
						Job_Baby_Gunslinger, Job_Baby_Ninja);
				if( .BabySummoner )
					Job_Options(.@job_opt, Job_Baby_Summoner);
				break;
			default:
				mes "An error has occurred.";
				close;
		}
	} else if( Is_First_Cls(.@eac) || 				// First Class
			   Is_First_Cls(.@eac&(~EAJL_UPPER)) ||	// Trans. First Cls
			   (.BabyClass && Is_First_Cls(.@eac&(~EAJL_BABY))) ) {	// Baby First Cls
		// Player is First Class (not Novice)
		// most jobs should have two options here  (2-1 and 2-2)
		.@class1 = roclass(.@eac|EAJL_2_1); // 2-1
		.@class2 = roclass(.@eac|EAJL_2_2); // 2-2
		// dispbottom "Debug: Classes: class1 ("+.@class1+"), class2 ("+.@class2+")";
		if(.LastJob && lastJob && (.@eac&EAJL_UPPER)) {
			// Player is rebirth Cls and linear class changes are enforced
			Require_Level(.Req_Second[0], .Req_Second[1]);
			Job_Options(.@job_opt, lastJob + Job_Novice_High);
		} else {
			// Class is not enforced, player can decide.
			if( .@class1 > 0 ) { // 2-1
				Require_Level(.Req_Second[0], .Req_Second[1]);
				Job_Options(.@job_opt, .@class1);
			}
			if( .@class2 > 0 ) { // 2-2
				Require_Level(.Req_Second[0], .Req_Second[1]);
				Job_Options(.@job_opt, .@class2);
			}
		}
	}
	
	// Displaying the Job Menu defined by .@job_opt.
	// .@job_opt should not be changed below this line.
	function Job_Menu;
	Job_Menu(.@job_opt);
	close;

// Displays the job menu
function	Job_Menu	{
	
	function Confirm_Change;
	while(true) {
		
		mes "I can train you to get stronger.";
		mes "You don't even have to complete a quest!";
		mes "My training is not for free tho...";
		next;
		mes "Prices:";
		mes "Novice to 1st Class = ^0055FF"+.cost[0]+"^000000 Zeny";
		mes "1st to 2nd = ^0055FF"+.cost[1]+"^000000 Zeny";
		mes "2nd to 3rd = ^0055FF"+.cost[2]+"^000000 Zeny";
		mes "Platinskills = ^0055FF"+.cost[3]+"^000000 Zeny";
		next;
		menu "Job Change:Platin Skills", -;
		switch (@menu) {
			case 1:
				Check_Riding();
				Check_SkillPoints();
				// getarg(0) is the .@job_opt array holding all available job changes.
				.@opt_cnt =  getarraysize(getarg(0));
				if( .@opt_cnt <= 0 ) {
					mes "No more jobs are available.";
					close;
				}
				.@selected = 0; // Just a single job class given, no select needed
				if (.@opt_cnt > 1) {
					// Multiple job classes given. Select one and save it to .@class
					// After that confirm .@class
					mes "Select a job:";
					.@menu$ = "";
					for (.@i = 0; .@i < .@opt_cnt; .@i++) {
						if( getelementofarray(getarg(0), .@i) == Job_Novice_High)
							.@jobname$ = "^0055FFRebirth^000000";
						else
							.@jobname$ = jobname(getelementofarray(getarg(0), .@i));
						.@menu$ = .@menu$ + " ~ " + .@jobname$ + ":";
					}
					.@selected = select(.@menu$) - 1;
					if( .@selected < 0 || .@selected >= .@opt_cnt )
						close;
					mes .NPCName$;
				}
				.@class = getelementofarray(getarg(0), .@selected);
				if ((.@class == Job_Super_Novice || .@class == Job_Super_Baby) &&
						BaseLevel < .SNovice) {
					// Special Level Requirement because Super Novice and
					// Super Baby can both be selected in one of the first class
					// changes. That's why the Level Requirement is after and not before
					// the selection.
					mes "A base level of " + .SNovice +
						" is required to turn into a " + jobname(.@class) + ".";
					return;
				}
				// Confirm the Class
				Confirm_Change(.@class, .@opt_cnt > 1);
				break;
			case 2:
				mes "Would you like to learn these skills now?";
				mes "Platinskill training costs ^0055FF"+.cost[3]+"^000000 Zeny";
				next;
				
				if (select("Yes Please:No") == 2) {
					mes "Come back if you want to train.";
					close;
				}
				if ( Zeny < .cost[3] )	{
					mes "You don't have ^0055FF"+.cost[3]+"^000000 Zeny!";
					close;
				}
				
				callfunc "F_GetPlatinumSkills";
				mes .NPCName$;
				mes "There you go!";
				Zeny -= .cost[3];
				specialeffect2 EF_ELECTRIC;
				close;
				break;
		}
	}
	return;
}


// Executes the actual jobchange and closes.
function	Job_Change	{

	.@previous_class = Class;
	.@to_cls = getarg(0);
	
	if ( (.@to_cls >= Job_Swordman && .@to_cls <= Job_Thief) || (.@to_cls >= Job_Gunslinger && .@to_cls <= Job_Ninja) || .@to_cls == Job_Taekwon || (.@to_cls >= Job_Swordman_High && .@to_cls <= Job_Thief_High) || (.@to_cls >= Job_Baby && .@to_cls <= Job_Baby_Thief) || .@to_cls == Job_Baby_Gunslinger || .@to_cls == Job_Baby_Ninja || .@to_cls == Job_Baby_Taekwon )	{
		.costamount = .cost[0];
	} else if ( (.@to_cls >= Job_Knight && .@to_cls <= Job_Crusader2) || (.@to_cls >= Job_Lord_Knight && .@to_cls <= Job_Paladin2) || (.@to_cls >= Job_Star_Gladiator && .@to_cls <= Job_Soul_Linker) || (.@to_cls >= Job_Kagerou && .@to_cls <= Job_Rebellion) || .@to_cls == Job_SuperNovice || (.@to_cls >= Job_Baby_Knight && .@to_cls <= Job_Super_Baby) )	{
		.costamount = .cost[1];
	} else {
		.costamount = .cost[2];
	}
	
	if ( Zeny < .costamount )	{
		next;
		mes "You don't have ^0055FF"+.costamount+"^000000 Zeny!";
		close;
	}
	
	next;
	mes .NPCName$;
	mes "You are now " + callfunc("F_InsertArticle", jobname(.@to_cls)) + "!";
	
	if (.@to_cls == Job_Novice_High && .LastJob) {
		lastJob = Class;		// Saves the lastJob for rebirth
		ADVJOB = Class + 4001;	// Sets rebirth path for regular job change
		set valkyrie_Q,2;		// Complete Book of Ymir Quest
		completequest 1000;		// Complete Rebirth Quest
	}
	
		Zeny -= .costamount;
		jobchange .@to_cls;
	
	if (.@to_cls == Job_Novice_High)
		resetlvl(1);
	else if (.@to_cls == Job_Baby) {
		resetstatus;
		resetskill;
		set SkillPoint,0;
	}
	specialeffect2 EF_ANGEL2;
	specialeffect2 EF_ELECTRIC;
	if (.@previous_class != Class) {
		if (.Platinum ) {
			callfunc "F_GetPlatinumSkills";
		} else {
			if ( .@to_cls >= Job_Swordman_High && .@to_cls <= Job_Thief_High )	{
				callfunc "F_GetPlatinumSkills";
			}
		}
		if (.GetJobEquip) {
			Get_Job_Equip();
		}
	}
	close; // Always closes after the change
}

function	Confirm_Change	{
	// Player confirms he want to change into .@class
	.@class = getarg(0, -1);
	.@back = getarg(1, false);
	if( .@class < 0 || .@class >= 4239 ) {
		mes "No more jobs are available.";
		close;
	}
	mes "Do you want to change into ^0055FF"+jobname(.@class)+"^000000 class?";
	.@job_option$ = " ~ Change into ^0055FF"+jobname(.@class)+"^000000 class";
	if( .@class == Job_Novice_High)
		.@job_option$ = " ~ ^0055FFRebirth^000000";
	if (select(.@job_option$+": ~ ^777777" + 
			((.@back) ?"Go back" : "Cancel") + "^000000") == 1) {
		Job_Change(.@class);
	}
	if (!.@back)
		close; // "Cancel" pressed
	return;
}

// Function which gives a job related item to the player
// the items are the rewards from the original job change quests
function	Get_Job_Equip	{
	// Note: The item is dropping, when the player can't hold it.
	// But that's better than not giving the item at all.
	.@eac = eaclass();
	if( .@eac&EAJL_THIRD ) {
		// Third Class Items
		getitem 2795,1;	//	Green Apple Ring for every 3rd Class
		switch(BaseJob) {
			// BaseJob of Third Cls
			// For Normal Third, Baby Third and Transcended Third Cls
			case Job_Knight:
				getitem 5746,1;	break;	//	Rune Circlet [1]
			case Job_Wizard:
				getitem 5753,1;	break;	//	Magic Stone Hat [1]
			case Job_Hunter:
				getitem 5748,1;	break;	//	Sniper Goggle [1]
			case Job_Priest:
				getitem 5747,1;	break;	//	Mitra [1]
			case Job_Blacksmith:
				getitem 5749,1;	break;	//	Driver Band [1]
			case Job_Assassin:
				getitem 5755,1;	break;	//	Silent Executor [1]
			case Job_Crusader:
				getitem 5757,1;	break;	//	Dip Schmidt Helm [1]
			case Job_Sage:
				getitem 5756,1;	break;	//	Wind Whisper [1]
			case Job_Bard:
				getitem 5751,1;	break;	//	Maestro Song's Hat [1]
			case Job_Dancer:
				getitem 5758,1;	break;	//	Dying Swan [1]
			case Job_Monk:
				getitem 5754,1;	break;	//	Blazing Soul [1]
			case Job_Alchemist:
				getitem 5752,1;	break;	//	Midas Whisper[1]
			case Job_Rogue:
				getitem 5750,1; 		//	Shadow Handicraft [1]
				getitem 6121,1;			//	Makeover Brush
				getitem 6122,1;	break;	//	Paint Brush
		}
	} else if ( !(.@eac&EAJL_2) && !(.@eac&EAJL_UPPER) ) {
		// Not Second Job AND not Rebirth/Third
		if ( (.@eac&EAJ_UPPERMASK) == EAJ_SWORDMAN ) {
			getitem 1101,1;
			getitem 2101,1;
		} else if ( (.@eac&EAJ_UPPERMASK) == EAJ_MAGE ) {
			getitem 1601,1;
			getitem 2101,1;
		} else if ( (.@eac&EAJ_UPPERMASK) == EAJ_ARCHER ) {
			getitem 1701,1;
			getitem 1750,500;
		} else if ( (.@eac&EAJ_UPPERMASK) == EAJ_ACOLYTE ) {
			getitem 1501,1;
			getitem 2101,1;
		} else if ( (.@eac&EAJ_UPPERMASK) == EAJ_MERCHANT ) {
			getitem 1301,1;
			getitem 2101,1;
		} else if ( (.@eac&EAJ_UPPERMASK) == EAJ_THIEF ) {
			getitem 1201,1;
			getitem 2101,1;
		} else if ( (.@eac&EAJ_UPPERMASK) == EAJ_GUNSLINGER ) {
			getitem 13100,1;
			getitem 13200,500;
		} else if ( (.@eac&EAJ_UPPERMASK) == EAJ_NINJA ) {
			getitem 13010,1;
			getitem 2101,1;
		} else if ( (.@eac&EAJ_UPPERMASK) == EAJ_TAEKWON ) {
			getitem 2101,1;
		}
	}
	return;
}

OnInit:
	// Initialisation, do not edit these
	.NPCName$ = "[Job Master]";
	
	// Settings
	.ThirdClass = true;				// Enable third classes?
	.RebirthClass = true;			// Enable rebirth classes?
	.SecondExpanded = true;			// Enable new expanded second classes: Ex. Super Novice, Kagerou/Oboro, Rebellion?
	.BabyNovice = true;				// Enable Baby novice classes? Disable it if you like player must have parent to get job baby.
	.BabyClass = true;				// Enable Baby classes?
	.BabyThird = true;				// Enable Baby third classes?
	.BabyExpanded = true;			// Enable Baby Expanded classes: Ex. Baby Ninja, Baby Taekwon, etc.
	.BabySummoner = false;			// Enable Baby Summoner?
	.LastJob = true;				// Enforce linear class changes?
	.SkillPointCheck = true;		// Force player to use up all skill points?
	.Platinum = false;				// Allways get Platinum Skills (fals = only high 1st jobs)?
	.GetJobEquip = true;			// Get job equipment (mostly weapons) on job change?

	// Level Requirements
	setarray .Req_First[0],1,10; 		// Minimum base level, job level to turn into 1st class
	setarray .Req_Second[0],1,40; 		// Minimum base level, job level to turn into 2nd class
	setarray .Req_Rebirth[0],99,50;		// Minimum base level, job level to rebirth
	setarray .Req_Third[0],99,50;		// Minimum base level, job level to change to third class
	setarray .Req_Exp_NJ_GS[0],99,70; 	// Minimum base level, job level to turn into Expanded Ninja and Gunslinger
	setarray .Req_Exp_SNOVI[0],99,99; 	// Minimum base level, job level to turn into Expanded Super Novice
	.SNovice = 45;						// Minimum base level to turn into Super Novice
	setarray .cost,						// Cost for Jobchange
	5000,							// To first
	50000,							// To Second
	500000,							// Rebirth / Third
	50000;							// Platinum Skills
	
	// Setting adjustments by PACKETVER
	if( PACKETVER < 20161207 ) {
		if( .BabyExpanded )
			debugmes "jobmaster: BabyExpanded is disabled due to outdated PACKETVER.";
		if( .BabySummoner )
			debugmes "jobmaster: BabySummoner is disabled due to outdated PACKETVER.";
		.BabyExpanded = false;
		.BabySummoner = false;
	}
	end;
}

// NPC List
moc_para01,35,18,2	duplicate(Job Master)	Job Master#eden	10180

Problem solved - have a good one!

yani9o

Edited May 11, 2020 by yani9o

Sign In

Jobmaster Rebirth into regular Jobchange

Question

yani9o

2 answers to this question

Recommended Posts

yani9o

yani9o

Join the conversation

Recently Browsing 0 members

Docs

Get Started

Github

Community

My Account