Job Changer + 3rd Job Items

[frenzmu06]

requesting an edit to the original jobmaster for it to give the 3rd job rewards after jobchanging to a 3rd class (item depends on the job)

 

 

item list:

***Every Class - Green Apple Ring Item ID# 2795
Rune Knight - Rune Circlet [1] Item ID# 5746
Bishop - Mitra [0] Item ID# 5747
Ranger - Sniper Goggles [1] Item ID# 5748
Mechanic - Driver Band [1] Item ID# 5749(Male) / Driver Band [1] Item ID# 5760(Female)
Shadow Chaser - Shadow Handicraft [1] Item ID# 5750,Makeover Brush Item ID#6121, Paint Brush Item ID# 6122
Minstrel - Minstrel Song Hat [1] Item ID# 5751
Genetic - Midas Whisper [1] Item ID# 5752
Warlock - Magic Stone Hat [1] Item ID# 5753
Shura - Blazing Soul [1] Item ID# 5754
Guillotine - Silence Executer [0] tem ID# 5755
Sorcerer - Wind Whisper [1] Item ID# 5756
Wanderer - Dying Swan [1] Item ID# 5758
Royal Guard- Dip Schmidt Helm [1] Item ID# 5757

 

advance tnx

[frenzmu06]

help

hello

bump

Edited July 12, 2013 by frenzmu06

[frenzmu06]

bump

[frenzmu06]

another bump

[Capuche]

//===== rAthena Script =======================================

//= Job Master

//===== By: ==================================================

//= Euphy

//===== Current Version: =====================================

//= 1.3

//===== Compatible With: =====================================

//= rAthena SVN r16114+

//===== Description: =========================================

//= A fully functional job changer.

//===== Additional Comments: =================================

//= 1.0 Initial script.

//= 1.1 Fixed reset on Baby job change.

//= 1.2 Added Expanded Super Novice support and initial Kagerou/Oboro support.

//= 1.3 Kagerou/Oboro added.

//============================================================

prontera,153,193,6 script Job Master 123,{

function Job_Menu; function A_An;

mes "[Job Master]";

if (Class > 4049) {

mes "No more jobs are available.";

close;

}

if (checkfalcon() || checkcart() || checkriding() || ismounting()) {

mes "Please remove your "+((checkfalcon())?"falcon":"")+((checkcart())?"cart":"")+((checkriding())?"Peco":"")+((ismounting())?"mount":"")+" before proceeding.";

close;

}

if (.SkillPointCheck && SkillPoint) {

mes "Please use all your skill points before proceeding.";

close;

}

set .@eac, eaclass();

set .@i, ((.ThirdClass)?roclass(.@eac&EAJ_UPPERMASK):Class);

if (.@i > 6 && .@i < 22) {

if (BaseLevel < .Rebirth[0] || JobLevel < .Rebirth[1]) {

set .@blvl, .Rebirth[0]-BaseLevel; set .@jlvl, .Rebirth[1]-JobLevel;

mes "You need "+((.@blvl>0)?.@blvl+" more base levels "+((.@jlvl>0)?"/ ":""):"")+((.@jlvl>0)?.@jlvl+" more job levels ":"")+"to continue.";

close;

}

if (Class > 21) {

mes "Switch to third class?";

next;

Job_Menu(roclass(.@eac|EAJL_THIRD));

close;

}

while(1) {

mes "Select an option.";

next;

set .@i, select(" ~ ^0055FFRebirth^000000:"+((.ThirdClass)?" ~ ^FF0000Third Class^000000":"")+": ~ ^777777Cancel^000000");

if (.@i==3) close;

mes "[Job Master]";

mes "Are you sure?";

next;

Job_Menu(((.@i==1)?4001:roclass(.@eac|EAJL_THIRD)));

mes "[Job Master]";

}

}

set .@j1, roclass(.@eac|EAJL_2_1); set .@j2,roclass(.@eac|EAJL_2_2);

if ((.@eac&EAJ_UPPERMASK) == EAJ_SUPER_NOVICE) setarray .@exp[0],roclass(.@eac|EAJL_THIRD),99;

if (Class == Job_Ninja) setarray .@exp[0],.@j1,70;

if (.@exp[0] && .ThirdClass) {

if (BaseLevel < .Rebirth[0] || JobLevel < .@exp[1]) {

set .@blvl, .Rebirth[0]-BaseLevel; set .@jlvl, .@exp[1]-JobLevel;

mes "You need "+((.@blvl>0)?.@blvl+" more base levels "+((.@jlvl>0)?"/ ":""):"")+((.@jlvl>0)?.@jlvl+" more job levels ":"")+"to continue.";

close;

}

mes "Switch to "+jobname(.@exp[0])+"?";

next;

Job_Menu(.@exp[0]);

close;

}

if (.@eac&EAJL_2)

if (.@eac&(EAJL_UPPER|EAJL_BABY) || roclass(.@eac|EAJL_UPPER) == -1) {

mes "No more jobs are available.";

close;

}

if ((.@eac&EAJ_BASEMASK) == EAJ_NOVICE) {

if (JobLevel < .JobReq[0])

mes "A job level of "+.JobReq[0]+" is required to change into the 1st Class.";

else if (Class == 4001 && .LastJob && lastJob) {

mes "Switch classes now?";

next;

Job_Menu(roclass((eaclass(lastJob)&EAJ_BASEMASK)|EAJL_UPPER));

} else switch(Class) {

case 0: Job_Menu(1,2,3,4,5,6,23,4046,24,25,4023);

case 4001: Job_Menu(4002,4003,4004,4005,4006,4007);

case 4023: Job_Menu(4024,4025,4026,4027,4028,4029,4045);

default: mes "An error has occurred."; break;

}

close;

}

if (roclass(.@eac|EAJL_2_1) == -1 || roclass(.@eac|EAJL_2_2) == -1)

mes "No more jobs are available.";

else if (!(.@eac&EAJL_2) && JobLevel < .JobReq[1])

mes "A job level of "+.JobReq[1]+" is required to change into the 2nd Class.";

else if (.LastJob && lastJob && (.@eac&EAJL_UPPER)) {

mes "Switch classes now?";

next;

Job_Menu(lastJob+4001);

} else

Job_Menu(.@j1,.@j2);

close;

function Job_Menu {

while(1) {

if (getargcount() > 1) {

mes "Select a job.";

set .@menu$,"";

for(set .@i,0; .@i<getargcount(); set .@i,.@i+1)

set .@menu$, .@menu$+" ~ "+jobname(getarg(.@i))+":";

set .@menu$, .@menu$+" ~ ^777777Cancel^000000";

next;

set .@i, getarg(select(.@menu$)-1,0);

if (!.@i) close;

if ((.@i == 23 || .@i == 4045) && BaseLevel < .SNovice) {

mes "[Job Master]";

mes "A base level of "+.SNovice+" is required to turn into a "+jobname(.@i)+".";

close;

}

mes "[Job Master]";

mes "Are you sure?";

next;

} else

set .@i, getarg(0);

if (select(" ~ Change into ^0055FF"+jobname(.@i)+"^000000 class: ~ ^777777"+((getargcount() > 1)?"Go back":"Cancel")+"^000000") == 1) {

mes "[Job Master]";

mes "You are now "+A_An(jobname(.@i))+"!";

if (.@i==4001 && .LastJob) set lastJob, Class;

jobchange .@i;

if (.@i==4001 || .@i==4023) resetlvl(1);

specialeffect2 338; specialeffect2 432;

if (.Platinum) callsub Get_Platinum;

if ( eaclass()&EAJL_THIRD ) {

getitem 2795,1;// ***Every Class - Green Apple Ring Item ID# 2795

switch( Class ) {

case 4054:

case 4060:

case 4096:

getitem 5746,1;//Rune Knight - Rune Circlet [1] Item ID# 5746

break;

case 4057:

case 4063:

case 4099:

getitem 5747,1;// Bishop - Mitra [0] Item ID# 5747

break;

case 4056:

case 4062:

case 4098:

getitem 5748,1;// Ranger - Sniper Goggles [1] Item ID# 5748

break;

case 4058:

case 4064:

case 4100:

getitem ( Sex? 5749 : 5760 ),1;// Mechanic - Driver Band [1] Item ID# 5749(Male) / Driver Band [1] Item ID# 5760(Female)

break;

case 4055:

case 4061:

case 4097:

getitem 5753,1;//Warlock - Magic Stone Hat [1] Item ID# 5753

break;

case 4070:

case 4077:

case 4106:

getitem 5754,1;//Shura - Blazing Soul [1] Item ID# 5754

break;

case 4059:

case 4065:

case 4101:

getitem 5755,1;//Guillotine - Silence Executer [0] tem ID# 5755

break;

case 4067:

case 4074:

case 4103:

getitem 5756,1;//Sorcerer - Wind Whisper [1] Item ID# 5756

break;

case 4069:

case 4076:

case 4105:

getitem 5758,1;//Wanderer - Dying Swan [1] Item ID# 5758

break;

case 4073:

case 4066:

case 4102:

getitem 5757,1;//Royal Guard- Dip Schmidt Helm [1] Item ID# 5757

break;

case 4072:

case 4079:

case 4108:

getitem 5750,1;

getitem 6121,1;

getitem 6122,1;//Shadow Chaser - Shadow Handicraft [1] Item ID# 5750,Makeover Brush Item ID#6121, Paint Brush Item ID# 6122

break;

case 4068:

case 4075:

case 4104:

getitem 5751,1;//Minstrel -:: Minstrel Song Hat [1] Item ID# 5751

break;

case 4071:

case 4078:

case 4107:

getitem 5752,1;//Genetic - Midas Whisper [1] Item ID# 5752

default:

}

}

close;

}

if (getargcount() == 1) return;

mes "[Job Master]";

}

end;

}

function A_An {

setarray .@A$[0],"a","e","i","o","u";

set .@B$, "_"+getarg(0);

for(set .@i,0; .@i<5; set .@i,.@i+1)

if (compare(.@B$,"_"+.@A$[.@i])) return "an "+getarg(0);

return "a "+getarg(0);

}

Get_Platinum:

skill 142,1,0;

switch(BaseClass) {

case 0: if (Class !=23) skill 143,1,0; break;

case 1: skill 144,1,0; skill 145,1,0; skill 146,1,0; break;

case 2: skill 157,1,0; break;

case 3: skill 147,1,0; skill 148,1,0; break;

case 4: skill 156,1,0; break;

case 5: skill 153,1,0; skill 154,1,0; skill 155,1,0; break;

case 6: skill 149,1,0; skill 150,1,0; skill 151,1,0; skill 152,1,0; break;

default: break;

}

switch(BaseJob) {

case 7: skill 1001,1,0; break;

case 8: skill 1014,1,0; break;

case 9: skill 1006,1,0; break;

case 10: skill 1012,1,0; skill 1013,1,0; break;

case 11: skill 1009,1,0; break;

case 12: skill 1003,1,0; skill 1004,1,0; break;

case 14: skill 1002,1,0; break;

case 15: skill 1015,1,0; skill 1016,1,0; break;

case 16: skill 1007,1,0; skill 1008,1,0; skill 1017,1,0; skill 1018,1,0; skill 1019,1,0; break;

case 17: skill 1005,1,0; break;

case 18: skill 238,1,0; break;

case 19: skill 1010,1,0; break;

case 20: skill 1011,1,0; break;

default: break;

}

return;

OnInit:

setarray .Rebirth[0],99,50; // Minimum base level, job level to rebirth OR change to third class

setarray .JobReq[0],10,40; // Minimum job level to turn into 1st class, 2nd class

set .ThirdClass,1; // Enable third classes? (1: yes / 0: no)

set .SNovice,45; // Minimum base level to turn into Super Novice

set .LastJob,1; // Enforce linear class changes? (1: yes / 0: no)

set .SkillPointCheck,1; // Force player to use up all skill points? (1: yes / 0: no)

set .Platinum,1; // Get platinum skills automatically? (1: yes / 0: no)

end;

}

[frenzmu06]

thanks, i'll try this now, i'm currently using this

i found yours more flexible upon reading, thanks

 

@off i requested this almost 2 weeks ago and now you and him answered the same day T_T, i'll only use one from the two (sry for i will not use one from the two of your' scripts) i feel i've just wasted someones time T_T, but anyways thank to both

[Capuche]

You're welcome!

i feel i've just wasted someones time T_T

It didn't take too much time don't worry, and it's better for you to have the choice

[frenzmu06]

thanks again