Jump to content
  • 0

NPC

Koutaro Satomi

Asked by Koutaro Satomi,

 Share

Question

Koutaro Satomi Poring

Koutaro Satomi

Posted
  • Group:  Members
  • Topic Count:  11
  • Topics Per Day:  0.00
  • Content Count:  22
  • Reputation:   0
  • Joined:  09/27/14
  • Last Seen:  
Posted (edited)

just a quick question im very sorry as well if im noob.. i don't have any background experience on scripting but im still learning each and everytime..

 

i would justl ike to know how would i be able to make 5 npc out of this instead of 5 is to 1 something like that.. here's my script


//===== rAthena Script =======================================
//= Euphy's Quest Shop
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.6b
//===== Compatible With: =====================================
//= rAthena SVN r16862+
//===== Description: =========================================
//= A dynamic quest shop based on Lunar's, with easier config.
//= Includes support for multiple shops & cashpoints.
//= Item Preview script by ToastOfDoom.
//===== Additional Comments: =================================
//= 1.0 Initial script.
//= 1.2 Added category support.
//= 1.3 More options and fixes.
//= 1.4 Added debug settings.
//= 1.5 Replaced categories with shop IDs.
//= 1.6 Added support for purchasing stackables.
//= 1.6a Added support for previewing costumes and robes.
//= 1.6b Added 'disable_items' command.
//============================================================

// Shop NPCs -- supplying no argument displays entire menu.
//    callfunc "qshopd"{,<shop ID>{,<shop ID>{,...}}};
//============================================================
prontera,101,81,4    script    Consumables    856,{ callfunc "qshopd"; }


// Script Core
//============================================================
-    script    quest_shopd    -1,{
function Add; function Chk; function Slot; function A_An;
OnInit:
    freeloop(1);

// -----------------------------------------------------------
//  Basic shop settings.
// -----------------------------------------------------------

    set .Announce,0;    // Announce quest completion? (1: yes / 0: no)
    set .ShowSlot,1;    // Show item slots? (2: all equipment / 1: if slots > 0 / 0: never)
    set .ShowID,0;      // Show item IDs? (1: yes / 0: no)
    set .ShowZeny,1;    // Show Zeny cost, if any? (1: yes / 0: no)
    set .MaxStack,100;    // Max number of quest items purchased at one time.

// -----------------------------------------------------------
//  Points variable -- optional quest requirement.
//    setarray .Points$[0],"<variable name>","<display name>";
// -----------------------------------------------------------

    setarray .Points$[0],"#CASHPOINTS","Cash Points";

// -----------------------------------------------------------
//  Shop IDs -- to add shops, copy dummy data at bottom of file.
//    setarray .Shops$[1],"<Shop 1>","<Shop 2>"{,...};
// -----------------------------------------------------------

//    setarray .Shops$[1],"Weapon Donates","Armor Donates","Donate Cards";
    setarray .Shops$[1],"Consumables";

// -----------------------------------------------------------
//  Quest items -- do NOT use a reward item more than once!
//    Add(<shop ID>,<reward ID>,<reward amount>,
//        <Zeny cost>,<point cost>,
//        <required item ID>,<required item amount>{,...});
// -----------------------------------------------------------

    Add(1,14003,1,0,0,7179,3);
    Add(1,13696,1,0,0,7179,30);
    Add(1,12901,1,0,0,7179,5);
    Add(1,12909,1,0,0,7179,5);
    Add(1,12213,1,0,0,7179,100);
    Add(1,6127,1,0,0,7179,10);
    Add(1,7776,1,0,0,7179,30);
    Add(1,13710,1,0,0,7179,250);
    Add(1,12029,2,0,0,7179,1);
    Add(1,13989,1,0,0,7179,2);
    Add(1,17070,1,0,0,7179,50);
    Add(1,13973,1,0,0,7179,15);
    Add(1,13718,1,0,0,7179,5);
    Add(1,14287,1,0,0,7179,2);
    Add(1,14288,1,0,0,7179,2);
    Add(1,13547,1,0,0,7179,5);
    Add(1,14003,1,0,0,7179,3);
    Add(1,12922,1,0,0,7179,5);
    Add(1,12913,1,0,0,7179,5);
    Add(1,12914,1,0,0,7179,5);
    Add(1,12917,1,0,0,7179,5);
    Add(1,12916,1,0,0,7179,5);
    Add(1,12910,1,0,0,7179,5);
    Add(1,13553,1,0,0,7179,5);
    Add(1,12903,1,0,0,7179,30);
    Add(1,12904,1,0,0,7179,30);
    Add(1,12905,1,0,0,7179,30);
    Add(1,12906,1,0,0,7179,30);
    Add(1,12907,1,0,0,7179,30);
    Add(1,12908,1,0,0,7179,30);
    Add(1,14284,1,0,0,7179,20);
    Add(1,14285,1,0,0,7179,20);
    Add(1,14286,1,0,0,7179,20);


// -----------------------------------------------------------

    freeloop(0);
    set .menu$,"";
    for(set .@i,1; .@i<=getarraysize(.Shops$); set .@i,.@i+1) {
        set .menu$, .menu$+.Shops$[.@i]+":";
        npcshopdelitem "qshopd"+.@i,909;
    }
    end;

OnMenu:
    set .@size, getarraysize(@i);
    if (!.@size) set .@i, select(.menu$);
    else if (.@size == 1) set .@i, @i[0];
    else {
        for(set .@j,0; .@j<.@size; set .@j,.@j+1)
            set .@menu$, .@menu$+.Shops$[@i[.@j]]+":";
        set .@i, @i[select(.@menu$)-1];
    }
    deletearray @i[0],getarraysize(@i);
    if (.Shops$[.@i] == "") {
        message strcharinfo(0),"An error has occurred.";
        end;
    }
    dispbottom "Select one item at a time.";
    callshop "qshopd"+.@i,1;
    npcshopattach "qshopd"+.@i;
    end;

OnBuyItem:
    // .@q[] : RewardID, BoughtAmt, RewardAmt, BaseAmt, ReqZeny, ReqPts, { ReqItem, ReqAmt, ... }
    setarray .@q[0],@bought_nameid[0],((@bought_quantity[0] > .MaxStack)?.MaxStack:@bought_quantity[0]);
    copyarray .@q[3],getd(".q_"+.@q[0]+"[0]"),getarraysize(getd(".q_"+.@q[0]));
    set .@q[2],.@q[1]*.@q[3];
    if (!.@q[2] || .@q[2] > 30000) {
        message strcharinfo(0),"You can't purchase that many "+getitemname(.@q[0])+".";
        end;
    }
    mes "[Quest Shop]";
    mes "Reward: ^0055FF"+((.@q[2] > 1)?.@q[2]+"x ":"")+Slot(.@q[0])+"^000000";
    mes "Requirements:";
    disable_items;
    if (.@q[4]) mes " > "+Chk(Zeny,.@q[4]*.@q[1])+(.@q[4]*.@q[1])+" Zeny^000000";
    if (.@q[5]) mes " > "+Chk(getd(.Points$[0]),.@q[5]*.@q[1])+(.@q[5]*.@q[1])+" "+.Points$[1]+" ("+getd(.Points$[0])+"/"+(.@q[5]*.@q[1])+")^000000";
    if (.@q[6]) for(set .@i,6; .@i<getarraysize(.@q); set .@i,.@i+2)
        mes " > "+Chk(countitem(.@q[.@i]),.@q[.@i+1]*.@q[1])+((.ShowID)?"{"+.@q[.@i]+"} ":"")+Slot(.@q[.@i])+" ("+countitem(.@q[.@i])+"/"+(.@q[.@i+1]*.@q[1])+")^000000";
    next;
    setarray @qe[1], getiteminfo(.@q[0],5), getiteminfo(.@q[0],11);
    if (@qe[2] > 0 && ((@qe[1] & 1) || (@qe[1] & 256) || (@qe[1] & 512) || (@qe[1] & 1024) || (@qe[1] & 2048) || (@qe[1] & 4096) || (@qe[1] & 4) || (@qe[1] & 8192)))
        set .@preview,1;
    addtimer 1000, strnpcinfo(0)+"::OnEnd";
    while(1) {
        switch(select(" ~ Purchase ^0055FF"+getitemname(.@q[0])+"^000000:"+((.@preview && !@qe[7])?" ~ Preview...":"")+": ~ ^777777Cancel^000000")) {
        case 1:
            if (@qe[0]) {
                mes "[Quest Shop]";
                mes "You're missing one or more quest requirements.";
                close;
            }
            if (!checkweight(.@q[0],.@q[2])) {
                mes "[Quest Shop]";
                mes "^FF0000You need "+(((.@q[2]*getiteminfo(.@q[0],6))+Weight-MaxWeight)/10)+" additional weight capacity to complete this trade.^000000";
                close;
            }
            if (.@q[4]) set Zeny, Zeny-(.@q[4]*.@q[1]);
            if (.@q[5]) setd .Points$[0], getd(.Points$[0])-(.@q[5]*.@q[1]);
            if (.@q[6]) for(set .@i,6; .@i<getarraysize(.@q); set .@i,.@i+2)
                delitem .@q[.@i],.@q[.@i+1]*.@q[1];
            getitem .@q[0],.@q[2];
            if (.Announce) announce strcharinfo(0)+" has created "+((.@q[2] > 1)?.@q[2]+"x "+getitemname(.@q[0]):A_An(getitemname(.@q[0])))+"!",0;
            specialeffect2 EF_FLOWERLEAF;
            close;
        case 2:
            setarray @qe[3], getlook(LOOK_HEAD_BOTTOM), getlook(LOOK_HEAD_TOP), getlook(LOOK_HEAD_MID), getlook(LOOK_ROBE), 1;
            if ((@qe[1] & 1) || (@qe[1] & 4096)) changelook LOOK_HEAD_BOTTOM, @qe[2];
            else if ((@qe[1] & 256) || (@qe[1] & 1024)) changelook LOOK_HEAD_TOP, @qe[2];
            else if ((@qe[1] & 512) || (@qe[1] & 2048)) changelook LOOK_HEAD_MID, @qe[2];
            else if ((@qe[1] & 4) || (@qe[1] & 8192)) changelook LOOK_ROBE, @qe[2];
            break;
        case 3:
            close;
        }
    }

OnEnd:
    if (@qe[7]) {
        changelook LOOK_HEAD_BOTTOM, @qe[3];
        changelook LOOK_HEAD_TOP, @qe[4];
        changelook LOOK_HEAD_MID, @qe[5];
        changelook LOOK_ROBE, @qe[6];
    }
    deletearray @qe[0],8;
    end;

function Add {
    if (getitemname(getarg(1)) == "null") {
        debugmes "Quest reward #"+getarg(1)+" invalid (skipped).";
        return;
    }
    setarray .@j[0],getarg(2),getarg(3),getarg(4);
    for(set .@i,5; .@i<getargcount(); set .@i,.@i+2) {
        if (getitemname(getarg(.@i)) == "null") {
            debugmes "Quest requirement #"+getarg(.@i)+" invalid (skipped).";
            return;
        } else
            setarray .@j[.@i-2],getarg(.@i),getarg(.@i+1);
    }
    copyarray getd(".q_"+getarg(1)+"[0]"),.@j[0],getarraysize(.@j);
    npcshopadditem "qshopd"+getarg(0),getarg(1),((.ShowZeny)?getarg(3):0);
    return;
}

function Chk {
    if (getarg(0) < getarg(1)) {
        set @qe[0],1;
        return "^FF0000";
    } else
        return "^00FF00";
}

function Slot {
    set .@s$,getitemname(getarg(0));
    switch(.ShowSlot) {
        case 1: if (!getitemslots(getarg(0))) return .@s$;
        case 2: if (getiteminfo(getarg(0),2) == 4 || getiteminfo(getarg(0),2) == 5) return .@s$+" ["+getitemslots(getarg(0))+"]";
        default: return .@s$;
    }
}

function A_An {
    setarray .@A$[0],"a","e","i","o","u";
    set .@B$, "_"+getarg(0);
    for(set .@i,0; .@i<5; set .@i,.@i+1)
        if (compare(.@B$,"_"+.@A$[.@i])) return "an "+getarg(0);
    return "a "+getarg(0);
}
}

function    script    qshopd    {
    deletearray @i[0],getarraysize(@i);
    for(set .@i,0; .@i<getargcount(); set .@i,.@i+1)
        set @i[.@i],getarg(.@i);
    doevent "quest_shopd::OnMenu";
    end;
}


// Dummy shop data -- copy as needed.
//============================================================
-    shop    qshopd1    -1,909:-1
-    shop    qshopd2    -1,909:-1
-    shop    qshopd3    -1,909:-1
-    shop    qshopd4    -1,909:-1
-    shop    qshopd5    -1,909:-1
Edited by Emistry
codebox
Link to comment
Share on other sites

4 answers to this question

Recommended Posts

Jaburak Poring

Jaburak

Posted
  • Group:  Members
  • Topic Count:  48
  • Topics Per Day:  0.01
  • Content Count:  1125
  • Reputation:   236
  • Joined:  07/30/12
  • Last Seen:  
Posted

Duplicate the NPC script then change the quest_shopd and qshopd# to different name.

Link to comment
Share on other sites
Koutaro Satomi Poring

Koutaro Satomi

Posted
  • Group:  Members
  • Topic Count:  11
  • Topics Per Day:  0.00
  • Content Count:  22
  • Reputation:   0
  • Joined:  09/27/14
  • Last Seen:  
  • Author
Posted

sir Anakid i was able to make the duplications for npc(Thank you) but they all have the same items?.. how would i be able to change those?

Link to comment
Share on other sites
Winz Poring

Winz

Posted
  • Group:  Members
  • Topic Count:  22
  • Topics Per Day:  0.00
  • Content Count:  1479
  • Reputation:   172
  • Joined:  12/14/11
  • Last Seen:  
Posted

http://rathena.org/wiki/Basic_Scripting#Duplicating


they will have the exactly same items as the main script. if you want to make them different, you need to make different NPCs. you can copy paste the script, and change the sold item and price tho.

Link to comment
Share on other sites
Radian Drops

Radian

Posted
  • Group:  Members
  • Topic Count:  162
  • Topics Per Day:  0.05
  • Content Count:  1546
  • Reputation:   192
  • Joined:  07/23/14
  • Last Seen:  
Posted (edited)

I dupplicate it like this

mellina,106,80,3	script	Quest Shop#1	871,{ callfunc "qshop",1,2,3,4,5,9,11,13; }
mellina,104,83,3	script	Battle Ground Prizes#13	751,{ callfunc "qshop",14,15,16; }

que_house_s,78,48,4	script	Zodiac Donate#1	787,{ callfunc "qshop",6; }
que_house_s,78,46,4	script	Suits Donate#2	787,{ callfunc "qshop",7; }
que_house_s,78,44,4	script	Mutant Dragon Set#3	787,{ callfunc "qshop",8; }
que_house_s,78,42,4	script	Ability Sets#4	787,{ callfunc "qshop",9; }
que_house_s,78,40,4	script	Random Donates#5	787,{ callfunc "qshop",10,12; }
que_house_s,65,44,4	script	Fusion Set#5	787,{ callfunc "qshop",11; }
que_house_s,72,50,4	script	Imperial Item#17	787,{ callfunc "qshop",17; }

and this too

setarray .Shops$[1],"Wings","Upper","Middle","Access","Rares","Zodiac","Donate","Mutant Dragon Set","Ability Items","Random Donates","Fusion Set","Balloon Donate","Dragon Weapons","Battle Ground Prize 1","Battle Ground Prize 2","Battle Ground Prize 3","Imperial Items";

and dont forget to add more of this 

// Dummy shop data -- copy as needed.
//============================================================
-	shop	qshop1	-1,909:-1
-	shop	qshop2	-1,909:-1
-	shop	qshop3	-1,909:-1
-	shop	qshop4	-1,909:-1
-	shop	qshop5	-1,909:-1
-	shop	qshop6	-1,909:-1
-	shop	qshop7	-1,909:-1
-	shop	qshop8	-1,909:-1
-	shop	qshop9	-1,909:-1
-	shop	qshop10	-1,909:-1
-	shop	qshop11	-1,909:-1
-	shop	qshop12	-1,909:-1
-	shop	qshop13	-1,909:-1

-	shop	qshop14	-1,909:-1
-	shop	qshop15	-1,909:-1
-	shop	qshop16	-1,909:-1
-	shop	qshop17	-1,909:-1
Edited by Ginji
Link to comment
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

Guest
Answer this question...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
 Share
Go to question listing
×
×
  • Create New...