Jump to content
  • 0

bomb poring survival error script


skuray

Question


  • Group:  Members
  • Topic Count:  8
  • Topics Per Day:  0.00
  • Content Count:  29
  • Reputation:   1
  • Joined:  07/16/18
  • Last Seen:  

Hello friends or.
This is the bomb poring event.
he announces the event, asks to give the command @je, but nothing happens ...
the option to click on npc to participate also disappears when the ads start ...
help me please

// https://rathena.org/board/topic/107940-bomb-poring-script-need-help/

prontera,175,210,4    script    Bomb Poring    1904,{
    if ( ( .@size = getvariableofnpc( .aidtotal, "runordie" ) ) >= 100 ) { // 100 participant max
        mes "["+strnpcinfo(0)+"]";
        mes "I'm sorry, the room is full";
        close;
    }
    if(getvariableofnpc( .start, "runordie" ) != 1) {
        mes "["+strnpcinfo(0)+"]";
        mes "EI! voce gostaria de se unir a mim?";
        next;
        if(select("Participar do evento!:Sair do evento!") == 2) end;
        percentheal 100, 100;
        warp "quiz_02", 334,345;
        set getvariableofnpc( .aid[ .@size ], "runordie" ), getcharid(3);
        set getvariableofnpc( .aidtotal, "runordie" ), getvariableofnpc( .aidtotal, "runordie" ) +1;
        end;
    } else {
        mes "["+strnpcinfo(0)+"]";
        mes "Desculpe o evento esta desativado no momento.";
        end;
    }
}

-    script    runordie    -1,{
OnInit:
    //disablenpc "Bomb Poring";
    //bindatcmd "runordie", strnpcinfo(0)+"::OnStart", 99,100;
    .onesec = 1000; // use for script debugging... set to 100 to make the announcement run faster
    end;
OnStart:
OnClock0010:
OnClock0110:
OnClock0210:
OnClock0310:
OnClock0356:
OnClock0420:
OnClock0610:
OnClock0710:
OnClock0810:
OnClock0910:
OnClock1010:
OnClock1110:
OnClock1210:
OnClock1310:
OnClock1410:
OnClock1510:
OnClock1610:
OnClock1710:
OnClock1810:
OnClock1910:
OnClock2010:
OnClock2110:
OnClock2210:
OnClock2310:
    deletearray .aid;
    .aidtotal = 0;
    mapwarp "quiz_02", "prontera", 140,76;
    killmonsterall "quiz_02";
    .start = 1;
    announce "Bomb Poring event is on!",bc_all,0xffccff;
    sleep 4 * .onesec;
    announce "To participate in this event please talk to me at upper part of prontera beside reset girl!",bc_all,0xffccff;
    sleep 6 * .onesec;
    announce "You only have 1 minute to register on this event!",bc_all,0xffccff;
    sleep 20 * .onesec;
    announce "30 seconds left before registration is closed!",bc_all,0xffccff;
    sleep 10 * .onesec;
    announce "To participate in this event (@je)!",bc_all,0xffccff;
    sleep 10 * .onesec;
    announce "Last 10 seconds for registrations!",bc_all,0xffccff;
    sleep 5 * .onesec;
    announce "Bomb Poring : 5",bc_all,0xffccff;
    sleep 1000;
    announce "Bomb Poring : 4",bc_all,0xffccff;
    sleep 1000;
    announce "Bomb Poring : 3",bc_all,0xffccff;
    sleep 1000;
    announce "Bomb Poring : 2",bc_all,0xffccff;
    sleep 1000;
    announce "Bomb Poring : 1",bc_all,0xffccff;
    sleep 1000;
    .start = 2;
    announce "Event is now closed.",bc_all,0xffccff;
    if ( .aidtotal < 2 ) { // cannot start event if nobody joins(0) or just having (1) player
        announce "Bomb Poring is canceled not enough players to continue!",bc_all,0xffccff;
        mapwarp "quiz_02", "prontera", 160,168;
        deletearray .aid;
        .aidtotal = 0;
        .start = 0;
        end;
    }

    mapannounce "quiz_02", "Welcome Bomb Poring!",bc_map,0xffccff;
    sleep 3 * .onesec;
    mapannounce "quiz_02", "To the players don't know this event, It its very simple!",bc_map,0xffccff;
    sleep 3 * .onesec;
    mapannounce "quiz_02", "You just need to stay AWAY from anything that you think its DANGEROUS!!",bc_map,0xffccff;
    sleep 3 * .onesec;
    mapannounce "quiz_02", "Stay alive no matter what!",bc_map,0xffccff;
    sleep 3 * .onesec;
    mapannounce "quiz_02", "The LAST SURVIVOR will be the WINNER",bc_map,0xffccff;
    sleep 3 * .onesec;
    mapannounce "quiz_02", "Event will start in 3....",bc_map,0xffccff;
    sleep 1 * .onesec;
    mapannounce "quiz_02", "2...",bc_map,0xffccff;
    sleep 1 * .onesec;
    mapannounce "quiz_02", "1..",bc_map,0xffccff;
    sleep 1 * .onesec;
    mapannounce "quiz_02", "Start Running Now!",bc_map,0xffccff;
    while ( .start ) {
        .@more += rand(1,2);
        monster "quiz_02", 0,0, "Come On Baby!!!", 1904, 2 + .@more, "", 0;
        monster "quiz_02", 0,0, "Come On Baby!!!", 1904, 2 + .@more, "", 1;
        monster "quiz_02", 0,0, "Come On Baby!!!", 1904, 2 + .@more, "", 2;
        sleep 5000;
    }
    end;
OnPCDieEvent:
OnPCLogoutEvent:
    if ( strcharinfo(3) == "quiz_02" && .start ) {
        if ( .aidtotal > 1 ) {
            for ( .@i = .aidtotal - 1; .@i >= 0; .@i-- ) {
                if ( getcharid(3) == .aid[.@i] ) {
                    deletearray .aid[.@i], 1;
                    .aidtotal--;
                }
            }
        }
        if ( .aidtotal == 1 ) {
            .start = 0;
            killmonsterall "quiz_02";
            announce "Congratulations ~ the winner is "+ rid2name(.aid),bc_all,0xffccff;
            sleep 5000;
            if ( isloggedin( .aid ) ) {
                attachrid .aid;
                getitem 20080,5; // winner prize
                warp "prontera", 160,168;
            }
            deletearray .aid;
            .aidtotal = 0;
        }
    }
    end;
}
quiz_02    mapflag    nowarp
quiz_02    mapflag    noreturn
quiz_02    mapflag    nowarpto
quiz_02    mapflag    noteleport
quiz_02    mapflag    nosave    SavePoint
quiz_02    mapflag    noskill
quiz_02    mapflag    nomemo
quiz_02    mapflag    nopenalty
quiz_02    mapflag    noicewall


 

 

Edited by Emistry
Please use codebox
Link to comment
Share on other sites

1 answer to this question

Recommended Posts

  • 0

  • Group:  Members
  • Topic Count:  4
  • Topics Per Day:  0.00
  • Content Count:  303
  • Reputation:   117
  • Joined:  12/10/16
  • Last Seen:  

There was no command.

Could you try this?

// https://rathena.org/board/topic/107940-bomb-poring-script-need-help/

prontera,175,210,4	script	Bomb Poring	1904,{
OnRegister:
	if(getvariableofnpc( .start, "runordie" ) != 1) {
		if ( getvariableofnpc( .aidtotal, "runordie" ) >= 100 ) { // 100 participant max
			mes "["+strnpcinfo(0)+"]";
			mes "I'm sorry, the room is full";
			close;
		}
		mes "["+strnpcinfo(0)+"]";
		mes "EI! voce gostaria de se unir a mim?";
		next;
		if(select("Participar do evento!:Sair do evento!") == 2) end;
		percentheal 100, 100;
		warp "quiz_02", 334,345;
		.@size = getvariableofnpc( .aidtotal, "runordie" ); // if someone just registered
		set getvariableofnpc( .aid[ .@size ], "runordie" ), getcharid(3);
		set getvariableofnpc( .aidtotal, "runordie" ), .@size +1;
		end;
	} else {
		mes "["+strnpcinfo(0)+"]";
		mes "Desculpe o evento esta desativado no momento.";
		close;
	}
}

-	script	runordie	-1,{
OnInit:
	bindatcmd "runordie", strnpcinfo(0)+"::OnStart", 99,100;
	bindatcmd "je", "Bomb Poring::OnRegister";
	.onesec = 1000; // use for script debugging... set to 100 to make the announcement run faster
	end;
OnStart:
OnClock0010:
OnClock0110:
OnClock0210:
OnClock0310:
OnClock0356:
OnClock0420:
OnClock0610:
OnClock0710:
OnClock0810:
OnClock0910:
OnClock1010:
OnClock1110:
OnClock1210:
OnClock1310:
OnClock1410:
OnClock1510:
OnClock1610:
OnClock1710:
OnClock1810:
OnClock1910:
OnClock2010:
OnClock2110:
OnClock2210:
OnClock2310:
	deletearray .aid;
	.aidtotal = 0;
	mapwarp "quiz_02", "prontera", 140,76;
	killmonsterall "quiz_02";
	.start = 1;
	announce "Bomb Poring event is on!",bc_all,0xffccff;
	sleep 4 * .onesec;
	announce "To participate in this event please talk to me at upper part of prontera beside reset girl!",bc_all,0xffccff;
	sleep 6 * .onesec;
	announce "You only have 1 minute to register on this event!",bc_all,0xffccff;
	sleep 20 * .onesec;
	announce "30 seconds left before registration is closed!",bc_all,0xffccff;
	sleep 10 * .onesec;
	announce "To participate in this event (@je)!",bc_all,0xffccff;
	sleep 10 * .onesec;
	announce "Last 10 seconds for registrations!",bc_all,0xffccff;
	sleep 5 * .onesec;
	announce "Bomb Poring : 5",bc_all,0xffccff;
	sleep 1000;
	announce "Bomb Poring : 4",bc_all,0xffccff;
	sleep 1000;
	announce "Bomb Poring : 3",bc_all,0xffccff;
	sleep 1000;
	announce "Bomb Poring : 2",bc_all,0xffccff;
	sleep 1000;
	announce "Bomb Poring : 1",bc_all,0xffccff;
	sleep 1000;
	.start = 2;
	announce "Event is now closed.",bc_all,0xffccff;
	if ( .aidtotal < 2 ) { // cannot start event if nobody joins(0) or just having (1) player
		announce "Bomb Poring is canceled not enough players to continue!",bc_all,0xffccff;
		mapwarp "quiz_02", "prontera", 160,168;
		deletearray .aid;
		.aidtotal = 0;
		.start = 0;
		end;
	}
	mapannounce "quiz_02", "Welcome Bomb Poring!",bc_map,0xffccff;
	sleep 3 * .onesec;
	mapannounce "quiz_02", "To the players don't know this event, It its very simple!",bc_map,0xffccff;
	sleep 3 * .onesec;
	mapannounce "quiz_02", "You just need to stay AWAY from anything that you think its DANGEROUS!!",bc_map,0xffccff;
	sleep 3 * .onesec;
	mapannounce "quiz_02", "Stay alive no matter what!",bc_map,0xffccff;
	sleep 3 * .onesec;
	mapannounce "quiz_02", "The LAST SURVIVOR will be the WINNER",bc_map,0xffccff;
	sleep 3 * .onesec;
	mapannounce "quiz_02", "Event will start in 3....",bc_map,0xffccff;
	sleep 1 * .onesec;
	mapannounce "quiz_02", "2...",bc_map,0xffccff;
	sleep 1 * .onesec;
	mapannounce "quiz_02", "1..",bc_map,0xffccff;
	sleep 1 * .onesec;
	mapannounce "quiz_02", "Start Running Now!",bc_map,0xffccff;
	while ( .start ) {
		.@more += rand(1,2);
		monster "quiz_02", 0,0, "Come On Baby!!!", 1904, 2 + .@more, "", 0;
		monster "quiz_02", 0,0, "Come On Baby!!!", 1904, 2 + .@more, "", 1;
		monster "quiz_02", 0,0, "Come On Baby!!!", 1904, 2 + .@more, "", 2;
		sleep 5000;
	}
	end;
OnPCDieEvent:
OnPCLogoutEvent:
	if ( strcharinfo(3) == "quiz_02" && .start ) {
		if ( .aidtotal > 1 ) {
			for ( .@i = .aidtotal - 1; .@i >= 0; .@i-- ) {
				if ( getcharid(3) == .aid[.@i] ) {
					deletearray .aid[.@i], 1;
					.aidtotal--;
				}
			}
		}
		if ( .aidtotal == 1 ) {
			.start = 0;
			killmonsterall "quiz_02";
			announce "Congratulations ~ the winner is "+ rid2name(.aid),bc_all,0xffccff;
			sleep 5000;
			if ( isloggedin( .aid ) ) {
				attachrid .aid;
				getitem 20080,5; // winner prize
				warp "prontera", 160,168;
			}
			deletearray .aid;
			.aidtotal = 0;
		}
	}
	end;
}
quiz_02	mapflag	nowarp
quiz_02	mapflag	noreturn
quiz_02	mapflag	nowarpto
quiz_02	mapflag	noteleport
quiz_02	mapflag	nosave	SavePoint
quiz_02	mapflag	noskill
quiz_02	mapflag	nomemo
quiz_02	mapflag	nopenalty
quiz_02	mapflag	noicewall

 

Edited by n0tttt
Link to comment
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

Guest
Answer this question...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
×
  • Create New...