Jump to content
  • 0
Enoch

Mvp and Mini boss Card List

Question

Good day guys i want to request a script where normal players can see the list of mvp and mini boss cards in the server by clicking it thank you.

Link to comment
Share on other sites

3 answers to this question

Recommended Posts

  • 0
Spoiler
//Created by Racaae (https://rathena.org/board/topic/129771-mvp-and-mini-boss-card-list/)
aldebaran,144,128,0	script	Card List	4_BOARD3,{
	mes "I can see here the list of mini-boss";
	mes "and MvP cards available in the server.";
	if (.ShowIdInGame)
		mes "Next to each card name is it's Item ID.";
	next;
	switch(select("MvP cards.", "Mini-Boss cards.", "Cancel")) {
		case 1:
			.@m$ = "MvPCards";
			break;
		case 2:
			.@m$ = "MiniBossCards";
			break;
		case 3:
			close;
	}
	for ( .@i = 0; .@i < getarraysize(getd("."+.@m$)); ++.@i ) {
		if (.@i && .@i%6 == 0) {
			.@page++;
			mes "          Page " + .@page;
			next;
		}
		if (.ShowIdInGame)
			mes "(" + getd("."+.@m$+"["+.@i+"]")+") <ITEM>"+replacestr(getitemname(getd("."+.@m$+"["+.@i+"]")), " Card", "")+"<INFO>"+getd("."+.@m$+"["+.@i+"]")+"</INFO></ITEM>";
		else
			mes "<ITEM>"+getitemname(getd("."+.@m$+"["+.@i+"]"))+"<INFO>"+getd("."+.@m$+"["+.@i+"]")+"</INFO></ITEM>";
	}
	mes "          Page " + (.@page+1);
	close;

OnInit:
//=== CONF ===================
	.ShowIdInGame = true; //true or false

	//MvP cards ID
	setarray .MvPCards,4144,4147,4142,4132,4128,4143,4137,4123,4146,4131,
		4148,4121,4135,4318,4324,4168,4305,4276,4134,4330,4263,4236,4302,
		4342,4372,4357,4359,4361,4363,4367,4365,4352,4374,4376,4399,4386,
		4403,4407,4408,4419,4425,4430,4441,4145,27162,4456,4451,4457;

	if (checkre(0)) { //Renewal MvP cards ID
		setarray .MvPCards[getarraysize(.MvPCards)], 27126,4507,4520,4509,
			4525,4526,4527,4528,4529,4560,4561,4562,4563,4564,4565,4566,
			4578,4576,4574,4580,4590,4591,4592,4556,4601,4602,4603,4604,
			4647,4648,4649,4650,4651,4652,27164,27106,4625,27182,4610,
			27020,4636,31026,27180,27150,4662,27151,27081,27152,27113,
			27327,27326,27321,27104,300099,300100,27287,27119,27294,27298,
			300239,300107,300145,300151,300214,300228,300248,300262,27346,
			27329,27362,27363,27305,27318,300078,300079,300080,4697,27319,
			4671,4672,4673,4674,4675,4676,4677,4678,4679,4680,4681,4682,
			4683,31023,300281;
	}
	//Mini-Boss cards ID
	setarray .MiniBossCards,4047,4054,4163,4169,4174,4179,4183,4197,
		4198,4203,4207,4211,4237,4238,4241,4250,4254,4266,4284,4285,
		4290,4291,4300,4306,4320,4336,4354,4384,4395,4396,4397;

	end;
}

 

Add or remove IDs in the arrays to fit your server.

  • Like 1
Link to comment
Share on other sites

  • 0

hi how about the total mvp cards in the sever example only 3 GTB card in the server so other player dont complain how many gtb card 

Link to comment
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

Guest
Answer this question...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.



×
×
  • Create New...

Important Information

By using this site, you agree to our Terms of Use and Privacy Policy.