Refining NPC Script

[Oraios]

Dear community,

could anyone help me to write a script of a "refiner npc" which refine's every part of the equipment (also mid and lower hg) safe to +5 and from +6 - +10 there's a chance of 25% that it refines the item to the next lvl.

 

Best regards!

[_Okuz_]

Hello Oraios, how are you buddy!?

I can do it for you. I'll be back soon with your script.

C ya!

 

EDIT--
Here is your request:

prontera,150,150,5	script	Nemir Faiax	726,{

	mes "[Nemir Faiax]";
	mes "Hello young "+(Sex ? "man" : "lady")+"!";
	mes "I'm able to refine ^FF0000all of your equipments^000000 to +5 without any price!";
	mes "Plus, from +6 to +10 there's a chance of ^FF000025% of success^000000.";
	mes "What do you think!?";
	next;
	if (select("Go ahead babe!")) {
		for (set .@i, 2; .@i < 10; set .@i, .@i + 1) {
			if (getequipid(.@i) > -1 /* && getequipisenableref(.@i) */) {
				if (getequiprefinerycnt(.@i) > 4 && getequiprefinerycnt(.@i) < 11) {
					if (rand(100) > 74) {
						successrefitem .@i;
					}
					else {
						failedrefitem .@i;
					}
				}
				else if (getequiprefinerycnt(.@i) < 5) {
					successrefitem .@i, 5;
				}
			}
		}
	}
	mes "[Nemir Faiax]";
	mes "My job here is done.";
	mes "Bye!";
	close2;
	emotion e_kis;
	end;
}

If you want to enable the refinable flag, change this:

			if (getequipid(.@i) > -1 /* && getequipisenableref(.@i) */) {

To this:

			if (getequipid(.@i) > -1 && getequipisenableref(.@i)) {

C ya!

Edited July 9, 2016 by _Okuz_

[Oraios]

Hey man, I am fine dude ;D

 

Thanks buddy!

[_Okuz_]

@Oraios
Done!     

C ya!

Edited July 9, 2016 by _Okuz_

[Oraios]

thank you a lot!