Jump to content

Npc help

tarantoda18

By tarantoda18
in Tulong para sa Server

 Share

Recommended Posts

tarantoda18 Poring

tarantoda18

Posted
  • Group:  Members
  • Topic Count:  2
  • Topics Per Day:  0.00
  • Content Count:  2
  • Reputation:   0
  • Joined:  11/17/15
  • Last Seen:  
Posted (edited)

Hi bago lang po ako nag eencode for my own server, gusto ko lang malaman kase may nakuha po akong code na kasama na naloko kase ako ng dati kong dev kaya napa wipe ng wala sa oras. eto po ung sa npc

 

 

//===== rAthena Script =======================================
//= Euphy's Quest Shop
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.6c
//===== Compatible With: =====================================
//= rAthena Project
//===== Description: =========================================
//= A dynamic quest shop based on Lunar's, with easier config.
//= Includes support for multiple shops & cashpoints.
//= Item Preview script by ToastOfDoom.
//===== Additional Comments: =================================
//= 1.0 Initial script.
//= 1.2 Added category support.
//= 1.3 More options and fixes.
//= 1.4 Added debug settings.
//= 1.5 Replaced categories with shop IDs.
//= 1.6 Added support for purchasing stackables.
//= 1.6a Added support for previewing costumes and robes.
//= 1.6b Added 'disable_items' command.
//= 1.6c Replaced function 'A_An' with "F_InsertArticle".
//============================================================


// Shop NPCs -- supplying no argument displays entire menu.
// callfunc "qshop"{,<shop ID>{,<shop ID>{,...}}};
//============================================================
prontera,139,183,6 script All in One Shop#1 901,{ callfunc "qshop"; }




// Script Core
//============================================================
- script quest_shop -1,{ 
function Add; function Chk; function Slot;
OnInit:
freeloop(1);


// -----------------------------------------------------------
//  Basic shop settings.
// -----------------------------------------------------------


set .Announce,1; // Announce quest completion? (1: yes / 0: no)
set .ShowSlot,1; // Show item slots? (2: all equipment / 1: if slots > 0 / 0: never)
set .ShowID,0;   // Show item IDs? (1: yes / 0: no)
set .ShowZeny,1; // Show Zeny cost, if any? (1: yes / 0: no)
set .MaxStack,100; // Max number of quest items purchased at one time.


// -----------------------------------------------------------
//  Points variable -- optional quest requirement.
// setarray .Points$[0],"<variable name>","<display name>";
// -----------------------------------------------------------


setarray .Points$[0],"#CASHPOINTS","Cash Points";


// -----------------------------------------------------------
//  Shop IDs -- to add shops, copy dummy data at bottom of file.
// setarray .Shops$[1],"<Shop 1>","<Shop 2>"{,...};
// -----------------------------------------------------------


setarray .Shops$[1],"Aura level 1","Aura level 2","Aura Level GOD","Mid Gear","Upper Level Demon","Upper Level Dragon";


// -----------------------------------------------------------
//  Quest items -- do NOT use a reward item more than once!
// Add(<shop ID>,<reward ID>,<reward amount>,
//     <Zeny cost>,<point cost>,
//     <required item ID>,<required item amount>{,...});
// -----------------------------------------------------------


Add(1,29116,1,0,0,7568,100,1019,300,7063,200,7448,150);
Add(1,29127,1,0,0,7568,100,1019,300,7063,200,7448,150);
Add(1,29119,1,0,0,7568,100,1019,300,7063,200,7448,150);
Add(1,29118,1,0,0,7568,100,1019,300,7063,200,7448,150);
Add(1,29117,1,0,0,7568,100,1019,300,7063,200,7448,150);


Add(2,29117,1,0,0,7561,500,4415,50,969,200);
Add(2,29129,1,0,0,969,500,1036,300,7063,500,1038,300);
Add(2,29128,1,0,0,969,500,967,250,7799,250,949,250);
Add(2,29120,1,0,0,969,500,931,700,7123,500,7447,300,4054,1);
Add(2,29130,1,0,0,969,500,29117,1,29129,1,7539,100);
Add(2,29124,1,0,0,2254,1,2255,1,969,500,7063,500,7049,150);
Add(2,29131,1,0,0,29117,1,29119,1,969,500,7539,100);


Add(3,29147,1,0,0,29126,1,969,500,7539,100,7227,300);
Add(3,29199,1,0,0,29124,1,969,500,7539,100,7227,300);
Add(3,29162,1,0,0,29130,1,969,500,7539,100,7227,300);
Add(3,29202,1,0,0,29120,1,969,500,7539,100,7227,300);
Add(3,29163,1,0,0,29128,1,969,500,7539,100,7227,300);
Add(3,29192,1,0,0,29129,1,969,500,7539,100,7227,300);
Add(3,29146,1,0,0,29288,1,969,500,7539,100,7227,300);
Add(3,29208,1,0,0,29117,1,969,500,7539,100,7227,300);


Add(4,29297,1,0,0,7227,30,1038,500,923,500,1059,500);
Add(4,29288,1,0,0,7227,30,992,300,4178,50);
Add(4,29298,1,0,0,7227,30,7561,500,912,300,701,300);
Add(4,29301,1,0,0,7227,30,969,500,4064,50);
Add(4,29289,1,0,0,7227,30,4051,50,7203,500);
Add(4,29292,1,0,0,7227,30,1019,500,7321,500);


Add(5,29229,1,0,0,7111,300,7510,25,7277,100,658,50,7221,20,7214,200);
Add(5,29228,1,0,0,7111,300,7510,25,7277,100,658,50,7221,20,7214,200);
Add(5,29233,1,0,0,7111,300,7510,25,7277,100,658,50,7221,20,7214,200);
Add(5,29232,1,0,0,7111,300,7510,25,7277,100,658,50,7221,20,7214,200);
Add(5,29231,1,0,0,7111,300,7510,25,7277,100,658,50,7221,20,7214,200);
Add(5,29230,1,0,0,7111,300,7510,25,7277,100,658,50,7221,20,7214,200);


Add(6,29243,1,0,0,29229,1,7227,100,969,200,7539,100,7097,300);
Add(6,29259,1,0,0,29228,1,7227,100,969,200,7539,100,936,300);
Add(6,29258,1,0,0,29233,1,7227,100,969,200,7539,100,932,300);
Add(6,29253,1,0,0,29232,1,7227,100,969,200,7539,100,7321,300);
Add(6,29257,1,0,0,29231,1,7227,100,969,200,7539,100,1052,300);
Add(6,29235,1,0,0,29230,1,7227,100,969,200,7539,100,911,300);




// -----------------------------------------------------------


freeloop(0);
set .menu$,"";
for(set .@i,1; .@i<=getarraysize(.Shops$); set .@i,.@i+1) {
set .menu$, .menu$+.Shops$[.@i]+":";
npcshopdelitem "qshop"+.@i,909;
}
end;


OnMenu:
set .@size, getarraysize(@i);
if (!.@size) set @shop_index, select(.menu$);
else if (.@size == 1) set @shop_index, @i[0];
else {
for(set .@j,0; .@j<.@size; set .@j,.@j+1)
set .@menu$, .@menu$+.Shops$[@i[.@j]]+":";
set @shop_index, @i[select(.@menu$)-1];
}
deletearray @i[0],getarraysize(@i);
if (.Shops$[@shop_index] == "") {
message strcharinfo(0),"An error has occurred.";
end;
}
dispbottom "Select one item at a time.";
callshop "qshop"+@shop_index,1;
npcshopattach "qshop"+@shop_index;
end;


OnBuyItem:
// .@q[] : RewardID, BoughtAmt, RewardAmt, BaseAmt, ReqZeny, ReqPts, { ReqItem, ReqAmt, ... }
setarray .@q[0],@bought_nameid[0],((@bought_quantity[0] > .MaxStack)?.MaxStack:@bought_quantity[0]);
copyarray .@q[3],getd(".q_"+@shop_index+"_"+.@q[0]+"[0]"),getarraysize(getd(".q_"+@shop_index+"_"+.@q[0]));
set .@q[2],.@q[1]*.@q[3];
if (!.@q[2] || .@q[2] > 30000) {
message strcharinfo(0),"You can't purchase that many "+getitemname(.@q[0])+".";
end;
}
mes "[Quest Shop]";
mes "Reward: ^0055FF"+((.@q[2] > 1)?.@q[2]+"x ":"")+Slot(.@q[0])+"^000000";
mes "Requirements:";
disable_items;
if (.@q[4]) mes " > "+Chk(Zeny,.@q[4]*.@q[1])+(.@q[4]*.@q[1])+" Zeny^000000";
if (.@q[5]) mes " > "+Chk(getd(.Points$[0]),.@q[5]*.@q[1])+(.@q[5]*.@q[1])+" "+.Points$[1]+" ("+getd(.Points$[0])+"/"+(.@q[5]*.@q[1])+")^000000";
if (.@q[6]) for(set .@i,6; .@i<getarraysize(.@q); set .@i,.@i+2)
mes " > "+Chk(countitem(.@q[.@i]),.@q[.@i+1]*.@q[1])+((.ShowID)?"{"+.@q[.@i]+"} ":"")+Slot(.@q[.@i])+" ("+countitem(.@q[.@i])+"/"+(.@q[.@i+1]*.@q[1])+")^000000";
next;
setarray @qe[1], getiteminfo(.@q[0],5), getiteminfo(.@q[0],11);
if (@qe[2] > 0 && ((@qe[1] & 1) || (@qe[1] & 256) || (@qe[1] & 512) || (@qe[1] & 1024) || (@qe[1] & 2048) || (@qe[1] & 4096) || (@qe[1] & 4) || (@qe[1] & 8192)))
set .@preview,1;
addtimer 1000, strnpcinfo(0)+"::OnEnd";
while(1) {
switch(select(" ~ Purchase ^0055FF"+getitemname(.@q[0])+"^000000:"+((.@preview && !@qe[7])?" ~ Preview...":"")+": ~ ^777777Cancel^000000")) {
case 1:
if (@qe[0]) { 
mes "[Quest Shop]";
mes "You're missing one or more quest requirements.";
close;
}
if (!checkweight(.@q[0],.@q[2])) {
mes "[Quest Shop]";
mes "^FF0000You need "+(((.@q[2]*getiteminfo(.@q[0],6))+Weight-MaxWeight)/10)+" additional weight capacity to complete this trade.^000000";
close;
}
if (.@q[4]) set Zeny, Zeny-(.@q[4]*.@q[1]);
if (.@q[5]) setd .Points$[0], getd(.Points$[0])-(.@q[5]*.@q[1]);
if (.@q[6]) for(set .@i,6; .@i<getarraysize(.@q); set .@i,.@i+2)
delitem .@q[.@i],.@q[.@i+1]*.@q[1];
getitem .@q[0],.@q[2];
if (.Announce) announce strcharinfo(0)+" has created "+((.@q[2] > 1)?.@q[2]+"x "+getitemname(.@q[0]):callfunc("F_InsertArticle",getitemname(.@q[0])))+"!",0;
specialeffect2 EF_FLOWERLEAF;
close;
case 2:
setarray @qe[3], getlook(LOOK_HEAD_BOTTOM), getlook(LOOK_HEAD_TOP), getlook(LOOK_HEAD_MID), getlook(LOOK_ROBE), 1;
if ((@qe[1] & 1) || (@qe[1] & 4096)) changelook LOOK_HEAD_BOTTOM, @qe[2];
else if ((@qe[1] & 256) || (@qe[1] & 1024)) changelook LOOK_HEAD_TOP, @qe[2];
else if ((@qe[1] & 512) || (@qe[1] & 2048)) changelook LOOK_HEAD_MID, @qe[2];
else if ((@qe[1] & 4) || (@qe[1] & 8192)) changelook LOOK_ROBE, @qe[2];
break;
case 3:
close;
}
}


OnEnd:
if (@qe[7]) {
changelook LOOK_HEAD_BOTTOM, @qe[3];
changelook LOOK_HEAD_TOP, @qe[4];
changelook LOOK_HEAD_MID, @qe[5];
changelook LOOK_ROBE, @qe[6];
}
deletearray @qe[0],8;
end;


function Add {
if (getitemname(getarg(1)) == "null") {
debugmes "Quest reward #"+getarg(1)+" invalid (skipped).";
return;
}
setarray .@j[0],getarg(2),getarg(3),getarg(4);
for(set .@i,5; .@i<getargcount(); set .@i,.@i+2) {
if (getitemname(getarg(.@i)) == "null") {
debugmes "Quest requirement #"+getarg(.@i)+" invalid (skipped).";
return;
} else
setarray .@j[.@i-2],getarg(.@i),getarg(.@i+1);
}
copyarray getd(".q_"+getarg(0)+"_"+getarg(1)+"[0]"),.@j[0],getarraysize(.@j);
npcshopadditem "qshop"+getarg(0),getarg(1),((.ShowZeny)?getarg(3):0);
return;
}


function Chk {
if (getarg(0) < getarg(1)) {
set @qe[0],1;
return "^FF0000";
} else
return "^00FF00";
}


function Slot {
set .@s$,getitemname(getarg(0));
switch(.ShowSlot) {
case 1: if (!getitemslots(getarg(0))) return .@s$;
case 2: if (getiteminfo(getarg(0),2) == 4 || getiteminfo(getarg(0),2) == 5) return .@s$+" ["+getitemslots(getarg(0))+"]";
default: return .@s$;
}
}
}


function script qshop {
deletearray @i[0],getarraysize(@i);
for(set .@i,0; .@i<getargcount(); set .@i,.@i+1)
set @i[.@i],getarg(.@i);
doevent "quest_shop::OnMenu";
end;
}




// Dummy shop data -- copy as needed.
//============================================================
- shop qshop1 -1,909:-1
- shop qshop2 -1,909:-1
- shop qshop3 -1,909:-1
- shop qshop4 -1,909:-1
- shop qshop5 -1,909:-1




prontera,241,233,5 duplicate(All in One Shop#1) All in One NPC#46 446
kaso wala ng pong lumalabas dun sa number 6th shop pano kaya ma fifix un?
Edited by Radian
please apply codebox next time thanks!
Link to comment
Share on other sites
Radian Drops

Radian

Posted
  • Group:  Members
  • Topic Count:  162
  • Topics Per Day:  0.04
  • Content Count:  1546
  • Reputation:   192
  • Joined:  07/23/14
  • Last Seen:  
Posted 
- shop qshop6 -1,909:-1
- shop qshop7 -1,909:-1
- shop qshop8 -1,909:-1
- shop qshop9 -1,909:-1
- shop qshop10 -1,909:-1

add that below this line

// Dummy shop data -- copy as needed.
//============================================================
- shop qshop1 -1,909:-1
- shop qshop2 -1,909:-1
- shop qshop3 -1,909:-1
- shop qshop4 -1,909:-1
- shop qshop5 -1,909:-1
Link to comment
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

Guest
Reply to this topic...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
 Share
Go to topic listing
×
×
  • Create New...