R>Zeny to Proof of Donation

[Sallycantdance]

hello i would like to ask is there any bug free zeny converter to pods thanks in advance

[ryzenthird]

its pretty easy to code your own zeny to pod converter..

try this
 

prontera,150,150,4	script	Zeny To Pods	E_PORING,{
	
	.@total_pods_can_get = zeny / .pods_price;
	mes "[Zeny to pods]";
	mes "("+callfunc("F_InsertComma",.pods_price)+"z) for 1 pod";
	mes "You can get ("+.@total_pods_can_get+") pods with your current zeny";
	next;
	switch(select("Zeny to Pods:Cancel")){
		case 1:
			if(.@total_pods_can_get){
				input(.@convert,0,.@total_pods_can_get);
				if(.@convert > .@total_pods_can_get){
					mes "Sorry but you cannot convert that many PODS with your current zeny";
					close;
				}else if(!.@convert){
					mes "Sorry but you do not input any amount";
					close;
				}else if(!checkweight(7179,.@convert)){
					mes "Sorry but you cannot hold that many PODS with your current inventory weight";
					close;
				}else{
					mes "You want to convert your zeny to "+.@convert+" PODS Right?";
					switch(select("Yes:No")){
						case 1:
							set zeny,zeny-(.@convert * .pods_price);
							getitem 7179,.@convert;
							mes "Thank you for converting ("+.@convert+") PODS ";
							close;
						default:
							close;
					}
					close;
				}
			}else{
				mes "Sorry but you do not have enough zeny to convert to pods";
				close;
			}
			
		default:
			close;
	}
OnInit:
	set .pods_price,100000;
	end;
}