prontera,155,181,3	script	Yumi Haruka	10173,{

	mes .name$;
	mes "Hello there!";
	mes "I convert things swiftly and diligently!";
	mes "Is there anything you like to convert?";
	next;
	.@opt = select(.Menu$)-1;
	mes .name$;
	mes "You want to convert ^0055FF"+getitemname(.ItemIDFrom[.@opt])+"^000000 into ^0055FF"+getitemname(.ItemIDTo[.@opt])+"^000000.";
	mes "Please choose a chance or input your desired chance.";
	next;
	.@menu$ = "";
	for(.@i=0;.@i<getarraysize(.Chances);.@i++)
		.@menu$ = .@menu$ + "Give ^0055FF"+((.AmountFrom[.@opt]*.Chances[.@i])/100)+" "+getitemname(.ItemIDFrom[.@opt])+" for ^0055FF"+.Chances[.@i]+"%^000000 Chance:";
	.@menu$ = .@menu$ + "Custom Chance";
	next;
	.@opt2 = select(.@menu$)-1;
	if(.@opt2 >= getarraysize(.Chances)){
		mes .name$;
		mes "Please insert your desired chance.";
		next;
		input .@chance,1,100;
		.@amount = ((.AmountFrom[.@opt]*.@chance)/100);
	} else {
		.@amount = ((.AmountFrom[.@opt]*.Chances[.@opt2])/100);
		.@chance = .Chances[.@opt2];
	}
	mes .name$;
	mes "Your desired chance is ^0055FF"+.@chance+"%^000000.";
	mes "This would cost you ^FF5500"+.@amount+"^000000 pieces "+getitemname(.ItemIDFrom[.@opt])+" to get ^FF55001^000000 piece of "+getitemname(.ItemIDTo[.@opt])+".";
	mes "Would you like to proceed?.";
	next;
	if(select("Yes Please..:Cancel")==2) end;
	if(countitem(.ItemIDFrom[.@opt]) < .@amount){
		mes .name$;
		mes "I'm sorry, but i cannot process your request because you lack of ^0055FF"+getitemname(.ItemIDFrom[.@opt])+"^000000.";
		end;
	}
	mes .name$;
	if(rand(1,100) > .@chance){
		mes "Oh!~ Sorry, too bad~~";
		mes "The conversion has failed miserably.";
		mes "You can try again anytime.";
		end;
	}
	delitem .ItemIDFrom[.@opt],.@amount;
	getitem .ItemIDTo[.@opt],1;
	mes "Alright!~";
	mes "The conversion is a success!";
	mes "Hoping that you love my service.";
close;

OnInit:
	.name$ = "[ ^FF5500Yumi Haruka^000000 ]";
	//Setup Here
	setarray .ItemIDFrom[0],985,984;
	setarray .AmountFrom[0],100,200;
	setarray .ItemIDTo[0],7619,7620;

	//Do not touch without knowing - These is Menu available chances
	setarray .Chances[0],100,75,50,25;
	
	for(.@i=0;.@i<getarraysize(.ItemIDFrom);.@i++)
		.Menu$ = .Menu$ + getitemname(.ItemIDFrom[.@i])+" to "+getitemname(.ItemIDTo[.@i]) +":";
	.Menu$ = .Menu$ + "Cancel";
	//NOTE: Chance = 100/AmountFrom %;
end;

}