Jump to content
  • 0

TOF Event

MusiLiciouS

Asked by MusiLiciouS,

 Share

Question

MusiLiciouS Poring

MusiLiciouS

Posted
Posted (edited)

I would like to request a TRUE or FALSE Event script.   

 

• GM will have to activate the event.

• A warper will be enabled once the event is activated. After 1 minute. warper will be disabled

• Event map will be at quiz_02 ..... with the O and X.. 

• O = TRUE .... X = FALSE

• There should be a warper that will lead players to O and X

• There's an NPC where the GM will choose the correct answer. 

       For example, correct answer is TRUE all players at "O" will be warped to the holding area.

                       All players at "X" will be warped back to Prontera

 

 

Thank You in Advance :)    :wub:  :wub:  :wub:  :wub: 

 

 ** IMAGE OF PREFERRED MAP ATTACHED **

post-17644-0-79617100-1420777893_thumb.jpg

Edited by MusiLiciouS

5 answers to this question

Recommended Posts

  • 1
Luciar Poring

Luciar

Posted
Posted

I wrote this very quickly, forgive any errors. It's pretty straight forward, see what you can do with it

quiz_02,347,387,4	script	Trivia Control	123,{

	.@n$ = "[^0000FFTrivial Controller^000000]";
	
	mes .@n$;
	mes "Hello " + strcharinfo(0);
	if(getgmlevel() < .minGM) close;
	switch(.active) {
		
		case 1:
			mes "Players are still entering. Please wait.";
			close;
		
		case 2:
			switch(select("Ask Question:End Event")) {
				case 1:
					mes "Please input your question.";
					input .@q$;
					mes "Is it true or false?";
					.@a = select("True:False"); 
					next;
					mes .@n$;
					mes "Please verify your question:";
					mes .@q$;
					mes (.@a == 1 ? "True" : "False");
					select("Proceed");
					close2;
					announce "Question time!",bc_map;
					sleep2 2000;
					announce "True or False?",bc_map;
					announce .@q$,bc_map;
					donpcevent "TrueWarp::OnActive";
					donpcevent "FalseWarp::OnActive";
					sleep2 25000;
					announce "5 seconds!",bc_map;
					sleep2 5000;
					donpcevent "TrueWarp::OnClose";
					donpcevent "FalseWarp::OnClose";
					announce "The answer is...",bc_map;
					sleep2 5000;
					announce (.@a  == 1 ? "TRUE!!" : "FALSE!!"),bc_map;
					callsub OnReveal,.@a;
					end;
				
				case 2:
					mes "Event Ended.";
					announce "[Trivia Event] : The event has been ended by a GM",bc_all;
					.active = 0;
					close;
			}
			break;
		
		default:
			select("Activate Event");
			.active = 1;
			announce "[Trivia Event] : The event has been activated. Come to Prontera and warp to the event to participate!",bc_all;
			donpcevent "Trivia Warp::OnActivate";
			mes "Come talk to me when you're ready to proceed!";
			close2;
			sleep2 30000;
			announce "[Trivia Event] : You have 30 more seconds to join the event. Come to Prontera to participate!",bc_all;
			sleep2 30000;
			announce "[Trivia Event] : The event has started and the warp has been closed.",bc_all;
			.active = 2;
			announce "[Trivia Event] : Welcome to the trivia event!",bc_map;
			sleep2 3000;
			announce "[Trivia Event] : You will have 30 seconds to select True or False after the question is displayed.",bc_map;
			sleep2 3000;
			announce "[Trivia Event] : Simply warp to the corresponding answer. O = TRUE X = FALSE",bc_map;
			end;		
	}

	OnInit:
		.minGM = 1;
		.active = 0;
		end;
	
	OnReveal:
		if(getarg(0) == 1) {
			areawarp "quiz_02",324,334,347,357,"quiz_02",350,371;
			areawarp "quiz_02",352,334,352,357,"prontera",156,191;
		} else {
			areawarp "quiz_02",352,334,352,357,"quiz_02",350,371;
			areawarp "quiz_02",324,334,347,357,"prontera",156,191;
		}
		return;
}

quiz_02,337,365,0	script	TrueWarp	45,2,2,{
	
	warp "quiz_02",335,345;
	end;
	
	OnActive:
		enablenpc strnpcinfo(0);
		waitingroom "TRUE",0;
		end;
		
	OnClose:
	OnInit:
		disablenpc strnpcinfo(0);
		end;
}

quiz_02,362,365,0	script	FalseWarp	45,2,2,{
	
	warp "quiz_02",364,346;
	end;
	
	OnActive:
		enablenpc strnpcinfo(0);
		waitingroom "FALSE",0;
		end;
		
	OnClose:
	OnInit:
		disablenpc strnpcinfo(0);
		end;
}

prontera,150,191,0	script	Trivia Warp	45,2,2,{

	if(getvariableofnpc(.active,"Trivia Control")) warp "quiz_02",350,371;
	end;

	OnActivate:
		enablenpc strnpcinfo(0);
		waitingroom "Trivia Event",0;
		initnpctimer;
		end;
	
	OnTimer60000:
		stopnpctimer;
	OnInit:
		disablenpc strnpcinfo(0);
		end;
}
  • Upvote 1
MusiLiciouS Poring

MusiLiciouS

Posted
  • Author
Posted

Okie sir. Gonna try this one later..

I wrote this very quickly, forgive any errors. It's pretty straight forward, see what you can do with it

 

quiz_02,347,387,4	script	Trivia Control	123,{

	.@n$ = "[^0000FFTrivial Controller^000000]";
	
	mes .@n$;
	mes "Hello " + strcharinfo(0);
	if(getgmlevel() < .minGM) close;
	switch(.active) {
		
		case 1:
			mes "Players are still entering. Please wait.";
			close;
		
		case 2:
			switch(select("Ask Question:End Event")) {
				case 1:
					mes "Please input your question.";
					input .@q$;
					mes "Is it true or false?";
					.@a = select("True:False"); 
					next;
					mes .@n$;
					mes "Please verify your question:";
					mes .@q$;
					mes (.@a == 1 ? "True" : "False");
					select("Proceed");
					close2;
					announce "Question time!",bc_map;
					sleep2 2000;
					announce "True or False?",bc_map;
					announce .@q$,bc_map;
					donpcevent "TrueWarp::OnActive";
					donpcevent "FalseWarp::OnActive";
					sleep2 25000;
					announce "5 seconds!",bc_map;
					sleep2 5000;
					donpcevent "TrueWarp::OnClose";
					donpcevent "FalseWarp::OnClose";
					announce "The answer is...",bc_map;
					sleep2 5000;
					announce (.@a  == 1 ? "TRUE!!" : "FALSE!!"),bc_map;
					callsub OnReveal,.@a;
					end;
				
				case 2:
					mes "Event Ended.";
					announce "[Trivia Event] : The event has been ended by a GM",bc_all;
					.active = 0;
					close;
			}
			break;
		
		default:
			select("Activate Event");
			.active = 1;
			announce "[Trivia Event] : The event has been activated. Come to Prontera and warp to the event to participate!",bc_all;
			donpcevent "Trivia Warp::OnActivate";
			mes "Come talk to me when you're ready to proceed!";
			close2;
			sleep2 30000;
			announce "[Trivia Event] : You have 30 more seconds to join the event. Come to Prontera to participate!",bc_all;
			sleep2 30000;
			announce "[Trivia Event] : The event has started and the warp has been closed.",bc_all;
			.active = 2;
			announce "[Trivia Event] : Welcome to the trivia event!",bc_map;
			sleep2 3000;
			announce "[Trivia Event] : You will have 30 seconds to select True or False after the question is displayed.",bc_map;
			sleep2 3000;
			announce "[Trivia Event] : Simply warp to the corresponding answer. O = TRUE X = FALSE",bc_map;
			end;		
	}

	OnInit:
		.minGM = 1;
		.active = 0;
		end;
	
	OnReveal:
		if(getarg(0) == 1) {
			areawarp "quiz_02",324,334,347,357,"quiz_02",350,371;
			areawarp "quiz_02",352,334,352,357,"prontera",156,191;
		} else {
			areawarp "quiz_02",352,334,352,357,"quiz_02",350,371;
			areawarp "quiz_02",324,334,347,357,"prontera",156,191;
		}
		return;
}

quiz_02,337,365,0	script	TrueWarp	45,2,2,{
	
	warp "quiz_02",335,345;
	end;
	
	OnActive:
		enablenpc strnpcinfo(0);
		waitingroom "TRUE",0;
		end;
		
	OnClose:
	OnInit:
		disablenpc strnpcinfo(0);
		end;
}

quiz_02,362,365,0	script	FalseWarp	45,2,2,{
	
	warp "quiz_02",364,346;
	end;
	
	OnActive:
		enablenpc strnpcinfo(0);
		waitingroom "FALSE",0;
		end;
		
	OnClose:
	OnInit:
		disablenpc strnpcinfo(0);
		end;
}

prontera,150,191,0	script	Trivia Warp	45,2,2,{

	if(getvariableofnpc(.active,"Trivia Control")) warp "quiz_02",350,371;
	end;

	OnActivate:
		enablenpc strnpcinfo(0);
		waitingroom "Trivia Event",0;
		initnpctimer;
		end;
	
	OnTimer60000:
		stopnpctimer;
	OnInit:
		disablenpc strnpcinfo(0);
		end;
}

sir, is this script working at eathena? I've tried this one but, I can't click the NPC

Luciar Poring

Luciar

Posted
Posted

No. You posted a request on the rAthena support forums. Of course it's written to the most recent rAthena standards. In the future I would highly suggest including ALL pertinent information in your request post to avoid such issues. If you're asking the community to do something for you, the least you can do is provide them with all the information they need.

 

Change any instance of variable = value; to set variable,value;

MusiLiciouS Poring

MusiLiciouS

Posted
  • Author
Posted

No. You posted a request on the rAthena support forums. Of course it's written to the most recent rAthena standards. In the future I would highly suggest including ALL pertinent information in your request post to avoid such issues. If you're asking the community to do something for you, the least you can do is provide them with all the information they need.

 

Change any instance of variable = value; to set variable,value;

Woopsie. im sorry i forgot to include it. Thx sir gonna try it again.
Ernest90 Poring

Ernest90

Posted
Posted

is there any possibility for few thing?

 

- 5 Round for the game after that auto warp back to town.

- Winner get "Poring Coin"

- After first round end , auto warp back to starting point for 2nd question?

 

thanks for assists mate.

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

Guest
Answer this question...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
 Share
Go to question listing

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...