GmSupportRequest

[max65]

Hi, i need your help for, this script:

Quote

// -------------------------------------------------------------------------------------------------
// Original Script by: greenmagic469
// Modified by: Panda - GM Kazehaya
// - Knights Ragnarok Online -
// v1.0(Original) - Simple @request sent to GMs
// v1.1 - Added Delay and Number of GMs online
// v1.2 - Added changing waitingroom title and check if there are available GMs
// - Modification End -
// -------------------------------------------------------------------------------------------------

prontera,148,195,5    script    GM Support Assistant    469,{

if(.GM_Online < 1  ){ mes "[ ^FF55FFGM Support Assistant^000000; ]"; mes "No available GMs."; close; }
mes "[ ^FF55FFGM Support Assistant^000000; ]";
mes "Number of GM(s) online: "+.GM_Online;
mes "Would you like to contact them?";
menu "Send a help request.",P_1,"Quit.",P_2;

P_1:
if(gettimetick(2) < #HelpDelay) {
        mes "You may only send a message every 5 minutes!";
        close;
}
atcommand "@request This player is in need of assistance.";
dispbottom "Notified the Game Masters.";
set #HelpDelay,gettimetick(2)+300;
emotion e_hlp;
close;
end;

P_2:
close;

OnInit:
set .MinGMLevel,10;
    reload:
    delwaitingroom;
    waitingroom "Number of online GMs: "+.GM_Online+"",0;
    sleep2 3000;
    delwaitingroom;
    waitingroom "Do you want to contact GMs?",0;
    sleep2 3000;
    delwaitingroom;
    waitingroom "If you need assistance, please click me.",0;
    sleep2 3000;
    goto reload;
end;

OnPCLoginEvent:
if( getgmlevel() >= .MinGMLevel ){
set .GM_Online,.GM_Online+1;
end;
}
else
end;

OnPCLogoutEvent:
if( getgmlevel() >= .MinGMLevel ){
set .GM_Online,.GM_Online-1;
end;
}
else
end;

}

my mapserv.bat tell me (

How i can solved that plz? ^^

 

[pajodex]

don't use `sleep2`

 

Quoted from doc/script_commands.txt

sleep 10000; //pause the script for 10 seconds and ditch the RID (so no player is attached anymore)
sleep2 5000; //pause the script for 5 seconds, and continue with the RID attached.

 

I didn't test this but ohh well...

prontera,148,195,5	script	GM Support Assistant	469,{
	mes .n$;
	if ( !.onlinegm ) {
		mes "No available GMs at the moment";
		close;
	}
	mes "No. of GMs Online :"+ .onlinegm;
	mes " ";
	mes "Would you like to contact them?";
	next;
	if(select("Yes","No")==2) close;
	mes .n$;
	if(gettimetick(2) < #HelpDelay) {
		mes "You may only send a message every 5 minutes!";
        close;
	}
	atcommand "@request This player is in need of assistance.";
	#HelpDelay = gettimetick(2) + 300;
	mes "Game Masters has been notified.";
	close;

OnPCLoginEvent:
	if ( getgmlevel() > 10 ) 
		++.onlinegm; 
	end;
		
OnPCLogoutEvent:
	if ( getgmlevel() > 10 ) 
		--.onlinegm; 
	end;
	
OnInit:
	.n$ = "[ ^FF55FFGM Support Assistant^000000; ]";
L_Reload:
	waitingroom "Number of online GMs: "+.onlinegm,0;
	sleep 3000;
	delwaitingroom;
	waitingroom "Do you want to contact GMs?",0;
	sleep 3000;
	delwaitingroom;
	waitingroom "If you need assistance, please click me.",0;
	sleep 3000;
	delwaitingroom;
	goto L_Reload;
	end;
}

 

Edited October 19, 2018 by pajodex

[max65]

Thx ^^