n0tttt

March 2, 2020

Either integrate the part onto the script or use close2 + doevent.

February 28, 2020

Try changing BL_PC to UNITTYPE_PC. It seems like you have an outdated rAthena.

February 27, 2020

Like this?

-	script	reset_map	-1,{

OnInit:

	setarray .maplist$[0],"prt_fild08";
	end;

OnPCLogoutEvent:

	if(inarray(.maplist$,strcharinfo(3)) != -1) {
		getmapxy map$,x,y,BC_PC;
		logout_count++;
	}
	end;

OnPCLoginEvent:

	if(logout_count == 1) {
		warp map$,x,y;
		logout_count = 0;
		map$ = "";
		x = y = 0;
	} else if(inarray(.maplist$,strcharinfo(3)) != -1) {
		warp "SavePoint",0,0;
	}
	end;

}

January 14, 2020

3 hours ago, Xenduria said:

Can someone help me fix these errors. The npc wont even work.

Also is there a way to remove the Devil square? I already have my own custom one running.

It seems like you don't have or aren't loading Global_Functions.txt (https://raw.githubusercontent.com/rathena/rathena/master/npc/other/Global_Functions.txt)

You can delete the line in add_event, and also the Event_DevilSquare script.

November 24, 2019

Isn't this based on my own modification?

The var names and announce hex colors are even the same.

November 12, 2019

On 10/27/2019 at 11:35 AM, noobzter003 said:

error


script error on npc/custom/wbosshp.txt line 23
    parse_simpleexpr: unmatched ')'
    18 : OnHPBar:
    19 :        .@U_MAXHP = getunitdata (.mobGID,UMOB_MAXHP);
    20 :        while (.HP_Bar != false)
    21 :        {
    22 :                .@U_HP = getunitdata (.mobGID,UMOB_HP);
*   23 :                .@P_HP = (@'.'U_HP*100)/.@U_MAXHP;
    24 :
    25 :                cutin(.@P_HP+"", 1);
    26 :
    27 :                sleep2 100;
    28 :        }
[Info]: Done loading '12340' NPCs:
        -'2929' Warps
        -'188' Shops
        -'9223' Scripts
        -'3876' Spawn sets
        -'39591' Mobs Cached
        -'0' Mobs Not Cached

code:


payon,147,229,4	script	Test#HPbar	1_F_MARIA,{

	if (.HP_Bar == false)
	{
		.HP_Bar = true;
		.mobGID = monster ("payon",148,226,"[T] HP Test",1031,1,strnpcinfo(0)+"::OnDie");
		setunitdata .mobGID,UMOB_MAXHP,4000;
		setunitdata .mobGID,UMOB_HP,4000;
		addrid(5, "payon");
		addtimer(1000, strnpcinfo(0)+"::OnHPBar");
	}
	end;

OnDie:
	.HP_Bar = false;
	end;

OnHPBar:
	.@U_MAXHP = getunitdata (.mobGID,UMOB_MAXHP);
	while (.HP_Bar != false)
	{
		.@U_HP = getunitdata (.mobGID,UMOB_HP);
		.@P_HP = (@.U_HP*100)/.@U_MAXHP;

		cutin(.@P_HP+"", 1);

		sleep2 100;
	}
	cutin("0_hpbar", 1);
	sleep2 5000; //Delay to hide HP Bar
	cutin("", 255);
	end;
}

TIA

.@P_HP = (@'.'U_HP*100)/.@U_MAXHP;

to:

.@P_HP = (.@U_HP*100)/.@U_MAXHP;

August 10, 2019

On 7/31/2019 at 10:34 PM, omar94 said:

I bought it. But i dont know how to install.

Could you help me? or someone?

Have an exellent day

Just go to your rAthena npc folder and edit script_custom.conf with Notepad.

Add this line anywhere:

npc: npc/custom/Events.txt

Then copy the "Events.txt" file into the npc/custom folder.

You can now talk in-game to the script using @events script command.

June 19, 2019

On 6/12/2019 at 12:58 PM, fenrirdev said:

how to remove the @pvp command?

You could delete the bindatcmd line, but better use this one since I deleted it altogether:

/*
	Changelog:

	v1.1 	Added option to debuff players when entering the room.
		Added command to rotate manually.
		Remove hiding when quitting room.
		Added lvl checking on command.

	v1.1a	Removed right curly which made dispell function don't work. Sorry.
		Added color to the npc name in dialog.
		Added F_InsertPlural use.

	v1.2    Added waitingroom with player count.
*/

// You can use this function with other scripts as well.
function	script	dispell	{

	while(.@i++ < SC_SPL_MATK) {
		if(
			.@i != SC_WEIGHT50 &&
			.@i != SC_WEIGHT90 &&
			.@i != SC_NOCHAT &&
			.@i != SC_BABY &&
			/*
			.@i != SC_WEDDING &&
			.@i != SC_XMAS &&
			.@i != SC_SUMMER &&
			.@i != SC_HANBOK &&
			.@i != SC_OKTOBERFEST &&
			*/
			.@i != SC_JAILED &&
			.@i != SC_EXPBOOST &&
			.@i != SC_ITEMBOOST
		)
			sc_end .@i;
	}
	.@i = SC_FEAR;
	while(.@i++ < SC_AKAITSUKI)
		sc_end .@i;

}

prontera,147,172,6	script	PvP#0	4_M_SAKRAYROYAL,{

	.@n$ = "^3227cd[PvP Room]^000000";
	mes .@n$;
	if(BaseLevel >= .min_lv) {
		mes "There are ^d40f00"+F_InsertPlural(getmapusers(.map$),"player")+"^000000 inside right now.";
		mes "Do you want to enter to the room?";
		if(.debuff)
			mes "^8b0d1fBe careful, because every buff you have will be lost upon entering the room.^000000";
		next;
		if(select("Yes.","No, thanks.") == 1) {
			specialeffect2 F_Rand(EF_STORMKICK1,EF_STORMKICK2,EF_STORMKICK3,EF_STORMKICK6,EF_STORMKICK7);
			sleep2 600;
			specialeffect2 F_Rand(EF_SPINMOVE,EF_CASTSPIN2);
			sleep2 550;
			if(.debuff)
				dispell();
			warp .map$,0,0;
			mapannounce .map$,strcharinfo(0)+" has entered the room.",bc_map,0xb50505;
			if(!.waiting_room)
				donpcevent "PvP#0::OnWaitingRoom";
		}
	} else {
		mes "You must be at least level "+.min_lv+" to be able to enter the room.";
		close;
	}
	end;

OnInit:

	// Command to rotate the room maually.
	bindatcmd "rotatepvp","PvP#0::OnMinute00",60;

	// Min LvL to enter the room.
	.min_lv = 50;

	// Will players be dispelled upon entering the room?
	.debuff = false;

OnMinute00:
OnMinute30:

	// PvP maps go here. Change them as you wish.
	setarray .@maps$[0], "guild_vs2","guild_vs3","guild_vs5","pvp_y_1-1","guild_vs4","guild_vs1","arena_room";

	// Max amount of times a map can be repeated. 0 = unlimited.
	.@row = 3;

	.@size = getarraysize(.@maps$);

	if(.map$ == "") {

		// You can edit the room mapflags here.
		setarray .@mapfl[0], 	mf_nosave,
					mf_nodrop,
					mf_novending,
					mf_noteleport,
					mf_noreturn,
					mf_nowarp,
					mf_nowarpto,
					mf_nomemo,
					mf_nopenalty,
					mf_nobranch,
					mf_hidemobhpbar,
					mf_pvp,
					mf_pvp_noguild,
					mf_pvp_noparty,
					mf_pvp_nocalcrank,
					mf_loadevent;

		.@i = getarraysize(.@mapfl);
		while(.@i--) {
			.@j = .@size;
			while(.@j--)
				setmapflag .@maps$[.@j],.@mapfl[.@i];
		}

	}

	.@map$ = .map$;
	.@r    = rand(.@size);
	.map$  = .@maps$[.@r];
	if(.@row && .map$ == .@map$) {
		if(++.row >= .@row) {
			deletearray .@maps$[.@r],1;
			.map$ = .@maps$[rand(.@size - 1)];
			.row  = 0;
		}
	} else if(.row) {
		.row = 0;
	}
	if(.map$ != .@map$ && .@map$ != "") {
		mapwarp .@map$,.map$,0,0;
		sleep 2500;
		mapannounce .map$,"The PvP Room has changed!",bc_npc,0xe53a12;
	}
	end;

OnWaitingRoom:

	.waiting_room = true;
	while(true) {
		.@count = getmapusers(.map$);
		if(.@count != .@old_count) {
			.@old_count = .@count;
			delwaitingroom;
			waitingroom F_InsertPlural(.@count,"player")+".",0;
		}
		sleep 2500;
	}
	end;

}

March 23, 2019

Probably the map you warped to didn't have the mf_loadevent mapflag.

You can use this version anyways. I avoided doing it this way since it can cause a bit of lagging.

/*
	Changelog:

	v1.1 	Added option to debuff players when entering the room.
		Added command to rotate manually.
		Remove hiding when quitting room.
		Added lvl checking on command.

	v1.1a	Removed right curly which made dispell function don't work. Sorry.
		Added color to the npc name in dialog.
		Added F_InsertPlural use.

	v1.2    Added waitingroom with player count.

	v1.3    Use of pcblock command.
*/

// You can use this function with other scripts as well.
function	script	dispell	{

	while(.@i++ < SC_SPL_MATK) {
		if(
			.@i != SC_WEIGHT50 &&
			.@i != SC_WEIGHT90 &&
			.@i != SC_NOCHAT &&
			.@i != SC_BABY &&
			/*
			.@i != SC_WEDDING &&
			.@i != SC_XMAS &&
			.@i != SC_SUMMER &&
			.@i != SC_HANBOK &&
			.@i != SC_OKTOBERFEST &&
			*/
			.@i != SC_JAILED &&
			.@i != SC_EXPBOOST &&
			.@i != SC_ITEMBOOST
		)
			sc_end .@i;
	}
	.@i = SC_FEAR;
	while(.@i++ < SC_AKAITSUKI)
		sc_end .@i;

}

prontera,147,172,6	script	PvP#0	4_M_SAKRAYROYAL,{

	.@n$ = "^3227cd[PvP Room]^000000";
	mes .@n$;
	if(BaseLevel >= .min_lv) {
		mes "There are ^d40f00"+F_InsertPlural(getmapusers(.map$),"player")+"^000000 inside right now.";
		mes "Do you want to enter to the room?";
		if(.debuff)
			mes "^8b0d1fBe careful, because every buff you have will be lost upon entering the room.^000000";
		next;
		if(select("Yes.","No, thanks.") == 1) {
			specialeffect2 F_Rand(EF_STORMKICK1,EF_STORMKICK2,EF_STORMKICK3,EF_STORMKICK6,EF_STORMKICK7);
			sleep2 600;
			specialeffect2 F_Rand(EF_SPINMOVE,EF_CASTSPIN2);
			sleep2 550;
			if(.debuff)
				dispell();
			warp .map$,0,0;
			mapannounce .map$,strcharinfo(0)+" has entered the room.",bc_map,0xb50505;
			if(!.waiting_room)
				donpcevent "PvP#0::OnWaitingRoom";
		}
	} else {
		mes "You must be at least level "+.min_lv+" to be able to enter the room.";
		close;
	}
	end;

OnInit:

	// This command can be used to enter the PvP Room.
	bindatcmd "pvp","PvP#0::OnCommand";

	// Command to rotate the room maually.
	bindatcmd "rotatepvp","PvP#0::OnMinute00",60;

	// Min LvL to enter the room.
	.min_lv = 50;

	// Will players be dispelled upon entering the room?
	.debuff = false;

OnMinute00:
OnMinute30:

	// PvP maps go here. Change them as you wish.
	setarray .@maps$[0], "guild_vs2","guild_vs3","guild_vs5","pvp_y_1-1","guild_vs4","guild_vs1","arena_room";

	// Max amount of times a map can be repeated. 0 = unlimited.
	.@row = 3;

	.@size = getarraysize(.@maps$);

	if(.map$ == "") {

		// You can edit the room mapflags here.
		setarray .@mapfl[0], 	mf_nosave,
					mf_nodrop,
					mf_novending,
					mf_noteleport,
					mf_noreturn,
					mf_nowarp,
					mf_nowarpto,
					mf_nomemo,
					mf_nopenalty,
					mf_nobranch,
					mf_hidemobhpbar,
					mf_pvp,
					mf_pvp_noguild,
					mf_pvp_noparty,
					mf_pvp_nocalcrank,
					mf_loadevent;

		.@i = getarraysize(.@mapfl);
		while(.@i--) {
			.@j = .@size;
			while(.@j--)
				setmapflag .@maps$[.@j],.@mapfl[.@i];
		}

	}

	.@map$ = .map$;
	.@r    = rand(.@size);
	.map$  = .@maps$[.@r];
	if(.@row && .map$ == .@map$) {
		if(++.row >= .@row) {
			deletearray .@maps$[.@r],1;
			.map$ = .@maps$[rand(.@size - 1)];
			.row  = 0;
		}
	} else if(.row) {
		.row = 0;
	}
	if(.map$ != .@map$ && .@map$ != "") {
		mapwarp .@map$,.map$,0,0;
		sleep 2500;
		mapannounce .map$,"The PvP Room has changed!",bc_npc,0xe53a12;
	}
	end;

OnCommand:

	.@ins_id = instance_id();
	.@m$ = strcharinfo(3);
	if((!.@ins_id || instance_mapname(.@m$,.@ins_id) == "") && BaseLevel >= .min_lv) {
		if(.@m$ != .map$) {
			message strcharinfo(0),"Preparing to enter!";
		} else {
			message strcharinfo(0),"Quitting the room...";
			unitstopwalk getcharid(3);
			//pcblock PCBLOCK_MOVE|PCBLOCK_ATTACK|PCBLOCK_SKILL,true;
			pcblockmove getcharid(3),true;
			pcblockskill getcharid(3),true;
			setoption OPTION_HIDE|OPTION_CLOAK|OPTION_CHASEWALK,false;
		}
		.@hp = HP;
		sleep2 1400;
		while(.@i++ < 5) {
			message strcharinfo(0),(6 - .@i)+"...";
			sleep2 990;
			if(HP < .@hp) {
				message strcharinfo(0),"You can't do this in the middle of a battle.";
				//pcblock PCBLOCK_MOVE|PCBLOCK_ATTACK|PCBLOCK_SKILL,false;
				pcblockmove getcharid(3),false;
				pcblockskill getcharid(3),false;
				end;
			}
		}
		specialeffect2 F_Rand(EF_STORMKICK1,EF_STORMKICK2,EF_STORMKICK3,EF_STORMKICK6,EF_STORMKICK7);
		sleep2 600;
		specialeffect2 F_Rand(EF_SPINMOVE,EF_CASTSPIN2);
		sleep2 550;
		if(.@m$ != .map$) {
			if(.debuff)
				dispell();
			warp .map$,0,0;
			mapannounce .map$,strcharinfo(0)+" has entered the room.",bc_map,0xb50505;
			if(!.waiting_room)
				donpcevent "PvP#0::OnWaitingRoom";
		} else {
			warp "SavePoint",0,0;
			//pcblock PCBLOCK_MOVE|PCBLOCK_ATTACK|PCBLOCK_SKILL,false;
			pcblockmove getcharid(3),false;
			pcblockskill getcharid(3),false;
		}
	} else if(BaseLevel < .min_lv) {
		message strcharinfo(0),"You must be at least level "+.min_lv+" to be able to enter the room.";
	} else {
		message strcharinfo(0),"You can't enter the room in the middle of an instance.";
	}
	end;

OnWaitingRoom:

	.waiting_room = true;
	while(true) {
		.@count = getmapusers(.map$);
		if(.@count != .@old_count) {
			.@old_count = .@count;
			delwaitingroom;
			waitingroom F_InsertPlural(.@count,"player")+".",0;
		}
		sleep 2500;
	}
	end;

}

March 22, 2019

8 minutes ago, Break said:


[Warning]: script: buildin_getmapxy: Invalid type 128.
[Debug]: Source (NPC): Clucker at prontera (163,226)
[Debug]: (map_mapname2mapid) mapindex_name2id: Map "" not found in index list!

You don't have the last version of rAthena.

But you can change this line:

getmapxy .@m$,.@x0,.@y0,BL_NPC;

to:

getmapxy .@m$,.@x0,.@y0,UNITTYPE_NPC;

March 19, 2019

On 3/16/2019 at 7:27 AM, Break said:


[Debug]: NPCEvent 'Eventos::OnEndEvent' not found! (source: Event_DevilSquare)

Fixed, waiting for revision.

February 12, 2019

payon,147,229,4    script    Test#HPbar    1_F_MARIA,{

	if (.HP_Bar == false)
	{
		.HP_Bar = true;
		.mobGID = monster ("payon",148,226,"[T] HP Test",1031,1,strnpcinfo(0)+"::OnDie");
		setunitdata .mobGID,UMOB_MAXHP,4000;
		setunitdata .mobGID,UMOB_HP,4000;
		.@count = getmapunits(BL_PC, "payon", .@units);
		for (.@i = 0; .@i < .@count; .@i++)
		{
			attachrid .@units[.@i];
			addtimer(0,strnpcinfo(0)+"::OnHPBar");
		}
	}
	end;

OnDie:
	.HP_Bar = false;
	end;

OnHPBar:
	.@U_MAXHP = getunitdata (.mobGID,UMOB_MAXHP);
	while (.HP_Bar != false)
	{
		.@U_HP = getunitdata (.mobGID,UMOB_HP);
		.@P_HP = (@.U_HP*100)/.@U_MAXHP;

		cutin(.@P_HP+"", 1);

		sleep2 100;
	}
	cutin("0_hpbar", 1);
	sleep2 5000; //Delay to hide HP Bar
	cutin("", 255);
	end;
}

This could be done for every MvP, but the way it's done (by adding a script and an attach every player on the map, adding new players on the map, and show them the HP every 100ms) would generate a lot of lag. I'd recommend using this for a special event mostly, and even that would be resource-intensive. Another way could be adding only the characters who attack the MvP with a custom label like OnAttack. I think there's such a label floating around boards.

February 10, 2019

Something like this?

-	script	Hourly_Rewards	-1,{

OnAddMinute:

	#online_time++;
	if(#online_time % 5 == 0) {
		dispbottom "Time online: "+Time2Str(#online_time*60 + gettimetick(2))+".";
		if(#online_time % 60 == 0) {
			.@old_points = #hourly_points;
			.@reward = ((#online_time / 60) + 5)%6 + 1;
			switch(.@reward) {
			case 1:
				#hourly_points += 10;
				break;
			case 2:
				#hourly_points += 20;
				break;
			case 3:
				#hourly_points += 30;
				break;
			case 4:
				#hourly_points += 10;
				break;
			case 5:
				#hourly_points += 10;
				break;
			case 6:
				#hourly_points += 30;
				break
			}
			dispbottom "You won "+(#hourly_points - .@old_points)+" points. Current amount:"+F_InsertComma(#hourly_points)+".";
		}
	}

OnPCLoginEvent:

	addtimer 60000,"Hourly_Rewards::OnAddMinute";
	end;

}

February 10, 2019

I didn't read completely. In any case, he can disable every NPC, disable every outside player, and disable every item or skill which might warp players out of there.

Something like this?

-	script	Event_Novice	-1,{

	bindatcmd "startnovice","Event_Novice::OnStart";
	bindatcmd "endnovice","Event_Novice::OnEnd";
	end;

OnStart:

	setmapflag "new_1-1",mf_noexp;
	setmapflag "new_1-1",mf_nowarp;
	setmapflag "new_1-1",mf_nowarpto;
	setmapflag "new_1-1",mf_noskill;
	setmapflag "new_1-1",mf_noitemconsumption;
	setmapflag "new_1-1",mf_loadevent;
	.size = getunits(BL_NPC,"new_1-1",.npc$);
	freeloop true;
	for(.@i = 0;.@i < .size;.@i++)
		disablenpc .npc$[.@i];
/*
	.@size = getunits(BL_MOB,"new_1-1",.@mob);
	for(.@i = 0;.@i < .@size;.@i++)
		unitkill .@mob[.@i];
*/
	.@size = getunits(BL_PC,"new_1-1",.@player$);
	for(.@i = 0;.@i < .@size;.@i++) {
		if(readparam(Class,.@player$[.@i]) != Job_Novice)
			warp "SavePoint",0,0,getcharid(0,.@player$[.@i]);
	}
	freeloop false;
	end;

OnEnd:

	for(.@i = 0;.@i < .size;.@i++)
		enablenpc .npc$[.@i];
	deletearray .npc$;
	.size = 0;
	removemapflag "new_1-1",mf_noexp;
	removemapflag "new_1-1",mf_nowarp;
	removemapflag "new_1-1",mf_nowarpto;
	removemapflag "new_1-1",mf_noskill;
	removemapflag "new_1-1",mf_noitemconsumption;
	removemapflag "new_1-1",mf_loadevent;
	end;

OnPCLoadMapEvent:

	if(strcharinfo(3) == "new_1-1" && Class != Job_Novice)
		warp "SavePoint",0,0;
	end;

}

I don't know what kind of event it is (GM-controlled?), but if he needs some NPCs, he can just add them with enablenpc.

Forgot to mention why I added noexp. In case some people create party or guild. Actually don't remember how it works for guilds, but if it does like I think, player couldn't lvl up then couldn't join a guild and then escape by Emergency Recall or something like that. Anyways I don't know what kind of event is this (Zombie event?).

February 10, 2019

7 hours ago, AnnieRuru said:
if I understand this correctly, *jobcanentermap script command works together with db/re/job_noenter_map.txt
the script command only return 0 or 1, depends on the setting from job_noenter_map.txt

in other words, just a simple
if ( Class == Job_Novice ) return 0;
do the same thing as the script command

it doesn't warp out the players, kick or anything ... just return value 0 or 1

It also checks on warps.

npc.cpp:

	switch(mapdata->npc[i]->subtype) {
		case NPCTYPE_WARP:
			if ((!mapdata->npc[i]->trigger_on_hidden && (pc_ishiding(sd) || (sd->sc.count && sd->sc.data[SC_CAMOUFLAGE]))) || pc_isdead(sd))
				break; // hidden or dead chars cannot use warps
			if (!pc_job_can_entermap((enum e_job)sd->status.class_, map_mapindex2mapid(mapdata->npc[i]->u.warp.mapindex), sd->group_level))
				break;
			if(sd->count_rewarp > 10){
				ShowWarning("Prevented infinite warp loop for player (%d:%d). Please fix NPC: '%s', path: '%s'\n", sd->status.account_id, sd->status.char_id, mapdata->npc[i]->exname, mapdata->npc[i]->path);
				sd->count_rewarp=0;
				break;
			}
			pc_setpos(sd,mapdata->npc[i]->u.warp.mapindex,mapdata->npc[i]->u.warp.x,mapdata->npc[i]->u.warp.y,CLR_OUTSIGHT);
			break;

February 9, 2019

-	script	Sample	-1,{

OnPCLoginEvent:
	mes "[Points Viewer]";
	mes "Hello "+strcharinfo(0);
	mes ""+#CASHPOINTS+" Cash and "+#KAFRAPOINTS+" Free Cash.";
	mes "-----------------------------------";
	mes "Time VIP left";
	mes Time2Str(vip_status(VIP_STATUS_REMAINING) + gettimetick(2));
	mes "-----------------------------------";
	close;
}

Or

Time2Str(VIP_STATUS_EXPIRE)

February 9, 2019

db/import/job_noenter_map.txt

JOB_NOVICE,1,100

Something like this?

February 9, 2019

Like this?

prontera,155,175,4	script	TestScript	69,{
	
	setarray .@mob_id, 1002, 1004, 1005;
	setarray .@mob_qt,    1,    3,    8;
	setarray .@mob_req,   7,    8,   10;
	
	for(; .@i < getarraysize(.@mob_id); .@i++){
		
		if(.@mob_qt[.@i] >=  .@mob_req[.@i]) {
			dispbottom "You hunted down all the monsters on that map.";
		}
		else {
			dispbottom "You still have to hunt down the following monsters:";
			dispbottom "MonsterID: "+.@mob_id[.@i]+" Amount: "+.@mob_qt[.@i]+" Required quantity: "+.@mob_req[.@i];
			.@remain += (.@mob_req[.@i] - .@mob_qt[.@i]);
		}
	}
	if(.@remain)
		dispbottom "You still need to hunt "+F_InsertPlural(.@remain,"monster")+".";
	end;
}

February 9, 2019

-	script	Lucky_Draw	-1,{

OnMinute00:

	.@prize_id = 512;
	.@prize_amt = 5;
	if(gettime(DT_HOUR) % 2 == 0) {
		.@size = getunits(BL_PC,.@players);
		.@winner = .@players[rand(.@size)];
		attachrid .@winner;
		announce strcharinfo(0)+" has won the Lucky Draw ("+F_InsertPlural(.@prize_amt,getitemname(.@prize_id))+").",bc_all;
		if(checkweight(.@prize_id,.@prize_amt))
			getitem .@prize_id,.@prize_amt;
		else
			mail getcharid(0),"Lucky Draw","Prize","Heres the Lucky Draw Prize",0,.@prize_id,.@prize_amt;
	}
	end;

}

February 6, 2019

Update to last version of rAthena (you need this commit https://github.com/rathena/rathena/commit/1f97beae277a95bf7ede02e582a108b8802bb46c), and also last version of the script.

January 31, 2019

OnClock<hour><minute>:
OnMinute<minute>:
OnHour<hour>:
On<weekday><hour><minute>:
OnDay<month><day>:

This will execute when the server clock hits the specified date or time. Hours
and minutes are given in military time. ('0105' will mean 01:05 AM). Weekdays
are Sun,Mon,Tue,Wed,Thu,Fri,Sat. Months are 01 to 12, days are 01 to 31.
Remember the zero.

OnWed1930:

January 30, 2019

1) Edit db/pre-re or db/re achievement_db.yml

2) Test this:

skill.cpp

Change:

/*==========================================
 * Does cast-time reductions based on dex, item bonuses and config setting
 *------------------------------------------*/
int skill_castfix(struct block_list *bl, uint16 skill_id, uint16 skill_lv) {
	double time = skill_get_cast(skill_id, skill_lv);

	nullpo_ret(bl);

#ifndef RENEWAL_CAST
	{
		struct map_session_data *sd = BL_CAST(BL_PC, bl);
		struct status_change *sc = status_get_sc(bl);
		int reduce_cast_rate = 0;
		uint8 flag = skill_get_castnodex(skill_id);

		// Calculate base cast time (reduced by dex)
		if (!(flag&1)) {
			int scale = battle_config.castrate_dex_scale - status_get_dex(bl);

			if (scale > 0)	// not instant cast
				time = time * (float)scale / battle_config.castrate_dex_scale;
			else
				return 0; // instant cast
		}

		// Calculate cast time reduced by item/card bonuses
		if (sd) {
			if (!(flag&4) && sd->castrate != 100)
				reduce_cast_rate += 100 - sd->castrate;
			// Skill-specific reductions work regardless of flag
			for (const auto &it : sd->skillcastrate) {
				if (it.id == skill_id) {
					time += time * it.val / 100;
					break;
				}
			}
		}

		// These cast time reductions are processed even if the skill fails
		if (sc && sc->count) {
			// Magic Strings stacks additively with item bonuses
			if (!(flag&2) && sc->data[SC_POEMBRAGI])
				reduce_cast_rate += sc->data[SC_POEMBRAGI]->val2;
			// Foresight halves the cast time, it does not stack additively
			if (sc->data[SC_MEMORIZE]) {
				if(!(flag&2))
					time -= time * 50 / 100;
				// Foresight counter gets reduced even if the skill is not affected by it
				if ((--sc->data[SC_MEMORIZE]->val2) <= 0)
					status_change_end(bl, SC_MEMORIZE, INVALID_TIMER);
			}
		}

		time = time * (1 - (float)reduce_cast_rate / 100);
	}
#endif

	// config cast time multiplier
	if (battle_config.cast_rate != 100)
		time = time * battle_config.cast_rate / 100;
	// return final cast time
	time = max(time, 0);
	//ShowInfo("Castime castfix = %f\n",time);

	return (int)time;
}

to:

/*==========================================
 * Does cast-time reductions based on dex, item bonuses and config setting
 *------------------------------------------*/
int skill_castfix(struct block_list *bl, uint16 skill_id, uint16 skill_lv) {
	double time = skill_get_cast(skill_id, skill_lv);

	nullpo_ret(bl);

	struct map_session_data *sd = BL_CAST(BL_PC, bl);
	struct status_change *sc = status_get_sc(bl);
	int reduce_cast_rate = 0;
	uint8 flag = skill_get_castnodex(skill_id);

	if(sd) {

		if(sd->class_ & ~MAPID_THIRDMASK) {
			// Calculate base cast time (reduced by dex)
			if (!(flag&1)) {

				int scale = battle_config.castrate_dex_scale - status_get_dex(bl);
				if (scale > 0)	// not instant cast
					time = time * (float)scale / battle_config.castrate_dex_scale;
				else
					return 0; // instant cast
			}
			if (!(flag&4) && sd->castrate != 100)
				reduce_cast_rate += 100 - sd->castrate;
			// Skill-specific reductions work regardless of flag
			for (const auto &it : sd->skillcastrate) {
				if (it.id == skill_id) {
					time += time * it.val / 100;
					break;
				}
			}
			// These cast time reductions are processed even if the skill fails
			if (sc && sc->count) {
				// Magic Strings stacks additively with item bonuses
				if (!(flag&2) && sc->data[SC_POEMBRAGI])
					reduce_cast_rate += sc->data[SC_POEMBRAGI]->val2;
				// Foresight halves the cast time, it does not stack additively
				if (sc->data[SC_MEMORIZE]) {
					if(!(flag&2))
						time -= time * 50 / 100;
					// Foresight counter gets reduced even if the skill is not affected by it
					if ((--sc->data[SC_MEMORIZE]->val2) <= 0)
						status_change_end(bl, SC_MEMORIZE, INVALID_TIMER);
				}
			}
            time = time * (1 - (float)reduce_cast_rate / 100);
		}
	}

	// config cast time multiplier
	if (battle_config.cast_rate != 100)
		time = time * battle_config.cast_rate / 100;
	// return final cast time
	time = max(time, 0);
	//ShowInfo("Castime castfix = %f\n",time);

	return (int)time;
}

January 30, 2019

Could it be because this other NPC's (malangdo,218,123,1 script Namis#invest 545,4,4) OnTouch gets executed while you're on the other and sets the player current NPC id to 0 with its "end"?

Test removing this for now:

OnTouch:
	if (rand(2))
		emotion ET_SLEEPY;
	else
		specialeffect EF_SLEEPATTACK;
	end;

January 30, 2019

Script:

	// Here goes your view id to remove.
	.@view_id = 999;
	setarray .@look[0],LOOK_HEAD_BOTTOM,LOOK_HEAD_TOP,LOOK_HEAD_MID;
	for(.@i = EQI_HEAD_LOW;.@i <= EQI_HEAD_TOP;.@i++) {
		.@view = getiteminfo(getequipid(.@i),11);
		if(getlook(.@look[.@i - 4]) == .@view_id)
			setlook .@look[.@i - 4],.@view;
	}

Or querys:

	UPDATE `char` SET `head_top` = '0' WHERE `head_top` = '999'
	UPDATE `char` SET `head_mid` = '0' WHERE `head_mid` = '999'
	UPDATE `char` SET `head_bottom` = '0' WHERE `head_bottom` = '999'

I don't know how these might work, they may reset the view ids and players might have to relog (they could have no view id even if they have a poring hat, for example).

January 30, 2019

//===== rAthena Script =======================================
//= Job Master
//===== Description: =========================================
//= A fully functional job changer.
//===== Additional Comments: =================================
//= 1.0 Initial script. [Euphy]
//= 1.1 Fixed reset on Baby job change.
//= 1.2 Added Expanded Super Novice support and initial Kagerou/Oboro support.
//= 1.3 Kagerou/Oboro added.
//= 1.4 Rebellion added.
//= 1.5 Added option to disable RebirthClass. [mazvi]
//= 1.6 Added option to get job related equipment on change. [Braniff]
//= 1.7 Readability changes. Also added BabyExpanded and BabySummoner classes. [Jey]
//= 1.8 Added option to disable Baby Novice Only but Baby Class can be Enabled [mazvi]
//= 1.9 Migrate/Integrate to Global Functions Platinum Skills. [mazvi]
//============================================================

prontera,153,193,6	script	Job Master	123,{
function Get_Job_Equip;
// Checks if the Player has the required level.
// closes if not, returns if yes
function	Require_Level	{
	if (BaseLevel < getarg(0) || JobLevel < getarg(1)) {
		.@blvl = getarg(0) - BaseLevel;
		.@jlvl = getarg(1) - JobLevel;
		mes "Level requirement:";
		mes ((getarg(0)>1)? 
			"^bb0000"+getarg(0)+"^000000 (^bb0000Base^000000) / ":"")+"^00bb00"+
			getarg(1)+"^000000 (^00bb00Job^000000)";
		mes "You need " +
			((.@blvl > 0) ? "^bb0000"+.@blvl+"^000000 more base levels " + 
				((.@jlvl > 0) ? "and " : "") : "") +
			((.@jlvl > 0) ? "^00bb00"+.@jlvl+"^000000 more job levels " : "") +
			"to continue.";
		close;
	}
	return;
}

// Checks if the given eac is a baby class
function Is_Baby	{
	return ((getarg(0, eaclass())&EAJL_BABY)>0);
}

// Checks if the player can change to third class.
// Note: This does not include the level checks.
function	Can_Change_Third	{
	// To change to third class you either need to be:
	// * Second Class
	// * Transcendent Second Class
	// * Baby Second Class
	if( !.ThirdClass )
		return false; // Third job change disabled
	if( !(eaclass()&EAJL_2) )
		return false; // Not second Class
	if( eaclass()&EAJL_UPPER )
		return false; // No Rebirth 3rd.
	if( eaclass()&EAJL_THIRD )
		return false; // Already Third Class
	if( roclass(eaclass()|EAJL_THIRD) < 0 )
		return false; // Job has no third Class
	if( (eaclass()&EAJ_UPPERMASK) == EAJ_SUPER_NOVICE )
		return false; // Exp. Super Novice equals 3rd Cls, but has it's own case
	if( Is_Baby() && (!.BabyClass || !.BabyThird) )
		return false; // No Baby (Third) change allowed
	return true;
}

function	Can_Rebirth	{
	// To rebirth, you need to be:
	// * Second Class
	if( !.RebirthClass )
		return false; // Rebirth disabled
	if( !(eaclass()&EAJL_2) )
		return false; // Not second Class
	if( eaclass()&EAJL_UPPER )
		return false; // Already Rebirthed
	if( roclass(eaclass()|EAJL_UPPER) < 0 )
		return false; // Job has no transcended class
	if( Is_Baby() && !.BabyClass )
		return false; // No Baby changes allowed
	return true;
}

// Checks if the given eac is a first class
function	Is_First_Cls	{
	return (getarg(0) <= EAJ_TAEKWON);
}

function	Check_Riding	{
	// Note: Why we should always check for Riding:
	// Mounts are considered as another class, which
	// would make this NPC bigger just to handle with
	// those special cases.
	if (checkfalcon() || checkcart() || checkriding() || ismounting()) {
		mes "Please remove your " +
			((checkfalcon()) ? "falcon" : "") +
			((checkcart()) ? "cart" : "") +
			((checkriding()) ? "Peco" : "") +
			((ismounting()) ? "mount" : "") +
			" before proceeding.";
		close;
	}
	return;
}
function	Check_SkillPoints	{
	if (.SkillPointCheck && SkillPoint) {
		mes "Please use all your skill points before proceeding.";
		close;
	}
	return;
}

// addJobOptions is essentially the same like
// setarray .@array[getarraysize(.@array)],opt1,opt2,...;
// It's just easier to read, since we're using it very often
function	Job_Options	{
	.@argcount = getargcount();
	.@arr_size = getarraysize(getarg(0));
	for( .@i = 1; .@i < .@argcount; .@i++) {
		setarray getelementofarray(getarg(0), .@arr_size++),getarg(.@i);
	}
}

// Begin of the NPC
	mes .NPCName$;
	Check_Riding();
	Check_SkillPoints();

	// initialisation
	deletearray .@job_opt[0],getarraysize(.@job_opt);
	.@eac = eaclass();
	.@third_possible = Can_Change_Third();
	.@rebirth_possible = Can_Rebirth();
	.@first_eac = .@eac&EAJ_BASEMASK;
	.@second_eac = .@eac&EAJ_UPPERMASK;
	// Note: These are already set in pc.c
	// BaseClass = roclass(.@eac&EAJ_BASEMASK) which is the players First Class
	// BaseJob = roclass(.@eac&EAJ_UPPERMASK) which is the players Second Class
	//dispbottom "Debug: eac ("+.@eac+"), third ("+.@third_possible+"), rebirth("+.@rebirth_possible+"), BaseClass ("+BaseClass+"), BaseJob ("+BaseJob+")";
		
	// From here on the jobmaster checks the current class
	// and fills the the array `.@job_opt` with possible
	// job options for the player.
	
	if( .@rebirth_possible ) {
		// Rebirth option (displayed on the top of the menu)
		Require_Level(.Req_Rebirth[0], .Req_Rebirth[1]);
		Job_Options(.@job_opt, Job_Novice_High);
	}
	if( .@third_possible ) {
		// Third Job change (displayed below rebirth)
		Require_Level(.Req_Third[0], .Req_Third[1]);
		Job_Options(.@job_opt, roclass(.@eac|EAJL_THIRD));
	}
	 
	if (.SecondExpanded && 
	   (.@eac&EAJ_UPPERMASK) == EAJ_SUPER_NOVICE && // is Super Novice
	   !(eaclass()&EAJL_THIRD) ) {				 	// not already Expanded SN
		// (Baby) Super Novice to Expanded (Baby) Super Novice
	   	if( !Is_Baby(.@eac) || (.BabyClass && .BabyExpanded) ) {
			// .BabyClass & .BabyExpanded must be enabled if the is a baby
			Require_Level(.Req_Exp_SNOVI[0], .Req_Exp_SNOVI[1]);
			Job_Options(.@job_opt,roclass(.@eac|EAJL_THIRD)); // Expanded SN is "third" cls
		}
	}
	
	if (.SecondExpanded && 
		((.@eac&(~EAJL_BABY)) == EAJ_NINJA || 		// is (Baby) Ninja
		(.@eac&(~EAJL_BABY)) == EAJ_GUNSLINGER)) {	// is (Baby) Gunslinger
		// (Baby) Ninja to (Baby) Kagerou / Oboro
		// (Baby) Gunslinger to (Baby) Rebellion
		if( !Is_Baby(.@eac) || (.BabyClass && .BabyExpanded) ) {
			// .BabyClass & .BabyExpanded must be enabled if the is a baby
			Require_Level(.Req_Exp_NJ_GS[0], .Req_Exp_NJ_GS[1]);
			// Kagerou, Oboro, Rebellion are considered as a 2-1 class
			Job_Options(.@job_opt, roclass(.@eac|EAJL_2_1));
		}
	}
	
	// Player is Job_Novice, Job_Novice_High or Job_Baby
	if (.@first_eac == EAJ_NOVICE && .@second_eac != EAJ_SUPER_NOVICE) {
		// MAPID_NOVICE, MAPID_SUPER_NOVICE, MAPID_NOVICE_HIGH, MAPID_BABY
		Require_Level(.Req_First[0], .Req_First[1]);
		switch(Class) {
			case Job_Novice:
				// First job change
				Job_Options(.@job_opt,Job_Swordman,
					Job_Mage, Job_Archer, Job_Acolyte, Job_Merchant, Job_Thief,
					Job_Super_Novice, Job_Taekwon, Job_Gunslinger, Job_Ninja);
				if( .BabyNovice )
					Job_Options(.@job_opt, Job_Baby);
				break;
			case Job_Novice_High:
				// Job change after rebirth
				if( .LastJob && lastJob )
					Job_Options(.@job_opt,
						roclass((eaclass(lastJob)&EAJ_BASEMASK)|EAJL_UPPER));
				else
					Job_Options(.@job_opt, 
						Job_Swordman_High, Job_Mage_High, Job_Archer_High,
						Job_Acolyte_High, Job_Merchant_High, Job_Thief_High);
				break;
			case Job_Baby:
				if( !.BabyClass )
					break;
				// First job change as a baby
				Job_Options(.@job_opt, Job_Baby_Swordman, Job_Baby_Mage,
					Job_Baby_Archer,Job_Baby_Acolyte, Job_Baby_Merchant,
					Job_Baby_Thief);
				if( .BabyExpanded )
					Job_Options(.@job_opt, Job_Super_Baby, Job_Baby_Taekwon,
						Job_Baby_Gunslinger, Job_Baby_Ninja);
				if( .BabySummoner )
					Job_Options(.@job_opt, Job_Baby_Summoner);
				break;
			default:
				mes "An error has occurred.";
				close;
		}
	} else if( Is_First_Cls(.@eac) || 				// First Class
			   Is_First_Cls(.@eac&(~EAJL_UPPER)) ||	// Trans. First Cls
			   (.BabyClass && Is_First_Cls(.@eac&(~EAJL_BABY))) ) {	// Baby First Cls
		// Player is First Class (not Novice)
		// most jobs should have two options here  (2-1 and 2-2)
		.@class1 = roclass(.@eac|EAJL_2_1); // 2-1
		.@class2 = roclass(.@eac|EAJL_2_2); // 2-2
		// dispbottom "Debug: Classes: class1 ("+.@class1+"), class2 ("+.@class2+")";
		if(.LastJob && lastJob && (.@eac&EAJL_UPPER)) {
			// Player is rebirth Cls and linear class changes are enforced
			Require_Level(.Req_Second[0], .Req_Second[1]);
			Job_Options(.@job_opt, lastJob + Job_Novice_High);
		} else {
			// Class is not enforced, player can decide.
			if( .@class1 > 0 ) { // 2-1
				Require_Level(.Req_Second[0], .Req_Second[1]);
				Job_Options(.@job_opt, .@class1);
			}
			if( .@class2 > 0 ) { // 2-2
				Require_Level(.Req_Second[0], .Req_Second[1]);
				Job_Options(.@job_opt, .@class2);
			}
		}
	}
	
	// Displaying the Job Menu defined by .@job_opt.
	// .@job_opt should not be changed below this line.
	function Job_Menu;
	Job_Menu(.@job_opt);
	close;

// Displays the job menu
function	Job_Menu	{
	// getarg(0) is the .@job_opt array holding all available job changes.
	function Confirm_Change;
	while(true) {
		.@opt_cnt =  getarraysize(getarg(0));
		if( .@opt_cnt <= 0 ) {
			mes "No more jobs are available.";
			close;
		}

		.@selected = 0; // Just a single job class given, no select needed
		if (.@opt_cnt > 1) {
			// Multiple job classes given. Select one and save it to .@class
			// After that confirm .@class
			mes "Select a job.";
			.@menu$ = "";
			for (.@i = 0; .@i < .@opt_cnt; .@i++) {
				if( getelementofarray(getarg(0), .@i) == Job_Novice_High)
					.@jobname$ = "^0055FFRebirth^000000";
				else
					.@jobname$ = jobname(getelementofarray(getarg(0), .@i));
				.@menu$ = .@menu$ + " ~ " + .@jobname$ + ":";
			}
			.@menu$ = .@menu$+" ~ ^777777Cancel^000000";
			.@selected = select(.@menu$) - 1;
			if( .@selected < 0 || .@selected >= .@opt_cnt )
				close;
			next;
			mes .NPCName$;
		}
		.@class = getelementofarray(getarg(0), .@selected);
		if ((.@class == Job_Super_Novice || .@class == Job_Super_Baby) &&
				BaseLevel < .SNovice) {
			// Special Level Requirement because Super Novice and
			// Super Baby can both be selected in one of the first class
			// changes. That's why the Level Requirement is after and not before
			// the selection.
			mes "A base level of " + .SNovice +
				" is required to turn into a " + jobname(.@class) + ".";
			return;
		}
		// Confirm the Class
		Confirm_Change(.@class, .@opt_cnt > 1);
		next;
		mes .NPCName$;
	}
	return;
}


// Executes the actual jobchange and closes.
function	Job_Change	{
	.@to_cls = getarg(0);
	next;
	mes .NPCName$;
	mes "You are now " + callfunc("F_InsertArticle", jobname(.@to_cls)) + "!";
	if (.@to_cls == Job_Novice_High && .LastJob)
		lastJob = Class; // Saves the lastJob for rebirth
	jobchange .@to_cls;
	if (.@to_cls == Job_Novice_High)
		resetlvl(1);
	else if (.@to_cls == Job_Baby) {
		resetstatus;
		resetskill;
		set SkillPoint,0;
	}
	specialeffect2 EF_ANGEL2;
	specialeffect2 EF_ELECTRIC;
	if (.Platinum)
		callfunc "F_GetPlatinumSkills";
	if (.GetJobEquip)
		Get_Job_Equip();
	close; // Always closes after the change
}

function	Confirm_Change	{
	// Player confirms he want to change into .@class
	.@class = getarg(0, -1);
	.@back = getarg(1, false);
	if( .@class < 0 ) {
		mes "Unknown Class Error.";
		close;
	}
	mes "Do you want to change into ^0055FF"+jobname(.@class)+"^000000 class?";
	.@job_option$ = " ~ Change into ^0055FF"+jobname(.@class)+"^000000 class";
	if( .@class == Job_Novice_High)
		.@job_option$ = " ~ ^0055FFRebirth^000000";
	
	if (select(.@job_option$+": ~ ^777777" + 
			((.@back) ?"Go back" : "Cancel") + "^000000") == 1) {
		Job_Change(.@class);
	}
	if (!.@back)
		close; // "Cancel" pressed
	return;
}

// Function which gives a job related item to the player
// the items are the rewards from the original job change quests
function	Get_Job_Equip	{
	// Note: The item is dropping, when the player can't hold it.
	// But that's better than not giving the item at all.
	.@eac = eaclass();
	if( .@eac&EAJL_THIRD ) {
		// Third Class Items
		getitem 2795,1;	//	Green Apple Ring for every 3rd Class
		switch(BaseJob) {
			// BaseJob of Third Cls
			// For Normal Third, Baby Third and Transcended Third Cls
			case Job_Knight:
				getitem 5746,1;	break;	//	Rune Circlet [1]
			case Job_Wizard:
				getitem 5753,1;	break;	//	Magic Stone Hat [1]
			case Job_Hunter:
				getitem 5748,1;	break;	//	Sniper Goggle [1]
			case Job_Priest:
				getitem 5747,1;	break;	//	Mitra [1]
			case Job_Blacksmith:
				getitem 5749,1;	break;	//	Driver Band [1]
			case Job_Assassin:
				getitem 5755,1;	break;	//	Silent Executor [1]
			case Job_Crusader:
				getitem 5757,1;	break;	//	Dip Schmidt Helm [1]
			case Job_Sage:
				getitem 5756,1;	break;	//	Wind Whisper [1]
			case Job_Bard:
				getitem 5751,1;	break;	//	Maestro Song's Hat [1]
			case Job_Dancer:
				getitem 5758,1;	break;	//	Dying Swan [1]
			case Job_Monk:
				getitem 5754,1;	break;	//	Blazing Soul [1]
			case Job_Alchemist:
				getitem 5752,1;	break;	//	Midas Whisper[1]
			case Job_Rogue:
				getitem 5750,1; 		//	Shadow Handicraft [1]
				getitem 6121,1;			//	Makeover Brush
				getitem 6122,1;	break;	//	Paint Brush
		}
	} else if (.@eac&EAJL_2) {
		// Second Class (And not Third Class)
		switch(BaseJob) {
			// Second Class
			case Job_Knight:
				getitem 1163,1;	break;	//	Claymore [0]
			case Job_Priest:
				getitem 1522,1;	break;	//	Stunner [0]
			case Job_Wizard:
				getitem 1617,1;	break;	//	Survivor's Rod [0]
			case Job_Blacksmith:
				getitem 1360,1;	break;	//	Two-Handed-Axe [1]
			case Job_Hunter:
				getitem 1718,1;	break;	//	Hunter Bow [0]
			case Job_Assassin:
				getitem 1254,1;	break;	//	Jamadhar [0]
			case Job_Crusader:
				getitem 1410,1;	break;	//	Lance [0]
			case Job_Monk:
				getitem 1807,1;	break;	//	Fist [0]
			case Job_Sage:
				getitem 1550,1;	break;	//	Book [3]
			case Job_Rogue:
				getitem 1222,1;	break;	//	Damascus [1]
			case Job_Alchemist:
				getitem 1126,1;	break;	//	Saber [2]
			case Job_Bard:
				getitem 1907,1;	break;	//	Guitar [0]
			case Job_Dancer:
				getitem 1960,1;	break;	//	Whip [1]
			case Job_Super_Novice:
				getitem 1208,1;	break;	//	Main Gauche [4]
			case Job_Gunslinger:
				getitem 13101,1; break;	//	Six Shooter [2]
			case Job_Ninja:
				getitem 13010,1; break;	//	Asura [2]
			case Job_Star_Gladiator:
				getitem 1550,1;	break;	//	Book [3]
			case Job_Soul_Linker:
				getitem 1617,1;	break;	//	Survivor's Rod [0]
		}
	} else {
		// Neither Second or Third Cls
		// => First Cls or not covered by the switch
		switch(BaseClass) {
			// First Class
			case Job_Swordman:
				getitem 1108,1;	break;	//	Blade [4]
			case Job_Mage:
				getitem 1602,1;	break;	//	Rod [4]
			case Job_Archer:
				getitem 1705,1;	break;	//	Composite Bow [4]
			case Job_Acolyte:
				getitem 1505,1;	break;	//	Mace [4]
			case Job_Merchant:
				getitem 1302,1;	break;	//	Axe [4]
			case Job_Thief:
				getitem 1208,1;	break;	//	Main Gauche [4]
		}
	}
	return;
}

OnInit:
	// Initialisation, do not edit these
	.NPCName$ = "[Job Master]";
	
	// Settings
	.ThirdClass = true;			// Enable third classes?
	.RebirthClass = true;			// Enable rebirth classes?
	.SecondExpanded = true;		// Enable new expanded second classes: Ex. Super Novice, Kagerou/Oboro, Rebellion?
	.BabyNovice = true;	// Enable Baby novice classes? Disable it if you like player must have parent to get job baby.
	.BabyClass = true;				// Enable Baby classes?
	.BabyThird = true;				// Enable Baby third classes?
	.BabyExpanded = true;			// Enable Baby Expanded classes: Ex. Baby Ninja, Baby Taekwon, etc.
	.BabySummoner = true;			// Enable Baby Summoner?
	.LastJob = true;				// Enforce linear class changes?
	.SkillPointCheck = true;		// Force player to use up all skill points?
	.Platinum = true;				// Get platinum skills automatically?
	.GetJobEquip = false;			// Get job equipment (mostly weapons) on job change?

	// Level Requirements
	setarray .Req_First[0],1,10; 		// Minimum base level, job level to turn into 1st class
	setarray .Req_Second[0],1,40; 		// Minimum base level, job level to turn into 2nd class
	setarray .Req_Rebirth[0],99,50;		// Minimum base level, job level to rebirth
	setarray .Req_Third[0],99,50;		// Minimum base level, job level to change to third class
	setarray .Req_Exp_NJ_GS[0],99,70; 	// Minimum base level, job level to turn into Expanded Ninja and Gunslinger
	setarray .Req_Exp_SNOVI[0],99,99; 	// Minimum base level, job level to turn into Expanded Super Novice
	.SNovice = 45;						// Minimum base level to turn into Super Novice
	
	// Setting adjustments by PACKETVER
	if( PACKETVER < 20161207 ) {
		if( .BabyExpanded )
			debugmes "jobmaster: BabyExpanded is disabled due to outdated PACKETVER.";
		if( .BabySummoner )
			debugmes "jobmaster: BabySummoner is disabled due to outdated PACKETVER.";
		.BabyExpanded = false;
		.BabySummoner = false;
	}
	end;
}

Sign In

Profiles

Forums

Downloads

Jobs Available

Server Database

Third-Party Services

Top Guides

Store

Crowdfunding

Posts posted by n0tttt