R> Custom Refiner

[ToYPiTz]

Hello rAthena im requesting a refiner. I hope someone can help me with this, I tried it myself but its too complicated for a beginner like me to make.

1. Check if its upgradable on my item.db
2. if upgradable max upgrade is +10
3. Item won't break if it fails. Safe limit +5. (No reduction on refining only on this two option "No Reduction Refine" and "Add Chance and No Reduction Refine" ((IF PLAYER)) has the "No Reduction Refine Ticket" Item ID# 6228)

4. 15% = +6

    10% = +7

      5% = +8

      3% = +9

      1% = +10

5. Has 4 menu's ("Normal Refine", "Add Chance Refine", "No Reduction Refine", "Add Chance and No Reduction Refine"

6. Has to check:

      -God Anvil Item ID# 7806 (instead of Oridecon or Elunium)

                      ~{Check on all option}

      -+5% Chance Refine Ticket Item ID# 6232 (adds 5% chance rate to success from +1 to +10)

                      ~{Only Check on "No Reduction Refine" option}

      -No Reduction Refine Ticket Item ID# 6228 (makes the chance of reduction to 0%) 

                      ~{Only Check on "No Reduction Refine", and "Add Chance and No Reduction Refine" option}

 

 

hope someone can help me on this its been in my head for so long but I just cant figure out how to make it, so that I can use it on my server.

Thanks rAthena.   

 Any reply will be much appreciated. Thank you in advance! 

Edited September 29, 2016 by ToYPiTz

[Skorm]

bump! willing to pay.

 

No need for that. Let me know if you have any problems. If you ever feel the need to delete the script from your server make sure to remove rf_opt from your sql database.

 

//https://rathena.org/board/topic/107575-r-custom-refiner/

prontera,150,192,5	script	God Refiner	4_F_KAFRA9,{
	@menu = 0;
	mes "[Sample]";
	mes "Select you refining options and click refine.";
	next;
	while( @menu != 1 ) {
		rf_opt = rf_opt ^ pow( 2, select (
			"[Refine]",
			( ( rf_opt & 4 ? "[^0000FFOn^000000] ":"[^FF0000Off^000000] " ) + "Add Chance Refine" ),
			( ( rf_opt & 8 ? "[^0000FFOn^000000] ":"[^FF0000Off^000000] " ) + "No Reduction Refine" )
		) );
	}
	
	if( !countitem( 7806 ) ) {
		mes "[Sample]";
		mes "You need at least one " + getitemname( 7806 ) + " for me to refine your items.";
		close;
	}
	
	if( ( rf_opt & 4 ) && !countitem( 6232 ) ) {
		mes "[Sample]";
		mes "You need at least one " + getitemname( 6232 ) + " to use the 'Add Chance Refine' option.";
		close;
	}
	
	if( ( rf_opt & 8 ) && !countitem( 6228 ) ) {
		mes "[Sample]";
		mes "You need at least one " + getitemname( 6228 ) + " to use the 'No Reduction Refine' option.";
		close;
	}
	
	.@i = select( 
		""+( ( .@ep = getequipid( EQI_HEAD_TOP )   +1 ) > 0 ? "^0000FF"+getitemname(getequipid( EQI_HEAD_TOP ))+"^000000" : "" ),
		""+( ( .@ep[1] = getequipid( EQI_ARMOR )   +1 ) > 0 ? "^0000FF"+getitemname(getequipid( EQI_ARMOR ))   +"^000000" : "" ),
		""+( ( .@ep[2] = getequipid( EQI_HAND_L )  +1 ) > 0 ? "^0000FF"+getitemname(getequipid( EQI_HAND_L ))  +"^000000" : "" ),
		""+( ( .@ep[3] = getequipid( EQI_HAND_R )  +1 ) > 0 ? "^0000FF"+getitemname(getequipid( EQI_HAND_R ))  +"^000000" : "" ),
		""+( ( .@ep[4] = getequipid( EQI_GARMENT ) +1 ) > 0 ? "^0000FF"+getitemname(getequipid( EQI_GARMENT )) +"^000000" : "" ),
		""+( ( .@ep[5] = getequipid( EQI_SHOES )   +1 ) > 0 ? "^0000FF"+getitemname(getequipid( EQI_SHOES ))   +"^000000" : "" ),
		( getarraysize(.@ep) ? "" : "I have nothing equipped!" )
	);
	
	if( getequipid( .@i ) != -1 || !.@ep ) {
		if ( getequipisenableref( .@i ) ) {
			.@refine = getequiprefinerycnt( .@i );
			if ( .@refine >= 10 ) {
				mes "[Sample]";
				mes "That item has already reached max level!";
				close;
			}
			delitem 7806,1;
			if ( ( rf_opt & 4 ) ) { delitem 6232,1; .@pr = .plus_refine; }
			if ( ( rf_opt & 8 ) ) { delitem 6228,1; .@rr++; }
			.@rand = rand(100) + 1;
			.@rand_refine = .refine_rates[.@refine] + .@pr;
			if( .@rand <= .@rand_refine ) {
				successrefitem .@i;
				mes "[Sample]";
				mes "Success!!!";
			} else {
				if( !.@rr ) {
					downrefitem .@i;
					mes "[Sample]";
					mes "I failed and the item lost one refine!";
				} else {
					mes "[Sample]";
					mes "I failed but your item is fine!";
				}
			}
		} else {
			mes "[Sample]";
			mes "I'm sorry but I can't refine that item!";
		}
	} else {
		mes "[Sample]";
		mes "You need to equip something first!";
	}
	close;
	
	OnInit:
		.plus_refine = 5;
		setarray .refine_rates,
			100, 100, 100, 100, 100,
			15 , 10 , 5  , 3  , 1  ;
		end;
}

[External Link]

 

P.S: Emistry I used your refiner from the other post as a base hope you don't mind. xD