Looking for only the guild name and all players get buff~

[crystalro]

Hello, Can anyone help me to make a script, for example a guildname is Emperor and who joined this guild Emperor's member all can get Assumption, Blessing and Agility...... not inside guild can't get buff...Thank you

[Skorm]

On 12/27/2016 at 11:36 AM, crystalro said:

Hello, Can anyone help me to make a script, for example a guildname is Emperor and who joined this guild Emperor's member all can get Assumption, Blessing and Agility...... not inside guild can't get buff...Thank you

prontera,184,177,5	script	Guild Buffer	100,{
	setarray .@sc_effect,   SC_INCREASEAGI,		SC_BLESSING,		SC_ANGELUS;
	setarray .@skil_txt$,   "Increase Agility",	"Blessing",			"Angelus";
	setarray .@ticks    ,   200000,				200000,				200000;
	setarray .@skil_num ,   29,					34,					33;
	setarray .@levels   ,   10,					10,					10;
	.@len = getarraysize(.@sc_effect);

	if( !strcmp( strcharinfo(2), "Emperor" ) ) {
		for( .@a = 0; .@a < .@len; .@a++ ) {
			misceffect 253;
			skilleffect .@skil_num[.@a], .@levels[.@a];
			sc_start .@sc_effect[.@a], .@ticks[.@a], .@levels[.@a];
			message strcharinfo(0),"Buff ["+.@skil_txt$[.@a]+"] Added.";
		}
	}
	end;
}

 

If you mean one person clicks the buffer and entire guild gets buffed... I limited it to just the guild master and only once per minute...

Spoiler

prontera,184,177,5	script	Guild All Buffer	100,{
	if( @h_last > gettimetick(2) ) end;
	set @h_last, gettimetick(2)+60;
	.@guild = getcharid(2);

	if( !strcmp( strcharinfo(2), "Emperor" ) && !strcmp( strcharinfo(0), getguildmaster( .@guild ) ) ) {
		addrid( 3, 0, .@guild );
		for( .@a = 0; .@a < .len; .@a++ ) {
			misceffect 253;
			skilleffect .skil_num[.@a], .levels[.@a];
			sc_start .sc_effect[.@a], .ticks[.@a], .levels[.@a];
			message strcharinfo(0),"Buff ["+.skil_txt$[.@a]+"] Added.";
		}
	}
	end;
	
OnInit:
	setarray .sc_effect,   SC_INCREASEAGI,		SC_BLESSING,		SC_ANGELUS;
	setarray .skil_txt$,   "Increase Agility",	"Blessing",			"Angelus";
	setarray .ticks    ,   200000,				200000,				200000;
	setarray .skil_num ,   29,					34,					33;
	setarray .levels   ,   10,					10,					10;
	.len = getarraysize(.sc_effect);
	end;
}

 

 

Edited December 30, 2016 by Skorm

[mrdominic]

in thist script, all member of the Emperor Guild will get Agi,Bless & Assump, and another guild will get just 1 buff ex:Gloria, then you can try this.


NOTE: you must check the Guild ID first.

prontera,151,188,5	script	Healer#spcgbuff	754,{

if(strcharinfo(2)==getguildname(4)) goto gemperor;	//"4" is the guild ID. You can check it in your sql database at Guild section.
    specialeffect2 14; percentheal 100,100;	 	//for another guild
	sc_start SC_GLORIA,360000,5;	 		//for another guild
	end;

gemperor:						//just for guild emperor
	specialeffect2 120; percentheal 100,100;
	sc_start SC_BLESSING,360000,10;
	sc_start SC_INCREASEAGI,360000,10;
	sc_start SC_ASSUMPTIO,360000,5;
	end;
}

 

Sorry for my bad english Xp

Edited January 3, 2017 by mrdominic
text fix