I need help for Multiple Quest shop please.

JamS · November 28, 2018

Can someone help me to add extra flavor of "Euphy's Quest Shop" script please. I am planning to make the same Quest shop NPC but has multiple shop options categorize for example as:

Shop no. 1.) RENTAL ITEM SHOP and

Shop no. 2.) NON RENTAL ITEM SHOP.

(Sorry for my bad English)

//===== rAthena Script =======================================
//= Euphy's Quest Shop
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.6c
//===== Compatible With: =====================================
//= rAthena Project
//===== Description: =========================================
//= A dynamic quest shop based on Lunar's, with easier config.
//= Includes support for multiple shops & cashpoints.
//= Item Preview script by ToastOfDoom.
//===== Additional Comments: =================================
//= 1.0 Initial script.
//= 1.2 Added category support.
//= 1.3 More options and fixes.
//= 1.4 Added debug settings.
//= 1.5 Replaced categories with shop IDs.
//= 1.6 Added support for purchasing stackables.
//= 1.6a Added support for previewing costumes and robes.
//= 1.6b Added 'disable_items' command.
//= 1.6c Replaced function 'A_An' with "F_InsertArticle".
//============================================================

// Shop NPCs -- supplying no argument displays entire menu.
//    callfunc "qshop"{,<shop ID>{,<shop ID>{,...}}};
//  ADD YOUR NPC HERE
//============================================================
prontera,164,203,6    script    Quest Shop#1    998,{ callfunc "qshop"; }
// prontera,165,203,6    script    Quest Shop#2    998,{ callfunc "qshop",1,2; }    // call the shop 1 and 2 defined below
// etc.. Add your Shop NPCs 'Quest Shop#XXX' here
//============================================================


// Script Core - DO NOT DUPLICATE THIS NPC !!!!!!!!!!!!!
//============================================================
-    script    quest_shop    -1,{
function Add; function Chk; function Slot;
OnInit:
    freeloop(1);

// -----------------------------------------------------------
//  Basic shop settings.
// -----------------------------------------------------------

    set .Announce,1;    // Announce quest completion? (1: yes / 0: no)
    set .ShowSlot,1;    // Show item slots? (2: all equipment / 1: if slots > 0 / 0: never)
    set .ShowID,0;      // Show item IDs? (1: yes / 0: no)
    set .ShowZeny,0;    // Show Zeny cost, if any? (1: yes / 0: no)
    set .MaxStack,100;    // Max number of quest items purchased at one time.

// -----------------------------------------------------------
//  Points variable -- optional quest requirement.
//    setarray .Points$[0],"<variable name>","<display name>";
// -----------------------------------------------------------

    setarray .Points$[0],
        "#CASHPOINTS", "Cash Points";


//=====================================================================================
// ------------------- ADD YOUR SHOPS NAME AND ITEMS SHOPS STARTING HERE --------------
//=====================================================================================

// -----------------------------------------------------------
//  Shop IDs -- to add shops, copy dummy data at bottom of file.
//    setarray .Shops$[1],"<Shop 1>","<Shop 2>"{,...};
// -----------------------------------------------------------

    setarray .Shops$[1],
        "Headgears",    // Shop Named 1
        "Weapons",        // Shop Named 2
        "Other";        // Shop Named 3

// -----------------------------------------------------------
//  Quest items -- do NOT use a reward item more than once!
//    Add(<shop ID>,<reward ID>,<reward amount>,
//        <Zeny cost>,<point cost>,
//        <required item ID>,<required item amount>{,...});
// -----------------------------------------------------------

// Shop 1 ( RENTAL ITEMS) <<-- This shop should be all rental items
    Add(1,5022,1,0,0,7086,1,969,10,999,40,1003,50,984,2);
    Add(1,5032,1,0,0,1059,250,2221,1,2227,1,7063,600);
    Add(1,5027,1,0,0,2252,1,1036,400,7001,50,4052,1);
    Add(1,5045,1,0,0,2252,1,1054,450,943,1200);

// Shop 2 (NON RENTAL) <<-- This shop should be all non rental items
    Add(2,1224,1,0,0,7297,30,969,10,999,50,714,10);
    Add(2,1225,1,0,0,7292,30,969,10,999,50,714,10);

// Shop 3 (NON RENTAL) <<-- This shop should be all non rental items
    Add(3,531,1,3,0,512,1,713,1);
    Add(3,532,1,3,0,513,1,713,1);
    Add(3,533,1,3,0,514,1,713,1);
    Add(3,534,1,3,0,515,1,713,1);

// -----------------------------------------------------------

//=====================================================================================
// ------------------- YOUR SHOPS AND ITEMS SHOPS HAVE BEEN ADDED ---------------------
//=====================================================================================

    freeloop(0);
    set .menu$,"";
    for(set .@i,1; .@i<=getarraysize(.Shops$); set .@i,.@i+1) {
        set .menu$, .menu$+.Shops$[.@i]+":";
        npcshopdelitem "qshop"+.@i,909;
    }
    end;

OnMenu:
    set .@size, getarraysize(@i);
    if (!.@size) set @shop_index, select(.menu$);
    else if (.@size == 1) set @shop_index, @i[0];
    else {
        for(set .@j,0; .@j<.@size; set .@j,.@j+1)
            set .@menu$, .@menu$+.Shops$[@i[.@j]]+":";
        set @shop_index, @i[select(.@menu$)-1];
    }
    deletearray @i[0],getarraysize(@i);
    if (.Shops$[@shop_index] == "") {
        message strcharinfo(0),"An error has occurred.";
        end;
    }
    dispbottom "Select one item at a time.";
    callshop "qshop"+@shop_index,1;
    npcshopattach "qshop"+@shop_index;
    end;

OnBuyItem:
    // .@q[] : RewardID, BoughtAmt, RewardAmt, BaseAmt, ReqZeny, ReqPts, { ReqItem, ReqAmt, ... }
    setarray .@q[0],@bought_nameid[0],((@bought_quantity[0] > .MaxStack)?.MaxStack:@bought_quantity[0]);
    copyarray .@q[3],getd(".q_"+@shop_index+"_"+.@q[0]+"[0]"),getarraysize(getd(".q_"+@shop_index+"_"+.@q[0]));
    set .@q[2],.@q[1]*.@q[3];
    if (!.@q[2] || .@q[2] > 30000) {
        message strcharinfo(0),"You can't purchase that many "+getitemname(.@q[0])+".";
        end;
    }
    mes "[Quest Shop]";
    mes "Reward: ^0055FF"+((.@q[2] > 1)?.@q[2]+"x ":"")+Slot(.@q[0])+"^000000";
    mes "Requirements:";
    disable_items;
    if (.@q[4]) mes " > "+Chk(Zeny,.@q[4]*.@q[1])+(.@q[4]*.@q[1])+" Zeny^000000";
    if (.@q[5]) mes " > "+Chk(getd(.Points$[0]),.@q[5]*.@q[1])+(.@q[5]*.@q[1])+" "+.Points$[1]+" ("+getd(.Points$[0])+"/"+(.@q[5]*.@q[1])+")^000000";
    if (.@q[6]) for(set .@i,6; .@i<getarraysize(.@q); set .@i,.@i+2)
        mes " > "+Chk(countitem(.@q[.@i]),.@q[.@i+1]*.@q[1])+((.ShowID)?"{"+.@q[.@i]+"} ":"")+Slot(.@q[.@i])+" ("+countitem(.@q[.@i])+"/"+(.@q[.@i+1]*.@q[1])+")^000000";
    next;
    setarray @qe[1], getiteminfo(.@q[0],5), getiteminfo(.@q[0],11);
    if (@qe[2] > 0 && ((@qe[1] & EQP_HEAD_LOW) || (@qe[1] & EQP_HEAD_TOP) || (@qe[1] & EQP_HEAD_MID) || (@qe[1] & EQP_COSTUME_HEAD_TOP) || (@qe[1] & EQP_COSTUME_HEAD_MID) || (@qe[1] & EQP_COSTUME_HEAD_LOW) || (@qe[1] & EQP_GARMENT) || (@qe[1] & EQP_COSTUME_GARMENT)))
        set .@preview,1;
    addtimer 1000, strnpcinfo(0)+"::OnEnd";
    while(1) {
        switch(select(" ~ Purchase ^0055FF"+getitemname(.@q[0])+"^000000:"+((.@preview && !@qe[7])?" ~ Preview...":"")+": ~ ^777777Cancel^000000")) {
        case 1:
            if (@qe[0]) {
                mes "[Quest Shop]";
                mes "You're missing one or more quest requirements.";
                close;
            }
            if (!checkweight(.@q[0],.@q[2])) {
                mes "[Quest Shop]";
                mes "^FF0000You need "+(((.@q[2]*getiteminfo(.@q[0],6))+Weight-MaxWeight)/10)+" additional weight capacity to complete this trade.^000000";
                close;
            }
            if (.@q[4]) set Zeny, Zeny-(.@q[4]*.@q[1]);
            if (.@q[5]) setd .Points$[0], getd(.Points$[0])-(.@q[5]*.@q[1]);
            if (.@q[6]) for(set .@i,6; .@i<getarraysize(.@q); set .@i,.@i+2)
                delitem .@q[.@i],.@q[.@i+1]*.@q[1];
            getitem .@q[0],.@q[2];
            if (.Announce) announce strcharinfo(0)+" has created "+((.@q[2] > 1)?.@q[2]+"x "+getitemname(.@q[0]):callfunc("F_InsertArticle",getitemname(.@q[0])))+"!",0;
            specialeffect2 EF_FLOWERLEAF;
            close;
        case 2:
            setarray @qe[3], getlook(LOOK_HEAD_BOTTOM), getlook(LOOK_HEAD_TOP), getlook(LOOK_HEAD_MID), getlook(LOOK_ROBE), 1;
            if ((@qe[1] & 1) || (@qe[1] & 4096)) changelook LOOK_HEAD_BOTTOM, @qe[2];
            else if ((@qe[1] & 256) || (@qe[1] & 1024)) changelook LOOK_HEAD_TOP, @qe[2];
            else if ((@qe[1] & 512) || (@qe[1] & 2048)) changelook LOOK_HEAD_MID, @qe[2];
            else if ((@qe[1] & 4) || (@qe[1] & 8192)) changelook LOOK_ROBE, @qe[2];
            break;
        case 3:
            close;
        }
    }

OnEnd:
    if (@qe[7]) {
        changelook LOOK_HEAD_BOTTOM, @qe[3];
        changelook LOOK_HEAD_TOP, @qe[4];
        changelook LOOK_HEAD_MID, @qe[5];
        changelook LOOK_ROBE, @qe[6];
    }
    deletearray @qe[0],8;
    end;

function Add {
    if (getitemname(getarg(1)) == "null") {
        debugmes "Quest reward #"+getarg(1)+" invalid (skipped).";
        return;
    }
    setarray .@j[0],getarg(2),getarg(3),getarg(4);
    for(set .@i,5; .@i<getargcount(); set .@i,.@i+2) {
        if (getitemname(getarg(.@i)) == "null") {
            debugmes "Quest requirement #"+getarg(.@i)+" invalid (skipped).";
            return;
        } else
            setarray .@j[.@i-2],getarg(.@i),getarg(.@i+1);
    }
    copyarray getd(".q_"+getarg(0)+"_"+getarg(1)+"[0]"),.@j[0],getarraysize(.@j);
    npcshopadditem "qshop"+getarg(0),getarg(1),((.ShowZeny)?getarg(3):0);
    return;
}

function Chk {
    if (getarg(0) < getarg(1)) {
        set @qe[0],1;
        return "^FF0000";
    } else
        return "^00FF00";
}

function Slot {
    set .@s$,getitemname(getarg(0));
    switch(.ShowSlot) {
        case 1: if (!getitemslots(getarg(0))) return .@s$;
        case 2: if (getiteminfo(getarg(0),2) == 4 || getiteminfo(getarg(0),2) == 5) return .@s$+" ["+getitemslots(getarg(0))+"]";
        default: return .@s$;
    }
}
}

function    script    qshop    {
    deletearray @i[0],getarraysize(@i);
    for(set .@i,0; .@i<getargcount(); set .@i,.@i+1)
        set @i[.@i],getarg(.@i);
    doevent "quest_shop::OnMenu";
    end;
}


// Dummy shop data -- copy as needed.
//============================================================
-    shop    qshop1    -1,909:-1
-    shop    qshop2    -1,909:-1
-    shop    qshop3    -1,909:-1
-    shop    qshop4    -1,909:-1
-    shop    qshop5    -1,909:-1


// Shop 1 ( RENTAL ITEMS) <<-- This shop should be all rental items
    Add(1,5022,1,0,0,7086,1,969,10,999,40,1003,50,984,2);
    Add(1,5032,1,0,0,1059,250,2221,1,2227,1,7063,600);
    Add(1,5027,1,0,0,2252,1,1036,400,7001,50,4052,1);
    Add(1,5045,1,0,0,2252,1,1054,450,943,1200);

// Shop 2 (NON RENTAL) <<-- This shop should be all non rental items
    Add(2,1224,1,0,0,7297,30,969,10,999,50,714,10);
    Add(2,1225,1,0,0,7292,30,969,10,999,50,714,10);

// Shop 3 (NON RENTAL) <<-- This shop should be all non rental items
    Add(3,531,1,3,0,512,1,713,1);
    Add(3,532,1,3,0,513,1,713,1);
    Add(3,533,1,3,0,514,1,713,1);
    Add(3,534,1,3,0,515,1,713,1);

Edited January 6, 2019 by Emistry
Please use codebox

n0tttt · November 28, 2018

Change:

Quote

getitem .@q[0],.@q[2];

to:

Quote

       if(@shop_index == <your rental shop number>)
           rentitem .@q[0],<rental time>;
       else
           getitem .@q[0],.@q[2];

And don't forget to put the name here:

Quote

   setarray .Shops$[1],
       "Headgears",   // Shop Named 1
       "Weapons",       // Shop Named 2
       "Other";       // Shop Named 3

Something like [Rental] Headgears

n0tttt · November 29, 2018

Show the whole script.

JamS · November 29, 2018

Sir @n0tttt thank you so much for your response. Unfortunately the one that you said is not working and it is showing like this:

image.png.2c9c1ddc959c04b7c94a9ec74fc74172.png

and this is the code I put:

            if(@shop_index == 1)
            rentitem .@q[0],604800;
           else
           getitem .@q[0],.@q[2];

@n0tttt sorry sir my bad.. I accidentally change the required items that is why its not showing.. Problem solve now.. Thank you so much sir!!..

and sir @n0tttt do you have an idea how to put this in the NPC PERMANENTLY ?

like this:

n0tttt · November 29, 2018

Change for example this:

prontera,164,203,6	script	Quest Shop#1	998,{ callfunc "qshop"; }

To this:

prontera,164,203,6	script	Quest Shop#1	998,{

	callfunc "qshop";
	end;

OnInit:

	getmapflag .m$,.@x,.@y,UNITTYPE_NPC;
	setmapflag .m$,mf_loadevent;
	end;

OnPCLoadMapEvent:

	if(strcharinfo(3) == .m$)
		showevent QTYPE_QUEST;
	end;
}

Sign In

I need help for Multiple Quest shop please.

Question

JamS

Link to comment

Share on other sites

4 answers to this question

Recommended Posts

n0tttt

Link to comment

Share on other sites

n0tttt

Link to comment

Share on other sites

JamS

Link to comment

Share on other sites

n0tttt

Link to comment

Share on other sites

Join the conversation

Recently Browsing 0 members

Docs

Get Started

Github

Community

My Account