Jump to content

archilles89

Members
 View Profile  See their activity

  • Posts

    72

  • Joined

  • Last visited

 Content Type 

Posts posted by archilles89

    help Costume Headgears functions as "Skin" for original headgear?

    in Database Support

    Posted · Edited by archilles89

    Hello, as the title states, I am trying to make a sort of "skin" function on an original item. What I plan is to have for example a person wearing Hat[1], only if the said person is wearing Hat[1] will he/she be able to equip a variety of Hat[1] recolors (Blue/Green/Black/Gold/White) as Costume. Keep in mind I am talking about Costume (Loc: 1024, 2048, 4096) not Custom Items.

     

    Essentially, I have a whole set of recolors of Hat[1] and I want players wearing the original Hat[1] to be able to wear those recolors as costumes. But ONLY IF the said player is wearing Hat[1].

    If the player is not wearing the original Hat[1], he/she will not be able to equip the recolors at Loc #1024.

     

    Can this be edited in the item's script itself?

    ~AnnieRuru~'s Private MVP Room v1.4

    in Scripting Support

    Posted · Edited by archilles89

     

    try to search for the similar topic....  this has been asked several times

     

    Done

    that. Almost all of the problems related to ~AnnieRuru~'s Private MVP

    Room v1.4 has identifiable errors in their scripts. Mine loads perfectly

    in map_server without any errors but hangs or stuck right after someone

    clicked the NPC. Thanks for the reply though!

     

     

     

    Annie  has updated  her script  to rev  1.4a

    http://rathena.org/board/topic/72376-mvp-summon-script/?p=146696

     

    Thank you! It worked! The thought that the script's compatibility with rAthena didn't even crossed my mind. Thanks again!

     

    Err, quick question, how do I change the title to solved?

    ~AnnieRuru~'s Private MVP Room v1.4

    in Scripting Support

    Posted

    try to search for the similar topic....  this has been asked several times

     

    Done that. Almost all of the problems related to ~AnnieRuru~'s Private MVP Room v1.4 has identifiable errors in their scripts. Mine loads perfectly in map_server without any errors but hangs or stuck right after someone clicked the NPC. Thanks for the reply though!

    ~AnnieRuru~'s Private MVP Room v1.4

    in Scripting Support

    Posted · Edited by archilles89

    Hello, as the title state, I am having a few issues with ~AnnieRuru~'s Private MVP Room script version 1.4. I have managed to get the script to load in map_server without any errors. But when in game, It would stuck right after someone clicked the "Private MVP Room" NPC. Can someone take a look at this? Perhaps I am not doing it right somehow?

    Here is the script:

    //	....... if your server has { Overwriting user function [int__] } don't blame me ..........
function	script	int__	{
	set .@num, atoi(getarg(0));
	if ( .@num == 0 || .@num >= 2147483647 ) return getarg(0);
	set .@l, getstrlen(.@num);
	for ( set .@i,0; .@i < .@l; set .@i, .@i + 1 ) {
		set .@num$, .@num % pow(10,.@i+1) / pow(10,.@i) + .@num$;
		if ( (.@i+1) % 3 == 0 && .@i+1 != .@l ) set .@num$, ","+ .@num$;
	}
	return .@num$;
}

//===== eAthena Script ======================================
//= Private MVP/Branch Room
//===== By: ===============================================
//= by ~AnnieRuru~
//===== Current Version: ======================================
//= 1.3
//===== Compatible With: ===================================== 
//= eAthena 11650 Trunk above or 11863 Stable above
//===== Description: ========================================= 
//= Player can rent MVP room for the player him/herself, for party or for guilds
//===== Topic =================================================
//= http://www.eathena.ws/board/index.php?showtopic=187654
//===== Additional Comments: ================================== 
//= 1.0 
//= ---- break the tradition which a script only for a player, or only for a party.
//=      now 1 room can be use for party and another room can use for guilds.
//= ---- timeout feature to prevent player owns the room indefinitely,
//=      by create a new account and sit/@at'ing inside overnight.
//= ---- can disable mvp/boss summon via configuration and becomes a branch room script.
//= ---- a double check to prevent players rent all the rooms for himself.
//= 1.0a
//= ---- fix a critial bug that the time count too fast -_-"
//= 1.1
//= ---- added item cost to rent or to summon
//= ---- added a config to limit summoning per session
//= ---- added flood control option
//= 1.2
//= ---- rewrite the waitingroom counter
//= ---- optimize the script in a way can add custom summon group
//= ---- add config to kill the monsters if the room just being left empty
//= ---- add GM can kick room in use
//= ---- add able to spawn in numbers
//= ---- add limitspawn can configure to negative to limit spawn in that group instead of individual one
//= 1.3
//= ---- fix chatroom countdown issue due to rev13269
//= ---- fix a bug if 2 people rent a room at same time, the later 1 will get the room
//= ---- add a feature so the GM can know how long the room has rented or abandoned
//= 1.4
//= ---- update with new mvp and mini bosses
//= ---- fix an exploit if server allow to use @mail, player can send item/zeny away to prevent item/zeny deletion when registering the room
//= ---- players die inside mvp room shouldn't lose exp
//========================================================

//	This is the shop for this Branch room IF you already enable it. Can sell whatever things you want.
-	shop	MVP Room#branch	-1,607:250000,608:200000



-	script	MVP Summoner	-1,{
	goto L_Start;

OnInit:
	getmapxy .@map$, .@x, .@y, 1;
	if ( .@map$ == "" ) {

//	Config ---------------------------------------------------------------------------------------

	// Time for rent a room IN MINUTES. When time out, players inside the room will kick out. Do Not set this as 0
	set .timeout, 60;
	// if the room left empty for # minutes, will be treated as give up the room. Do Not set this as 0
	set .nobodygiveup, 5;

	// NOTE : The script only search item OR zeny. if you specify item amount, then it will ask for the item. If item amount is 0, then it will ask for zeny.

	// the cost to rent a room
	set .rentitemid, 674; // item id use for rent a room - 674 - mithil coin
	set .rentitemamount, 0; // amount of items to rent a room
	set .rentcost, 1000000; // otherwise, zeny cost to rent a room

	// limit each room can only summon 1 monster at a time. (only the Summoning option)
	// Turn it off (0) means the player can summon a lot of monsters as long as the player has enough zeny/item. High rate server players love the room with a lot MVPs
	// Turn it on (1) means the player have to kill existing monster before can summon a new one. Low rate server player prefer to take out MVP 1 by 1
	set .floodcontrol, 1;

	// if .floodcontrol is turn off, your players might experience lag if they summoned too many MVPs
	// so what is the maximum input to limit your players summon too many ?
	set .inputlimit, 30;

	// If the room has left over monsters while nobody in the room and the room not give up yet, shall we kill monsters in empty room ?
	set .killmonster, 1; // Default is yes

	//	Options menu setting for MVP Summoner NPC.
	set .@menu[0], 1; // Turn Heal option On/Off
	set .@menu[1], 1; // Turn Group 1 summons On/Off -> MVP
	set .@menu[2], 1; // Turn Group 2 summons On/Off -> mini boss
	set .@menu[3], 1; // Turn Group 3 summons On/Off
	set .@menu[4], 1; // Turn Group 4 summons On/Off
	set .@menu[5], 0; // Turn Group 5 summons On/Off
	set .@menu[6], 0; // Turn Group 6 summons On/Off
	set .@menu[7], 0; // Turn Group 7 summons On/Off
	set .@menu[8], 0; // Turn Group 8 summons On/Off
	set .@menu[9], 0; // Turn Group 9 summons On/Off
	set .@menu[10], 1; // Sell shop items options On/Off ( shop npc above )

	//	set respawn point when they leave the room. Obviously warp to the Private MVP Room Warper npc
	set .respawnmap$, "dewata"; // Note : "SavePoint" does NOT work
	set .respawnx, 200;
	set .respawny, 180;

	// The minimum GM level can kick a room in use
	set .gmlvlkick, 80;

	// .limitspawn in previous revision changed to .grouplimit .
	// it is for limit each monster spawn per session, prevent them only killing same monster again and again
	// Now you can configure one group has limited summon, and another group has unlimited summon
	// Tips: if you server has an insane custom MVP, you can put your custom mob to Group 3~9 with insane item cost, and limit only 1 summon per session
	// .grouplimit use amount, means if group1limit set to 10, then each session can only summon up to 10 amount of that kind of monster. 0 is unlimited

	// ---------
	// Group 1 -> Normal MVP 
	// ---------
	set .group1name$, "Normal MVP"; // Group 1 name
	set .group1itemid, 674; // item id use for summon any Group 1 monster - 674 - mithil coin
	set .group1itemamount, 0; // amount of items to summon a Group 1 monster
	set .group1cost, 10000000; // if no item is specify, zeny cost to summon a Group 1 monster
	set .group1limit, 30; // limit of summon of Group 1 monster per session, prevent them only killing same monster again and again
	setarray .group1id,
		1511,//	Amon Ra
		1039,//	Baphomet
		1272,//	Dark Lord
		1719,//	Datale
		1046,//	Doppelgangger
		1389,//	Dracula
		1112,//	Drake
		1115,//	Eddga
		1418,//	Evil Snake Lord
		1252,//	Garm
		1086,//	Golden Thief Bug
		1492,//	Incantation Samurai
		1251,//	Knight of Windstorm
	//	1980,//	Kubkin ( I think this mvp is still new )
		1147,//	Maya
		1059,//	Mistress
		1150,//	Moonlight Flower
		1087,//	Orc Hero
		1190,//	Orc Lord
		1038,//	Osiris
		1157,//	Pharaoh
		1159,//	Phreeoni
		1623,//	RSX 0806
		1312;//	Turtle General

	// ---------
	// Group 2 -> Rare MVP
	// ---------
	set .group2name$, "Rare MVP"; // Group 2 name
	set .group2itemid, 674; // item id use for summon any Group 2 monster - 674 - mithil coin
	set .group2itemamount, 0; // amount of items to summon a Group 2 monster
	set .group2cost, 15000000; // if no item is specify, zeny cost to summon a Group 2 monster
	set .group2limit, 30; // limit of summon of Group 2 monster per session, prevent them only killing same monster again and again
	setarray .group2id,
		1785,// Atroce
		1630,// Bacsojin
		1768,// Gloom Under Night
		1734,// Kiel D-01
		1779,// Ktullanux
		1373,// Lord of Death
		1583;// Tao Gunka

	// ---------
	// Group 3 -> Exotic MVP
	// ---------
	set .group3name$, "Exotic MVP"; // Group 3 name
	set .group3itemid, 12109; // item id use for summon any Group 3 monster - 12109 - Poring box
	set .group3itemamount, 0; // amount of items to summon a Group 3 monster
	set .group3cost, 20000000; // if no item is specify, zeny cost to summon a Group 3 monster
	set .group3limit, 30; // limit of summon of Group 3 monster per session, prevent them only killing same monster again and again
	setarray .group3id,
		1874,//	Beelzebub
		1871,//	Fallen Bishop
		1649,// High Priest Magaleta
		2110,// Ifrit
		1688,//	Lady Tanee
		1650,// Sniper Shecil
		1751,//	Valkyrie Randgris
		1685,// Vesper
		1658;//	Ygnizem

	// ---------
	// Group 4 -> Legendary MVP
	// ---------
	set .group4name$, "Legendary MVP"; // Group 4 name
	set .group4itemid, 0; // item id use for summon any Group 4 monster
	set .group4itemamount, 0; // amount of items to summon a Group 4 monster
	set .group4cost, 25000000; // if no item is specify, zeny cost to summon a Group 4 monster
	set .group4limit, 30; // limit of summon of Group 4 monster per session, prevent them only killing same monster again and again
	setarray .group4id,
		1647,// Assassin Cross Eremes
		1651,// High Wizard Katrinn
		1646,// Lord Knight Seyren
		1708,//	Thanatos
		1648,// Whitesmith Harword
		1917;// Wounded Morroc

	// ---------
	// Group 5 -> mini boss
	// ---------
	set .group5name$, "Mini Boss"; // Group 5 name
	set .group5itemid, 674; // item id use for summon any Group 5 monster
	set .group5itemamount, 0; // amount of items to summon a Group 5 monster
	set .group5cost, 10000; // if no item is specify, zeny cost to summon a Group 5 monster
	set .group5limit, 30; // limit of summon of Group 5 monster per session, prevent them only killing same monster again and again
	setarray .group5id,
		1096,// Angeling
		1388,// Archangeling
		1795,// Bloody Knight
		1830,// Bow Guardian
		1839,// Byorgue
		1309,// Cat O' Nine Tail
		1283,// Chimera
		1302,// Dark Illusion
		1198,// Dark Priest
		1582,// Deviling
		1091,// Dragon Fly
		1093,// Eclipse
		1205,// Executioner
		1783,// Galion
		1592,// Gangster
		1120,// Ghostring
		1259,// Gryphon
		1720,// Hydro
		1090,// Mastering
		1289,// Maya Purple
		1262,// Mutant Dragon
		1203,// Mysteltainn
		1870,// Necromancer
		1295,// Owl Baron
		1829,// Sword Guardian
		1204,// Tirfing
		1089,// Toad
		1092,// Vagabond Wolf
		1765;// Valkyrie

	// ---------
	// Group 6
	// ---------
	set .group6name$, "Poring-Family"; // Group 6 name
	set .group6itemid, 12109; // item id use for summon any Group 6 monster
	set .group6itemamount, 0; // amount of items to summon a Group 6 monster
	set .group6cost, 100000; // if no item is specify, zeny cost to summon a Group 6 monster
	set .group6limit, 30; // limit of summon of Group 6 monster per session, prevent them only killing same monster again and again
	setarray .group6id,
		1002,// Poring
		1113,// Drops
		1031,// Poporing
		1242,// Marin
		1062,// Santa Poring
		1613,// Metaling
		1784,// Stapo
		1090,// Mastering
		1096,// Angeling
		1120,// Ghostring
		1582,// Deviling
		1388,// Arc Angeling
		1502;// Pori Pori

	// ---------
	// Group 7
	// ---------
	set .group7name$, ""; // Group 7 name
	set .group7itemid, 0; // item id use for summon any Group 7 monster
	set .group7itemamount, 0; // amount of items to summon a Group 7 monster
	set .group7cost, 0; // if no item is specify, zeny cost to summon a Group 7 monster
	set .group7limit, 0; // limit of summon of Group 7 monster per session, prevent them only killing same monster again and again
	setarray .group7id,
		1001,
		1002;

	// ---------
	// Group 8
	// ---------
	set .group8name$, ""; // Group 8 name
	set .group8itemid, 0; // item id use for summon any Group 8 monster
	set .group8itemamount, 0; // amount of items to summon a Group 8 monster
	set .group8cost, 0; // if no item is specify, zeny cost to summon a Group 8 monster
	set .group8limit, 0; // limit of summon of Group 8 monster per session, prevent them only killing same monster again and again
	setarray .group8id,
		1001,
		1002;

	// ---------
	// Group 9
	// ---------
	set .group9name$, ""; // Group 9 name
	set .group9itemid, 0; // item id use for summon any Group 9 monster
	set .group9itemamount, 0; // amount of items to summon a Group 9 monster
	set .group9cost, 0; // if no item is specify, zeny cost to summon a Group 9 monster
	set .group9limit, 0; // limit of summon of Group 9 monster per session, prevent them only killing same monster again and again
	setarray .group9id,
		1001,
		1002;

//	Config Ends ------------------------------------------------------------------------

		if ( .timeout == 0 ) set .timeout, 60;
		if ( .nobodygiveup == 0 ) set .nobodygiveup, 5;
		if ( .inputlimit < 1 ) set .inputlimit, 1;

		if ( .rentitemid && .rentitemamount ) {
			if ( getitemname(.rentitemid) == "null" ) {
				debugmes "Private MVP Room: Rent a room is using invalid item id.";
			}
		}
		set .@i, 1;
		while ( .@i <= 9 ) {
			if ( .@menu[.@i] && getd(".group"+ .@i +"itemid") && getd(".group"+ .@i +"itemamount") ) {
				if ( getitemname( getd(".group"+ .@i +"itemid") ) == "null" ) {
					debugmes "Private MVP Room: Group no. "+ .@i +" is using invalid item id.";
				}
			}
			set .@i, .@i +1 ;
		}
		set .menu$, ( (.@menu[0])?"Heal":"" )+":"+( (.@menu[1])?"Summon "+ .group1name$:"" )+":"+( (.@menu[2])?"Summon "+ .group2name$:"" )+":"+( (.@menu[3])?"Summon "+ .group3name$:"" )+":"+( (.@menu[4])?"Summon "+ .group4name$:"" )+":"+( (.@menu[5])?"Summon "+ .group5name$:"" )+":"+( (.@menu[6])?"Summon "+ .group6name$:"" )+":"+( (.@menu[7])?"Summon "+ .group7name$:"" )+":"+( (.@menu[8])?"Summon "+ .group8name$:"" )+":"+( (.@menu[9])?"Summon "+ .group9name$:"" )+":"+( (.@menu[10])?"Buy branches":"" )+":Leave this room:Give up this room";

		set .@i, 1;
		while ( .@i <= 9 ) {
			setd ".group"+ .@i +"idsize", getarraysize( getd(".group"+ .@i +"id") );
			if ( .@menu[.@i] && getd(".group"+ .@i +"limit") <= 0 ) {
				set .@j, 0;
				while ( .@j < getd(".group"+ .@i +"idsize") ) {
					setd ".group"+ .@i +"menu$", getd(".group"+ .@i +"menu$") + getmonsterinfo( getd(".group"+ .@i +"id["+ .@j +"]"), 0) +":";
					set .@j, .@j +1 ;
				}
			}
			set .@i, .@i +1 ;
		}
	}
	else {
		sleep 1;
		mapannounce .@map$, "Admin has refresh the server, please register the room again.", 1;
		mapwarp .@map$, .respawnmap$, .respawnx, .respawny;
	}
	end;

L_Start: // I hate gotos ... but ...
	set .@dif, strnpcinfo(2);
	if ( .remind[.@dif] == 0 ) {
		set .remind[.@dif], 1;
		initnpctimer;
	}
	mes "[MVP Summoner]";
	mes "Hi, what can I do for you ?";
	next;
	switch ( select(.menu$) ) {
		case 1:
			mes "[MVP Summoner]";
			if ( getmapmobs("this") > 0 ) {
				mes "I cannot offer heal service when there are monsters around.";
				close;
			}
			sc_end sc_stone;
			sc_end sc_slowdown;
			sc_end sc_freeze;
			sc_end sc_sleep;
			sc_end sc_curse;
			sc_end sc_silence;
			sc_end sc_confusion;
			sc_end sc_blind;
			sc_end sc_bleeding;
			sc_end sc_decreaseagi;
			sc_end sc_poison;
			sc_end sc_hallucination;
			sc_end sc_stripweapon;
			sc_end sc_striparmor;
			sc_end sc_striphelm;
			sc_end sc_stripshield;
			sc_end sc_changeundead;
			sc_end sc_orcish;
			sc_end sc_berserk;
			sc_end sc_ske;
			sc_end sc_swoo;
			sc_end sc_ska;
			percentheal 100,100;
			specialeffect2 7;
			sc_start SC_INCREASEAGI,600000,10;
			specialeffect2 EF_INCAGILITY;
			sc_start SC_BLESSING,600000,10;
			specialeffect2 EF_BLESSING;
			mes "You have completely healed.";
			close;
		default:
			set .@group, @menu -1;
			if ( .floodcontrol && getmapmobs("this") > 0 ) {
				mes "[MVP Summoner]";
				mes "I cannot summon another monster when there are monsters around.";
				close;
			}
			else if ( getd(".group"+ .@group +"itemid") && getd(".group"+ .@group +"itemamount") ) {
				mes "[MVP Summoner]";
				mes "The cost to summon a "+ getd(".group"+ .@group +"name$") +" is "+ getd(".group"+ .@group +"itemamount") +" "+ getitemname( getd(".group"+ .@group +"itemid") ) +".";
				if ( getd(".group"+ .@group +"limit") < 0 )
					mes "("+( ( ~getd(".group"+ .@group +"limit")+1 - getd(".group"+ .@group +"limit"+ .@dif) <= 0 )?0:( ~getd(".group"+ .@group +"limit")+1 - getd(".group"+ .@group +"limit"+ .@dif) ) )+") more summons for this group.";
				next;
			}
			else if ( getd(".group"+ .@group +"cost") ) {
				mes "[MVP Summoner]";
				mes "The cost to summon a "+ getd(".group"+ .@group +"name$") +" is "+ callfunc("int__", getd(".group"+ .@group +"cost") ) +" zeny.";
				if ( getd(".group"+ .@group +"limit") < 0 )
					mes "("+( ( ~getd(".group"+ .@group +"limit")+1 - getd(".group"+ .@group +"limit"+ .@dif) <= 0 )?0:( ~getd(".group"+ .@group +"limit")+1 - getd(".group"+ .@group +"limit"+ .@dif) ) )+") more summons for this group.";
				next;
			}
			else if ( getd(".group"+ .@group +"limit") < 0 ) {
				mes "[MVP Summoner]";
				mes "("+( ( ~getd(".group"+ .@group +"limit")+1 - getd(".group"+ .@group +"limit"+ .@dif) <= 0 )?0:( ~getd(".group"+ .@group +"limit")+1 - getd(".group"+ .@group +"limit"+ .@dif) ) )+") more summons for this group.";
				next;
			}
			if ( getd(".group"+ .@group +"limit") < 0 && getd(".group"+ .@group +"limit"+ .@dif) >= ~getd(".group"+ .@group +"limit")+1 ) {
				mes "[MVP Summoner]";
				mes "I'm sorry, but you can't summon any more monster for this group.";
				close;
			}
			else if ( getd(".group"+ .@group +"limit") > 0 ) {
				for ( set .@i, 0; .@i < getd(".group"+ .@group +"idsize"); set .@i, .@i +1 )
					set .@menu$, .@menu$ +( ( getd(".group"+ .@group +"limit"+ .@dif +"["+ .@i +"]") >= getd(".group"+ .@group +"limit") )?"^999999":"^000000" )+ getmonsterinfo( getd(".group"+ .@group +"id["+ .@i +"]"), 0) +" ("+ ( ( getd(".group"+ .@group +"limit") - getd(".group"+ .@group +"limit"+ .@dif +"["+ .@i +"]") <= 0 )?0:( getd(".group"+ .@group +"limit") - getd(".group"+ .@group +"limit"+ .@dif +"["+ .@i +"]") ) ) +")"+":";
				set .@menu, select(.@menu$) -1;
			}
			else
				set .@menu, select( getd(".group"+ .@group +"menu$") ) -1;
			mes "[MVP Summoner]";
			if ( .floodcontrol == 0 && .inputlimit > 1 ) {
				mes "Input an amount of monsters to summon.";
				next;
				input .@amount;
				if ( .@amount == 0 ) close;
				else if ( .@amount > .inputlimit )
					set .@amount, .inputlimit;
				mes "[MVP Summoner]";
			}
			else
				set .@amount, 1;
			if ( getd(".group"+ .@group +"itemid") && getd(".group"+ .@group +"itemamount") ) {
				if ( countitem( getd(".group"+ .@group +"itemid") ) < getd(".group"+ .@group +"itemamount") * .@amount ) {
					mes "You don't have enough "+ getitemname( getd(".group"+ .@group +"itemid") ) +" to summon a "+ getd(".group"+ .@group +"name$") +".";
					close;
				}
			}
			else if ( getd(".group"+ .@group +"cost") ) {
				if ( zeny < getd(".group"+ .@group +"cost") * .@amount ) {
					mes "You don't have enough zeny to summon a "+ getd(".group"+ .@group +"name$") +".";
					close;
				}
			}
			if ( .floodcontrol && getmapmobs("this") > 0 ) {
				mes "I cannot summon another monster when there are monsters around.";
				close;
			}
			else if ( getd(".group"+ .@group +"limit") > 0 ) {
				if ( getd(".group"+ .@group +"limit"+ .@dif +"["+ .@menu +"]") >= getd(".group"+ .@group +"limit") ) {
					mes "I'm sorry, but you already summoned that monster too much. Try summon another.";
					close;
				}
				else if ( getd(".group"+ .@group +"limit"+ .@dif +"["+ .@menu +"]") + .@amount > getd(".group"+ .@group +"limit") ) {
					mes "The amount you input is more than the limit you can summon. Try reduce the amount.";
					close;
				}
			}
			else if ( getd(".group"+ .@group +"limit") < 0 ) {
				if ( getd(".group"+ .@group +"limit"+ .@dif) >= ~getd(".group"+ .@group +"limit")+1 ) {
					mes "I'm sorry, but you can't summon any more monster for this group.";
					close;
				}
				else if ( getd(".group"+ .@group +"limit"+ .@dif) + .@amount > ~getd(".group"+ .@group +"limit")+1 ) {
					mes "The amount you input is more than the limit you can summon. Try reduce the amount.";
					close;
				}
			}
			mes "Summoning "+ .@amount +" "+ getmonsterinfo( getd(".group"+ .@group +"id["+ .@menu +"]"), 0) +".";
			mes "Ok, get ready ?";
			close2;
			if ( .floodcontrol && getmapmobs("this") > 0 ) end;
			if ( getd(".group"+ .@group +"itemid") && getd(".group"+ .@group +"itemamount") ) {
				if ( countitem( getd(".group"+ .@group +"itemid") ) < getd(".group"+ .@group +"itemamount") * .@amount ) end;
				delitem getd(".group"+ .@group +"itemid"), getd(".group"+ .@group +"itemamount") * .@amount;
			}
			else if ( getd(".group"+ .@group +"cost") ) {
				if ( zeny < getd(".group"+ .@group +"cost") * .@amount ) end;
				set zeny, zeny - getd(".group"+ .@group +"cost") * .@amount;
			}
			if ( getd(".group"+ .@group +"limit") > 0 ) {
				if ( getd(".group"+ .@group +"limit"+ .@dif +"["+ .@menu +"]") + .@amount > getd(".group"+ .@group +"limit") ) end;
				setd ".group"+ .@group +"limit"+ .@dif +"["+ .@menu +"]", getd(".group"+ .@group +"limit"+ .@dif +"["+ .@menu +"]") + .@amount;
			}
			else if ( getd(".group"+ .@group +"limit") < 0 ) {
				if ( getd(".group"+ .@group +"limit"+ .@dif) + .@amount > ~getd(".group"+ .@group +"limit")+1 ) end;
				setd ".group"+ .@group +"limit"+ .@dif, getd(".group"+ .@group +"limit"+ .@dif) + .@amount;
			}
			monster "this", 0, 0, "--ja--", getd(".group"+ .@group +"id["+ .@menu +"]"), .@amount;
			end;
		case 11:
			if ( getmapmobs("this") > 0 ) {
				mes "[MVP Summoner]";
				mes "I cannot offer this service when there are monsters around.";
				close;
			}
			close2;
			callshop "MVP room#branch", 0;
			end;
		case 12:
			mes "[MVP Summoner]";
			mes "Are you sure you want to leave this room ?";
			mes "If this room left empty for more than "+ .nobodygiveup +" minutes, you lost ownership for this room.";
			if ( select( "Yes:No") == 2 ) close;
			warp .respawnmap$, .respawnx, .respawny;
			end;
		case 13:
			mes "[MVP Summoner]";
			getmapxy .@map$, .@x, .@y, 0;
			if ( getmapusers(.@map$) > 1 ) {
				mes "There are still some players in this room. Make sure you are the last member in this room to use this option.";
				close;
			}
			mes "Are you sure you want to give up this room ?";
			if ( .rentcost )
				mes "You will need to pay again to enter this room.";
			next;
			if ( select( "Yes:No" ) == 2 ) close;
			warp .respawnmap$, .respawnx, .respawny;
			set .remaintime[.@dif], -1;
			end;
	}
	close;

OnEnterMap:
	set .@dif, strnpcinfo(2);
	set .remind[.@dif], 0;
	for ( set .@i, 1; .@i <= 9; set .@i, .@i +1 )
		deletearray getd(".group"+ .@i +"limit"+ .@dif), getd(".group"+ .@i +"idsize");
	set .nobodycounter[.@dif], 0;
	getmapxy .@map$, .@x, .@y ,1;
	set .starttime[.@dif], gettimetick(2);
	do {
		set .remaintime[.@dif], .timeout * 60 + .starttime[.@dif] - gettimetick(2);
		set .@hour[.@dif], .remainTime[.@dif] / 3600 ;
		set .@min[.@dif], .remainTime[.@dif] % 3600 / 60 ;
		set .@sec[.@dif], .remainTime[.@dif] % 3600 % 60 ;
		delwaitingroom strnpcinfo(0);
		waitingroom "Time Left = "+( ( .@hour[.@dif] )?( .@hour[.@dif] +":"):"" )+( ( .@min[.@dif] < 10 )?"0"+ .@min[.@dif]: .@min[.@dif] )+":"+( ( .@sec[.@dif] < 10 )?"0"+ .@sec[.@dif]: .@sec[.@dif] ), 0;
		if ( getmapusers(.@map$) )
			set .nobodycounter[.@dif], 0;
		else {
			set .nobodycounter[.@dif], .nobodycounter[.@dif] +1 ;
			if ( .nobodycounter[.@dif] > .nobodygiveup * 60 ) break;
		}
		sleep 995;
	} while ( .remaintime[.@dif] > 1 );
	set .remaintime[.@dif], 0;
	delwaitingroom "MVP Summoner#"+ .@dif;
	mapwarp .@map$, .respawnmap$, .respawnx, .respawny;
	end;

OnTimer100:
	stopnpctimer;
	npctalk "Hi ~ the bubble above my head is the countdown for using this room.";
	sleep 2000;
	npctalk "Sometimes, I can skip for about 1 second in the countdown.";
	sleep 3000;
	npctalk "That is because the server is experiencing minor lag problem.";
	sleep 3000;
	npctalk "So, don't complain about me cheated for the countdown ~ ^.^";
	sleep 3000;
	npctalk "Have a nice day ~";
	end;
}

dewata,209,168,4	script	Private MVP Room	450,{
	mes "[Private MVP Room]";
	mes "Please select a private MVP room.";
	next;
	if ( getvariableofnpc(.rentitemid, "MVP Summoner") && getvariableofnpc(.rentitemamount, "MVP Summoner") )
		mes "The cost to rent a room for "+ getvariableofnpc(.timeout, "MVP Summoner") +" minutes is "+ getvariableofnpc(.rentitemamount, "MVP Summoner") +" "+ getitemname( getvariableofnpc(.rentitemid, "MVP Summoner") ) +".";
	else if ( getvariableofnpc(.rentcost, "MVP Summoner") )
		mes "The cost to rent a room for "+ getvariableofnpc(.timeout, "MVP Summoner") +" minutes is "+ callfunc("int__", getvariableofnpc(.rentcost, "MVP Summoner") ) +" zeny.";
	else
		mes "You can only use the room for only "+ getvariableofnpc(.timeout, "MVP Summoner") +" minutes.";
	mes " ";
	for ( set .@i, 1; .@i <= 8; set .@i, .@i +1 ) {
		if ( getvariableofnpc(.remaintime[.@i],"MVP Summoner") ) {
			switch ( .type[.@i] ) {
				case 1: set .@color$, "^EE8800"; break;
				case 2: set .@color$, "^70CC11"; break;
				case 3: set .@color$, "^0000FF"; break;
				default: set .@color$, "^000000";
			}
			mes "Room #"+ .@i +" = "+ .@color$ + .whoinuse$[.@i] +"^000000";
		}
	}
	next;
	set .@room, select("MVP Room 1 ["+ getmapusers("06guild_01") +"]",
		"MVP Room 2 ["+ getmapusers("06guild_02") +"]",
		"MVP Room 3 ["+ getmapusers("06guild_03") +"]",
		"MVP Room 4 ["+ getmapusers("06guild_04") +"]",
		"MVP Room 5 ["+ getmapusers("06guild_05") +"]",
		"MVP Room 6 ["+ getmapusers("06guild_06") +"]",
		"MVP Room 7 ["+ getmapusers("06guild_07") +"]",
		"MVP Room 8 ["+ getmapusers("06guild_08") +"]");
	if ( getvariableofnpc(.remaintime[.@room],"MVP Summoner") ) {
		if ( .inuseid[.@room] == getcharid(.type[.@room]) ) {
			if ( getvariableofnpc(.killmonster,"MVP Summoner") && getmapusers("06guild_0"+ .@room) == 0 )
				killmonsterall "06guild_0"+ .@room;
			warp "06guild_0"+ .@room, 0,0;
			end;
		} else {
			mes "[Private MVP Room]";
			switch ( .type[.@room] ) {
				case 1: set .@color$, "^EE8800Party "; break;
				case 2: set .@color$, "^70CC11Guild "; break;
				case 3: set .@color$, "^0000FFPlayer ";
			}
			mes "This room is reserved for ";
			mes .@color$ + .whoinuse$[.@room] +"^000000 .";
			if ( getgmlevel() < getvariableofnpc(.gmlvlkick,"MVP Summoner") ) {
				mes "Please select another.";
				close;
			}
			mes " ";
			mes "Currently there are "+ getmapusers("06guild_0"+ .@room) +" players";
			mes "in that room.";
			set .@remaintime, getvariableofnpc(.remaintime[.@room],"MVP Summoner");
			mes "It still has "+( .@remaintime /60 )+"mn "+( .@remaintime %60 )+"s left.";
			set .@nobodycounter, getvariableofnpc(.nobodycounter[.@room],"MVP Summoner");
			if ( .@nobodycounter )
				mes "And have left empty for "+( .@nobodycounter /60 )+"mn "+( .@nobodycounter %60 )+"s.";
			mes "Kick them ?";
			next;
			if ( select ( "No:Yes" ) == 1 ) close;
			set getvariableofnpc(.remaintime[.@room],"MVP Summoner"), -1;
			mes "[Private MVP Room]";
			mes "Room#"+ .@room +" is empty now.";
			close;
		}
	}
	mes "[Private MVP Room]";
	if ( getvariableofnpc(.rentitemid, "MVP Summoner") && getvariableofnpc(.rentitemamount, "MVP Summoner") ) {
		if ( countitem(getvariableofnpc(.rentitemid, "MVP Summoner")) < getvariableofnpc(.rentitemamount, "MVP Summoner") ) {
			mes "You don't have enough "+ getitemname( getvariableofnpc(.rentitemid, "MVP Summoner") ) +" to rent a room.";
			close;
		}
	}
	else if ( getvariableofnpc(.rentcost, "MVP Summoner") ) {
		if ( zeny < getvariableofnpc(.rentcost, "MVP Summoner") ) {
			mes "You don't have enough zeny to rent a room.";
			close;
		}
	}
	mes "You reserve this room for ...";
	next;
	set .@type, select("For my party members", "For my guild members", "For personal account use" );
	if ( getcharid(.@type) == 0 ) {
		mes "[Private MVP Room]";
		mes "You do not own a "+( (.@type == 1)?"Party":"Guild" )+".";
		close;
	}
	else if ( getvariableofnpc(.rentitemid, "MVP Summoner") && getvariableofnpc(.rentitemamount, "MVP Summoner") ) {
		if ( countitem(getvariableofnpc(.rentitemid, "MVP Summoner")) < getvariableofnpc(.rentitemamount, "MVP Summoner") ) {
			mes "You don't have enough "+ getitemname( getvariableofnpc(.rentitemid, "MVP Summoner") ) +" to rent a room.";
			close;
		}
	}
	else if ( getvariableofnpc(.remaintime[.@room],"MVP Summoner") ) {
		mes "[Private MVP Room]";
		mes "I'm sorry, somebody else has already register this room faster than you.";
		close;
	}
	for ( set .@i, 1; .@i <= 8; set .@i, .@i +1 ) {
		if ( getvariableofnpc(.remaintime[.@i],"MVP Summoner") && .@type == .type[.@i] && getcharid(.@type) == .inuseid[.@i] ) {
			mes "[Private MVP Room]";
			mes "You already rented Room#"+ .@i +". Use that room instead.";
			close;
		}
	}
	set .type[.@room], .@type;
	set .inuseid[.@room], getcharid(.@type);
	set .whoinuse$[.@room], strcharinfo( (.@type == 3)?0:.@type );
	if ( getvariableofnpc(.rentitemid, "MVP Summoner") && getvariableofnpc(.rentitemamount, "MVP Summoner") ) {
		if ( countitem(getvariableofnpc(.rentitemid, "MVP Summoner")) < getvariableofnpc(.rentitemamount, "MVP Summoner") ) end;
		delitem getvariableofnpc(.rentitemid, "MVP Summoner"), getvariableofnpc(.rentitemamount, "MVP Summoner");
	}
	else if ( getvariableofnpc(.rentcost, "MVP Summoner") ) {
		if ( zeny < getvariableofnpc(.rentcost, "MVP Summoner") ) end;
		set zeny, zeny - getvariableofnpc(.rentcost, "MVP Summoner");
	}
	warp "06guild_0"+ .@room, 0,0;
	killmonsterall "06guild_0"+ .@room;
	donpcevent "MVP Summoner#"+ .@room +"::OnEnterMap";
	end;
}

06guild_01,49,49,4	duplicate(MVP Summoner)	MVP Summoner#1	116
06guild_02,49,49,4	duplicate(MVP Summoner)	MVP Summoner#2	116
06guild_03,49,49,4	duplicate(MVP Summoner)	MVP Summoner#3	116
06guild_04,49,49,4	duplicate(MVP Summoner)	MVP Summoner#4	116
06guild_05,49,49,4	duplicate(MVP Summoner)	MVP Summoner#5	116
06guild_06,49,49,4	duplicate(MVP Summoner)	MVP Summoner#6	116
06guild_07,49,49,4	duplicate(MVP Summoner)	MVP Summoner#7	116
06guild_08,49,49,4	duplicate(MVP Summoner)	MVP Summoner#8	116


06guild_01	mapflag	nowarpto
06guild_02	mapflag	nowarpto
06guild_03	mapflag	nowarpto
06guild_04	mapflag	nowarpto
06guild_05	mapflag	nowarpto
06guild_06	mapflag	nowarpto
06guild_07	mapflag	nowarpto
06guild_08	mapflag	nowarpto
06guild_01	mapflag	nomemo
06guild_02	mapflag	nomemo
06guild_03	mapflag	nomemo
06guild_04	mapflag	nomemo
06guild_05	mapflag	nomemo
06guild_06	mapflag	nomemo
06guild_07	mapflag	nomemo
06guild_08	mapflag	nomemo
06guild_01	mapflag	noteleport
06guild_02	mapflag	noteleport
06guild_03	mapflag	noteleport
06guild_04	mapflag	noteleport
06guild_05	mapflag	noteleport
06guild_06	mapflag	noteleport
06guild_07	mapflag	noteleport
06guild_08	mapflag	noteleport
06guild_01	mapflag	nosave	SavePoint
06guild_02	mapflag	nosave	SavePoint
06guild_03	mapflag	nosave	SavePoint
06guild_04	mapflag	nosave	SavePoint
06guild_05	mapflag	nosave	SavePoint
06guild_06	mapflag	nosave	SavePoint
06guild_07	mapflag	nosave	SavePoint
06guild_08	mapflag	nosave	SavePoint
06guild_01	mapflag	nopenalty
06guild_02	mapflag	nopenalty
06guild_03	mapflag	nopenalty
06guild_04	mapflag	nopenalty
06guild_05	mapflag	nopenalty
06guild_06	mapflag	nopenalty
06guild_07	mapflag	nopenalty
06guild_08	mapflag	nopenalty

    Appreciate any help I can get from you guys. Thanks.



    SOLVED:
    I was using the 1.4 version of the script which was not compatible with rAthena. Since then ~AnnieRuru~ have been gracious enough to update the script to v1.4a which is compatible with rAthena. Thanks to QQfoolsorellina for helping me and thanks to ~AnnieRuru~ for providing the script.

     

    Here is the link to the updated ~AnnieRuru~'s Private MVP Room version 1.4a
    http://rathena.org/board/topic/72376-mvp-summon-script/?p=146696

    Server "Online" Status in Control Panel

    in Web Support

    Posted · Edited by archilles89

    I am referring to this old 2011 topic in eAthena where this guy has the same problem as I am having now. He is unable to get the Char, Login, and Map status showing "Online" but the Players Online is showing. And what the other guy suggested is to write a check function that says "if there are players online, assume server is up".

    Can anybody guide me how to do this? Can anyone write the said "check" function for me please?.

    This is the link to the original thread in eAthena.ws

    http://www.eathena.ws/board/index.php?showtopic=279925
     

    Need some help with custom item in renewal

    in Client-side Support

    Posted · Edited by archilles89

    Thanks for the reply, how can I know if it reads data folder or grf and how do I know if it reads LUA or LUB first? Mind teaching me?

    I'll try converting all this into grf and setting it as number 0=custom.grf

    I'll also try using LUB files.

    Will get back to you with the results

    Results:

    I've tried using only LUA files in a seperate GRF and set the DATA.INI to read it first, still the same error.

    I've tried using only LUB files in a seperate GRF and set the DATA.INI to read it first, same thing happens.

    ---------------------------

    Error

    ---------------------------

    Cannot find File : sprite\¾Ç¼¼»ç¸®\³²\³².act

    ---------------------------

    OK

    ---------------------------

    I've tried making another item and it has the same error as well.

    How do I force the game to read the LUA or LUB files? :( It seems that it is able to trace the viewID as 833, but is unable to find _Dragonborn_Gold_Helm sprite name.

    Need some help with custom item in renewal

    in Client-side Support

    Posted

    i have already corrected the viewID.. it is now 833..

    Still have the same problem. but it's slightly different now.

    ---------------------------

    Error

    ---------------------------

    Cannot find File : sprite\¾Ç¼¼»ç¸®\³²\³².act

    ---------------------------

    OK

    ---------------------------

    as you can see, if I renamed the spr and act to only ³².spr and ³².act, the game reads the item and shows it with no errors.

    I still can't manage for it to read the correct name ³²_Dragonborn_Gold_Helm.spr and ³²_Dragonborn_Gold_Helm.act

    Need some help with custom item in renewal

    in Client-side Support

    Posted

    Hi guys, I really really need your help.

    I am not used to Renewal clients, I have always used xRay.

    Now I am using renewal, and it is showing nothing when I equipped it. The spr and act are all at the right places.

    Here is a screenshot of what I've done:

    Untitled-1.png

    The problem is the drop sprite is working, only the female and male sprites are not showing when I equipped them. Need help guys...

    Thanks in advance!

    Mohon tanya tentang custom item menggunakan Renewal.

    in Client & Patcher

    Posted · Edited by archilles89

    Salam sejahtera,

    Mohon kerjasama ahli rAthena membantu saya menyelesaikan masalah ini.

    Saya sedang mencuba buat custom item menggunakan renewal client.

    Saya sudah dapat memasukkan ia dan tiada masalah tentang "drop" sprite, collection dan item.

    Masalahnya hanya pada sprite untuk female dan male. Sudah bermacam cara saya pusingkan dia masih tidak boleh.

    Ini screenshotnya:

    Ini menunjukkan yang texturenya termasuk "drop" sprite sudah ok.

    screenDragonbornRO001.jpg

    Ini masalahnya, apabila saya cuba meng"equip"kannya, spritenya tidak nampak.

    screenDragonbornRO002.jpg

    Saya guna telah memuatnaikkan data folder saya dalam bentuk .rar

    Minta tolong tengokkan apa yang silapnya, mohon tunjuk ajar semua.

    Terima kasih..

    Edit:

    Ini adalah gambar menunjukkan cara saya memasukkan custom item ini.

    Untitled-1.png

    data.rar

×
×
  • Create New...